批处理批量重命名文件

@echo off
setlocal enabledelayedexpansion
echo 作者:phenix
echo.
echo 邮箱:279682817@qq.com
echo.
echo 查找目录中以英文开头的值，并过滤关键词和文件类型，替换为B,比如要查找开头为Sys的，包含Role Dept关键词，包含java xml的文件,分别输入Sys,Role Dept,java xml和B
echo.
set /p lujing=请输入路径:
set /p name=请输入被替换值:
set /p filtername=请输入过滤词，空格分开:
set /p fixname=请输入过滤文件类型，空格分开:
if "!filtername!" equ "" (
set filtername=.
)
if "!fixname!" equ "" (
set fixname=.
)
echo 查找到的文件如下:
for /f "usebackq tokens=*" %%i in (`dir /s /a-d /b "!lujing!"^|findstr /r "\<!name!"^|findstr /r  "!filtername!"^|findstr /r  "!fixname!"`) do (
echo %%i
)
set /p conf=确认重命名?1全部重命名不提示2重命名每个文件提示非12否:
if "!conf!" equ "1" (
call :changefile
) else (
if "!conf!" equ "2" (
call :changefile
)
)
echo 完毕!
pause
exit

:changefile
set /p rname=请输入替换值:
for /f "usebackq tokens=*" %%m in (`dir /s /a-d /b "!lujing!"^|findstr /r "\<!name!"^|findstr /r  "!filtername!"^|findstr /r  "!fixname!"`) do (
set fname=%%m
if "!conf!" equ "1" (
call set "val=%%fname:!name!=!rname!%%"
move /y "!fname!" "!val!"
) else (
if "!conf!" equ "2" (
set cfconf=
set /p cfconf=确认重命名!fname!?1是非1否:
if "!cfconf!" equ "1" (
call set "val1=%%fname:!name!=!rname!%%"
move /y "!fname!" "!val1!"
)
)
)
)