马农

题目描述

在观看完战马检阅之后，来自大草原的两兄弟决心成为超级“马农”，专门饲养战马。兄弟两回到草原，将可以养马的区域，分为 N*N 的单位面积的正方形， 并实地进行考察，归纳出了每个单位面积可以养马所获得的收益。接下来就要开始规划他们各自的马场了。首先，两人的马场都必须是矩形区域。同时，为了方便两人互相照应，也为了防止马匹互相走散，规定两个马场的矩形区域相邻，且只有一个交点。最后，互不认输的两人希望两个马场的收益相当，这样才不会影响他们兄弟的感情。现在，兄弟两找到你这位设计师，希望你给他们设计马场，问共有多少种设计方案。

输入

第一行一个整数 N，表示整个草原的大小为 N*N。
接下来 N 行，每行 N 个整数 A(i,j)，表示第 i 行第 j 列的单位草地的收成。
（注意：收益可能是负数，养马也不是包赚的，马匹也可能出现生病死亡等意外。）

输出

输出符合两人要求的草原分配方案数。

样例输入

3
1 2 3
4 5 6
7 8 9

样例输出

2

数据范围限制

40%的数据， N<=10。
100%的数据， N<=50, -1000

思路：

枚举两个矩形的交点，再分别枚举两组的长和宽，用很大很大的数组存这个值出现过多少次，再用一个版本号数组来存当前次数是否是最新更新的，这样就避免了每次清空数组的那样庞大的时间复杂度，哈哈~~~

代码：

var
        n,i,j,version,ans:longint;
        f:array[-2500000..2500000,0..1] of longint;
        sum:array[0..51,0..51] of longint;

procedure search_1(px,py,version:longint);
var
        x1,y1,x2,y2,total,a,b:longint;
begin
        x2:=px;
        y1:=py+1;
        for x1:=px downto 1 do
        begin
                for y2:=py+1 to n do
                begin
                        total:=sum[x2,y2]-sum[x1-1,y2]-sum[x2,y1-1]+sum[x1-1,y1-1];
                        if f[total,0]<>version then
                        begin
                                f[total,0]:=version;
                                f[total,1]:=0;
                        end;
                        f[total,1]:=f[total,1]+1;
                end;
        end;
end;

procedure search_2(px,py,version:longint);
var
        x1,y1,x2,y2,total:longint;
begin
        x2:=px;
        y2:=py;
        for x1:=px downto 1 do
        begin
                for y1:=py downto 1 do
                begin
                        total:=sum[x2,y2]-sum[x1-1,y2]-sum[x2,y1-1]+sum[x1-1,y1-1];
                        if f[total,0]<>version then
                        begin
                                f[total,0]:=version;
                                f[total,1]:=0;
                        end;
                        f[total,1]:=f[total,1]+1;
                end;
        end;
end;

procedure add_3(px,py,version:longint);
var
        x1,y1,x2,y2,total:longint;
begin
        x1:=px+1;
        y2:=py;
        for x2:=px+1 to n do
        begin
                for y1:=py downto 1 do
                begin
                        total:=sum[x2,y2]-sum[x1-1,y2]-sum[x2,y1-1]+sum[x1-1,y1-1];
                        if f[total,0]=version then
                        begin
                                ans:=ans+f[total,1];
                        end;
                end;
        end;
end;

procedure add_4(px,py,version:longint);
var
        x1,y1,x2,y2,total:longint;
begin
        x1:=px+1;
        y1:=py+1;
        for x2:=px+1 to n do
        begin
                for y2:=py+1 to n do
                begin
                        total:=sum[x2,y2]-sum[x1-1,y2]-sum[x2,y1-1]+sum[x1-1,y1-1];
                        if f[total,0]=version then
                        begin
                                ans:=ans+f[total,1];
                        end;
                end;
        end;
end;


procedure search(px,py:longint);
begin
        version:=version+1;
        search_1(px,py,version);
        add_3(px,py,version);

        version:=version+1;
        search_2(px,py,version);
        add_4(px,py,version);
end;

begin
        assign(input,'farmer.in');reset(input);
        assign(output,'farmer.out');rewrite(output);

        readln(n);
        for i:=1 to n do
        begin
                for j:=1 to n do
                begin
                        read(version);
                        sum[i,j]:=sum[i-1,j]+sum[i,j-1]-sum[i-1,j-1]+version;
                end;
                readln;
        end;

        version:=0;
        for i:=1 to n-1 do
        begin
                for j:=1 to n-1 do
                begin
                        search(i,j);
                end;
        end;

        writeln(ans);

        close(input);close(output);
end.