常用cmake命令解析

cmake命令在项目一般以CMakeList.txt文件存在，下面根据两个QT项目的cmake文件进行解析。

QT4项目的cmake文件解析

#定义项目的名称：本项目名称为demo
project(demo)

#声明CMake的最低版本要求：最低版本为2.6
cmake_minimum_required(VERSION 2.6)

#按一定的搜索路径查找以.cmake结尾的包，找到包后会返回
#一些信息给调用者，搜索路径一般是CMAKE_MODULE_PATH指定路径，CMake安装路径：
#寻找Qt4**.cmake包名称及寻找opencv**.cmake包名称，
#REQUIRED表示如果找不到包，CMake会停止执行
find_package(Qt4 REQUIRED)
FIND_PACKAGE( OpenCV REQUIRED )

#添加头文件目录：
#${}表示取出变量的值
include_directories(${QT_INCLUDES} ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_SOURCE_DIR}/lib ${CMAKE_CURRENT_SOURCE_DIR})

#set(var_name var_value)--声明变量var_name，var_name的值为var_value，
#这里的var_value的值，可以是路径，也可以是许多文件，这个命令可以灵活运用，
#比如当你想将许多源文件打包并重命名，就可以用到set指令：
#将几个cpp源文件打包并命名为demo_SRCS
set(demo_SRCS main.cpp projfile.cpp deformwin.cpp myimage.cpp singlephotoview.cpp pointspaint.cpp)

#demo_SRCS里面的文件运行MOC（只对QT4有效）
qt4_automoc(${demo_SRCS})

#ui文件进行uic操作，资源文件进行rcc操作（只只对QT4有效）
QT4_WRAP_CPP(QOBJ_CPP ${demo_SRCS})
qt4_wrap_ui(helloworld_FORMS_HEADERS deformwin.ui)

#使用指定的源文件向项目添加可执行文件
#将源文件demo_srcs等三个添加到可执行文件demo中
add_executable(demo ${demo_SRCS} ${helloworld_FORMS_HEADERS})

#指定链接给定目标和/或其依赖项时要使用的库或标志
target_link_libraries(demo ${QT_QTCORE_LIBRARY} ${QT_QTGUI_LIBRARY} imgwarp-lib opencv_core opencv_imgproc opencv_imgcodecs)

QT5目的cmake文件解析

#cmake最低版本
cmake_minimum_required(VERSION 3.5)

#工程名为111，版本为0.1，语言是C++
project(111 VERSION 0.1 LANGUAGES CXX)

#自动将当前源目录和构建目录添加到include路径。
#如果启用该变量，CMake会自动将CMAKE_CURRENT_SOURCE_DIR和#CMAKE_CURRENT_BINARY_DIR添加到每个目录的包含路径中。
#这些附加的include目录不会传播到子#目录。这主要用于外源构建，其中生成到构建树中的文件包含在#源树中的文件中
set(CMAKE_INCLUDE_CURRENT_DIR ON)

#使用autouic生成ui文件
set(CMAKE_AUTOUIC ON)

#将所有源代码提供给MOC以生成MOC文件
set(CMAKE_AUTOMOC ON)

#为Qt目标自动处理rc
set(CMAKE_AUTORCC ON)

#设置c++版本
set(CMAKE_CXX_STANDARD 17)

#指定的c++版本是必须的
set(CMAKE_CXX_STANDARD_REQUIRED ON)

#查找包，及下面的组件--必须找到
find_package(QT NAMES Qt6 Qt5 REQUIRED COMPONENTS Widgets)
find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Widgets)

#打包源文件为PROJECT_SOURCES
set(PROJECT_SOURCES
        main.cpp
        mainwindow.cpp
        mainwindow.h
        mainwindow.ui
)

#如果QT版本大于6，则将MANUAL_FINALIZATION和${PROJECT_SOURCES}加如可执行文件
if(${QT_VERSION_MAJOR} GREATER_EQUAL 6)
    qt_add_executable(111
        MANUAL_FINALIZATION
        ${PROJECT_SOURCES}
    )

# Define target properties for Android with Qt 6 as:
#    set_property(TARGET 111 APPEND PROPERTY QT_ANDROID_PACKAGE_SOURCE_DIR
#                 ${CMAKE_CURRENT_SOURCE_DIR}/android)
# For more information, see https://doc.qt.io/qt-6/qt-add-executable.html#target-creation
else()
    if(ANDROID)
        add_library(111 SHARED
            ${PROJECT_SOURCES}
        )
# Define properties for Android with Qt 5 after find_package() calls as:
#    set(ANDROID_PACKAGE_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/android")
    else()
        add_executable(111
            ${PROJECT_SOURCES}
        )
    endif()
endif()

#为项目指定依赖库
target_link_libraries(111 PRIVATE Qt${QT_VERSION_MAJOR}::Widgets)

#设置目标的属性
#格式：
#set_target_properties(目标文件1 目标文件2 ...PROPERTIES 
#                      属性1 属性值1 属性2 属性值2 ...) 
set_target_properties(111 PROPERTIES
    MACOSX_BUNDLE_GUI_IDENTIFIER my.example.com
    MACOSX_BUNDLE_BUNDLE_VERSION ${PROJECT_VERSION}
    MACOSX_BUNDLE_SHORT_VERSION_STRING ${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}
    MACOSX_BUNDLE TRUE
    WIN32_EXECUTABLE TRUE
)

#指定安装时要运行的规则
install(TARGETS 111
    BUNDLE DESTINATION .
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})

if(QT_VERSION_MAJOR EQUAL 6)
    qt_finalize_executable(111)
endif()