用vba正确打开分号间隔的csv文件

公司的一台设备控制电脑导出的记录文件格式为csv，导出到办公电脑上时发现这些csv文件的分隔符不是逗号，而是分号，如果用Excel直接打开，每行的内容会全部堆在第一列而没有分割开，虽然用Excel的分列功能可以简单地解决，但导出的文件非常多，故用vba写了个函数来解决。

Function GetSemicolonCSV(ByVal csvFullName As String)
    Dim i As Long, j As Long, Arr() As Byte, s As String, Arr2, Arr3, ArrAll
    i = FreeFile
    '二进制打开unicode编码的csv文件，跳过前两个字节后读取全部内容
    Open csvFullName For Binary As #i
    ReDim Arr(0 To LOF(i) - 3)
    Get #i, 3, Arr
    Close #i
    'vb的字符串是unicode编码的，复制二进制数组到字符串变量的指针指向的内存地址
    s = Arr
    '用换行符分割行，用分号分割列
    Arr2 = Split(s, vbNewLine)
    ReDim ArrAll(0 To UBound(Arr2), 0 To UBound(Split(Arr2(0), ";")))
    '第一行是字段名，去掉双引号
    Arr3 = Split(Replace(Arr2(0), """", ""), ";")
    '除了第三列是日期外其他都是数字
    For j = 0 To UBound(ArrAll, 2)
        ArrAll(0, j) = Arr3(j)
    Next
    For i = 1 To UBound(ArrAll, 1)
        Arr3 = Split(Arr2(i), ";")
        For j = 0 To UBound(ArrAll, 2)
            If j = 2 Then
                ArrAll(i, j) = CDate(Arr3(j))
            Else
                ArrAll(i, j) = CDbl(Arr3(j))
            End If
        Next
    Next
    GetSemicolonCSV = ArrAll
End Function