安装包注册表分析工具（批处理）

声明：本人水平有限，欢迎批评指正，禁止用于非法目的，请保持代码纯净和完整

 

工具说明：可以定制分析安装前后注册表的变化的工具

 

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
TITLE 安装包注册表分析工具
ECHO 安装包注册表分析工具
ECHO.
ECHO make by humors221
ECHO.
SET /P INPUT=请输入安装包路径：
SET /P ISCOMP=请依次输入HKEY_LOCAL_MACHINE,HKEY_CURRENT_USER,HKEY_CLASSES_ROOT,HKEY_USERS,HKEY_CURRENT_CONFIG是否比较，1表示比较，0表示不比较，如11000:
SET ISHKLM=!ISCOMP:~0,1!
SET ISHKCU=!ISCOMP:~1,1!
SET ISHKCR=!ISCOMP:~2,1!
SET ISHKU=!ISCOMP:~3,1!
SET ISHKCC=!ISCOMP:~4,1!
SET FILE1=OLD
SET FILE2=NEW
ECHO.
ECHO 开始分析旧注册表
CALL :EXPORTREG !FILE1!
ECHO.
ECHO 结束分析旧注册表
START /WAIT !INPUT!
ECHO.
ECHO 开始分析新注册表
CALL :EXPORTREG !FILE2!
ECHO.
ECHO 结束分析新注册表
ECHO.
ECHO 开始比较新旧注册表
CALL :COMPREG !FILE1! !FILE2!
ECHO.
ECHO 结束比较新旧注册表
ECHO.
ECHO 分析完毕！请查看REGCOMP.TXT
PAUSE
EXIT

:EXPORTREG
CALL :DELREG %1
IF !ISHKLM! EQU 1 (
ECHO 导出HKEY_LOCAL_MACHINE数据
REG EXPORT HKLM\ HKEY_LOCAL_MACHINE_%1.TXT
)
IF !ISHKCU! EQU 1 (
ECHO 导出HKEY_CURRENT_USER数据
REG EXPORT HKCU\ HKEY_CURRENT_USER_%1.TXT
)
IF !ISHKCR! EQU 1 (
ECHO 导出HKEY_CLASSES_ROOT数据
REG EXPORT HKCR\ HKEY_CLASSES_ROOT_%1.TXT
)
IF !ISHKU! EQU 1 (
ECHO 导出HKEY_USERS数据
REG EXPORT HKU\ HKEY_USERS_%1.TXT
)
IF !ISHKCC! EQU 1 (
ECHO 导出HKEY_CURRENT_CONFIG数据
REG EXPORT HKCC\ HKEY_CURRENT_CONFIG_%1.TXT
)
EXIT /B

:COMPREG
ECHO.>REGCOMP.TXT
IF !ISHKLM! EQU 1 (
ECHO 比较HKEY_LOCAL_MACHINE数据
FC /U /W /LB99999 HKEY_LOCAL_MACHINE_%1.TXT HKEY_LOCAL_MACHINE_%2.TXT>>REGCOMP.TXT
)
IF !ISHKCU! EQU 1 (
ECHO 比较HKEY_CURRENT_USER数据
FC /U /W /LB99999 HKEY_CURRENT_USER_%1.TXT HKEY_CURRENT_USER_%2.TXT>>REGCOMP.TXT
)
IF !ISHKCR! EQU 1 (
ECHO 比较HKEY_CLASSES_ROOT数据
FC /U /W /LB99999 HKEY_CLASSES_ROOT_%1.TXT HKEY_CLASSES_ROOT_%2.TXT>>REGCOMP.TXT
)
IF !ISHKU! EQU 1 (
ECHO 比较HKEY_USERS数据
FC /U /W /LB99999 HKEY_USERS_%1.TXT HKEY_USERS_%2.TXT>>REGCOMP.TXT
)
IF !ISHKCC! EQU 1 (
ECHO 比较HKEY_CURRENT_CONFIG数据
FC /U /W /LB99999 HKEY_CURRENT_CONFIG_%1.TXT HKEY_CURRENT_CONFIG_%2.TXT>>REGCOMP.TXT
)
CALL :DELREG %1
CALL :DELREG %2
EXIT /B

:DELREG
echo 删除HKEY_LOCAL_MACHINE_%1.TXT HKEY_CURRENT_USER_%1.TXT HKEY_CLASSES_ROOT_%1.TXT HKEY_USERS_%1.TXT HKEY_CURRENT_CONFIG_%1.TXT文件
DEL /Q HKEY_LOCAL_MACHINE_%1.TXT HKEY_CURRENT_USER_%1.TXT HKEY_CLASSES_ROOT_%1.TXT HKEY_USERS_%1.TXT HKEY_CURRENT_CONFIG_%1.TXT
EXIT /B