use study
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
-- =============================================
-- Author: cxw
-- Create date: 2006/11/28
-- Description: 用递归实现字符串分割
/*
--函数具体用法:
--最常用的调用:
select *
from dbo.RecurrentSplit('AA@BBB@CCC@','@',0,0)
select *
from dbo.RecurrentSplit('AA@@@BBB@@@CCC@@@','@@@',null,null)--默认
--具体细节用法:
--分割字符不显示,分割方法是按前面的分割字符串,只显示分割后的字符串
select *
from dbo.RecurrentSplit('AA@@@BBB@@@CCC@@@','@@@',0,1)
--分割字符显示,并是按前面的来进行分割,分割字符放在被分割字符串的前面
select *
from dbo.RecurrentSplit('@@@AA@@@BBB@@@CCC@@@','@@@',1,1)
--分割字符不显示,并是按后面的来进行分割,只显示分割后的字符串
select *
from dbo.RecurrentSplit('AA@@@BBB@@@CCC@@@','@@@',0,0)
--分割字符显示,并是按后面的来进行分割,分割字符放在被分割字符串的后面
select *
from dbo.RecurrentSplit('AA@@@BBB@@@CCC@@@','@@@',1,0)
*/
-- =============================================
Create FUNCTION DBO.RecurrentSplit
(
@nvStr nvarchar(2000) --需要分割字符串
,@vSeparte varchar(50) --分割字符串
,@iIsHaveSeparte int --是否显示字符串
,@iIsBefore int --是否是后面的分割符(分割字符分割的顺序)
)
RETURNS @Split table
(
IndexNo int default(0) --流水号
,SplitName nvarchar(1000) --分割后字符串
)
AS
BEGIN
if(charindex(@vSeparte,@nvStr)<=0) --处理在整个字符串里都没有要分割,也就是字符串本身
begin
insert into @Split(SplitName) values(@nvStr)
return
end
declare @iSeparteLen int
,@iEndHave int --最后几个字符串是否是分割字符
,@iStartHave int --前面几个字符串是否是分割字符
select @iSeparteLen=len(@vSeparte)
,@iStartHave=0
,@iEndHave=0
,@iIsHaveSeparte=case when @iIsHaveSeparte is null --默认值
then 0
else @iIsHaveSeparte
end
,@iIsBefore=case when @iIsBefore is null --默认值
then 0
else @iIsBefore
end
if(@iIsBefore=1) --只有在处理前面字符串分割时才用
begin
if(left(@nvStr,@iSeparteLen)<>@vSeparte)--处理前面几个分割字符一定是分割字符,不是就加
begin
select @nvStr=@vSeparte+@nvStr
,@iStartHave=1
end
end
if(right(@nvStr,@iSeparteLen)<>@vSeparte)--处理最后几个分割字符一定是分割字符,不是就加
begin
select @nvStr=@nvStr+@vSeparte
,@iEndHave=1
end; --分号一定不能少,因为用了with,是用公用表达式,在其前面一定要加;
with CharCET(CharStr,StrLen,IndexNo)
as
(
select substring(@nvStr,0
,case when @iIsBefore=0 then charindex(@vSeparte,@nvStr)+@iSeparteLen
else charindex(@vSeparte,@nvStr,charindex(@vSeparte,@nvStr)+@iSeparteLen) end
) CharStr
,case when @iIsBefore=0 then charindex(@vSeparte,@nvStr)
else charindex(@vSeparte,@nvStr,charindex(@vSeparte,@nvStr)+@iSeparteLen) end StrLen
,0 IndexNo --第一次初始化
union all
select substring(@nvStr
,case when @iIsBefore=0 then StrLen+@iSeparteLen
else StrLen end
,charindex(@vSeparte,@nvStr,StrLen+@iSeparteLen)-StrLen) CharStr
,charindex(@vSeparte,@nvStr,StrLen+@iSeparteLen) StrLen
,IndexNo+1 IndexNo --进行递归分割字符串
from CharCET
where StrLen<len(@nvStr)-@iSeparteLen --处理递归结束语句,也就是不要让其生成无限弟归下去
)
insert into @Split(IndexNo,SplitName)
select IndexNo,case when @iIsHaveSeparte=0
then replace(CharStr,@vSeparte,'')
else CharStr
end CharStr
from CharCET
if(@iIsHaveSeparte=1) --是否显示分割字符串
begin
update @Split --处理前面的分割字符串
set SplitName=case when @iStartHave=1
then replace(SplitName,@vSeparte,'')
else SplitName
end
where IndexNo = 0
update @Split --处理后面的分割字符串
set SplitName=case when @iEndHave=1
then replace(SplitName,@vSeparte,'')
else SplitName
end
where IndexNo = (select Max(IndexNo) from @Split)
end
RETURN
END
GO