字符串处理(模糊无序搜索)

-----------------------------------  

--  Author: htl258(Tony)  

--  Title : 字符串处理(模糊无序搜索)  

--  Date  : 2009-09-06 21:26:00  

--  http://blog.csdn.net/htl258

--  引用请保留此信息.

-----------------------------------  

 

IF NOT OBJECT_ID('TA') IS NULL  

    DROP TABLE TA  

GO  

CREATE TABLE TA (ID VARCHAR(3),TITLE VARCHAR(39))  

INSERT INTO TA  

SELECT '001','深入浅出SQLSERVER2005开发管理与应用实例' UNION ALL  

SELECT '002','SQLSERVER2005性能调校' UNION ALL  

SELECT '003','SQL完全手册' UNION ALL  

SELECT '004','SQLSERVER2005技术内幕存储引擎' UNION ALL  

SELECT '005','SQL宝典' UNION ALL  

SELECT '006','SQLSERVER2000高级管理与开发' UNION ALL  

SELECT '007','SQLSERVER2005数据库开发详解' UNION ALL  

SELECT '008','SQLSERVER2000存储过程与XML编程' UNION ALL  

SELECT '009','SQLSERVER2005系统管理实录' UNION ALL  

SELECT '010','SQL技术手册' 

GO  

 

--创建自定义函数 

IF NOT OBJECT_ID('FN_STR') IS NULL  

    DROP FUNCTION FN_STR  

GO  

CREATE FUNCTION FN_STR(

@STR VARCHAR(100),--输入字符串

@FLAG VARCHAR(10) --分隔符

)  

RETURNS @T TABLE(A VARCHAR(10))  

AS  

BEGIN  

    SET @STR=RTRIM(LTRIM(@STR))

    WHILE LEN(@STR)>0  

    BEGIN  

        INSERT @T SELECT LEFT(@STR,CHARINDEX(@FLAG,@STR+@FLAG)-1)  

        SET @STR=LTRIM(STUFF(LTRIM(@STR),1,

CHARINDEX(@FLAG,LTRIM(@STR)+@FLAG),''))

    END  

    RETURN   

END  

GO  

 

 

 

--1.所有关键字全匹配

DECLARE @S VARCHAR(100)  

SET @S='开发  SQL 2000' 

 

SELECT * FROM TA T   

WHERE NOT EXISTS(  

    SELECT 1   

    FROM FN_STR(@S,' ')   

    WHERE CHARINDEX(A,T.TITLE)=0)  

/*

ID   TITLE

---- ---------------------------------------

006  SQLSERVER2000高级管理与开发

 

(1 行受影响)

*/

 

 

--2.部份关键字匹配

SET @S='开发 2000'    

SELECT * FROM TA T   

WHERE EXISTS(  

    SELECT 1   

    FROM FN_STR(@S,' ')   

    WHERE CHARINDEX(A,T.TITLE)>0)  

/*

ID   TITLE

---- ---------------------------------------

001  深入浅出SQLSERVER2005开发管理与应用实例

006  SQLSERVER2000高级管理与开发

007  SQLSERVER2005数据库开发详解

008  SQLSERVER2000存储过程与XML编程

 

(4 行受影响)

*/