【NOIP 2011】mayan游戏 - Pascal

mayan游戏

题目描述

Mayan puzzle是最近流行起来的一个游戏。游戏界面是一个 7 行5 列的棋盘，上面堆放着一些方块，方块不能悬空堆放，即方块必须放在最下面一行，或者放在其他方块之上。游戏通关是指在规定的步数内消除所有的方块，消除方块的规则如下：

1 、每步移动可以且仅可以沿横向（即向左或向右）拖动某一方块一格：当拖动这一方块时，如果拖动后到达的位置（以下称目标位置）也有方块，那么这两个方块将交换位置（参见输入输出样例说明中的图6 到图7 ）；如果目标位置上没有方块，那么被拖动的方块将从原来的竖列中抽出，并从目标位置上掉落（直到不悬空，参见下面图1 和图2）；

2 、任一时刻，如果在一横行或者竖列上有连续三个或者三个以上相同颜色的方块，则它们将立即被消除（参见图1 到图3）。

- 注意：
a) 如果同时有多组方块满足消除条件，几组方块会同时被消除（例如下面图4 ，三个颜色为1 的方块和三个颜色为 2 的方块会同时被消除，最后剩下一个颜色为 2 的方块）。
b) 当出现行和列都满足消除条件且行列共享某个方块时，行和列上满足消除条件的所有方块会被同时消除（例如下面图5 所示的情形，5 个方块会同时被消除）。

3 、方块消除之后，消除位置之上的方块将掉落，掉落后可能会引起新的方块消除。注意：掉落的过程中将不会有方块的消除。

上面图1 到图 3 给出了在棋盘上移动一块方块之后棋盘的变化。棋盘的左下角方块的坐标为（0, 0 ），将位于（3, 3 ）的方块向左移动之后，游戏界面从图 1 变成图 2 所示的状态，此时在一竖列上有连续三块颜色为4 的方块，满足消除条件，消除连续3 块颜色为4 的方块后，上方的颜色为3 的方块掉落，形成图 3 所示的局面。

输入格式：

输入文件mayan.in，共 6 行。

第一行为一个正整数n ，表示要求游戏通关的步数。

接下来的5 行，描述 7*5 的游戏界面。每行若干个整数，每两个整数之间用一个空格隔开，每行以一个0 结束，自下向上表示每竖列方块的颜色编号（颜色不多于10种，从1 开始顺序编号，相同数字表示相同颜色）。

输入数据保证初始棋盘中没有可以消除的方块。

输出格式：

输出文件名为mayan.out。

如果有解决方案，输出 n 行，每行包含 3 个整数x，y，g ，表示一次移动，每两个整数之间用一个空格隔开，其中（x ，y）表示要移动的方块的坐标，g 表示移动的方向，1 表示向右移动，-1表示向左移动。注意：多组解时，按照 x 为第一关健字，y 为第二关健字，1优先于-1 ，给出一组字典序最小的解。游戏界面左下角的坐标为（0 ，0 ）。

如果没有解决方案，输出一行，包含一个整数-1。

Sample input

3
1 0
2 1 0
2 3 4 0
3 1 0
2 4 3 4 0

Sample output

2 1 1
3 1 1
3 0 1

输入输出样例说明

　　按箭头方向的顺序分别为图6 到图11

　　样例输入的游戏局面如上面第一个图片所示，依次移动的三步是：（2 ，1 ）处的方格向右移动，（3，1 ）处的方格向右移动，（3 ，0）处的方格向右移动，最后可以将棋盘上所有方块消除。

数据范围

　　对于30% 的数据，初始棋盘上的方块都在棋盘的最下面一行；

　　对于100%的数据，0 < n≤5 。
　　

题解

　　来自NOIP 2011 day1的第三题，一道非常暴力的搜索题，这种类型的题目在NOIP 2015 day1的第三题也出现过。放在第三题，非常考验选手对代码的熟练程度，在短时间的编译出较长的无误代码，也是一种难点。说的很简单就两个字“暴力”，要打起来难度还是有的。
　　
　　对题目分析后，无非就几种做法，那这里分享几个技巧：
　　 1. 对每个搜到的点，除非其左边为空，否则仅向右/下两个方向搜索。
　　 2. 模拟搜索到的两个点交换后，先记录下能消去的点，之后再一起消除。
　　 3. 通过对最后一行判断是否全部消除，来判断整个棋盘是否全部消除。

　　附上Pascal代码：
　　

program noip2011_mayan;
type sta=array[-1..11,-1..11] of longint;
var f:sta;
    x,y,z:array[-1..11] of longint;
    n,i,j,k,a,b,g,t:longint;

procedure print;
begin
for i:=1 to n do
   writeln(x[i],' ',y[i],' ',z[i]);
   halt;
end;

function check(newf:sta):boolean;
var i,j:longint;
begin
   for i:=0 to 4 do
     if newf[i,0] <>0 then
         exit(false);
   exit(true);
end;

procedure dfs(k:longint;newf:sta);
  forward;

procedure checkup(k:longint;newf:sta);
var tmp:array[0..5,0..7] of boolean;
    pan:boolean;
    i,j,g,t:longint;
begin
    pan:=false;
    while not pan do
        begin
           fillchar(tmp,sizeof(tmp),false);
           for i:=0 to 4 do
              for j:=0 to 7 do
                 begin
                  if newf[i,j] = 0 then continue;
                  if (newf[i,j]=newf[i,j+1]) and (newf[i,j]=newf[i,j+2]) then
                     begin
                       tmp[i,j]:=true;
                       tmp[i,j+1]:=true;
                       tmp[i,j+2]:=true;
                     end;
                  if (newf[i,j]=newf[i+1,j]) and (newf[i,j]=newf[i+2,j]) then
                      begin
                        tmp[i,j]:=true;
                        tmp[i+1,j]:=true;
                        tmp[i+2,j]:=true;
                      end;
                  end;
          for i:=0 to 4 do
            for j:=0 to 7 do
              if tmp[i,j] then newf[i,j]:=0;
          pan:=true;
          for i:=0 to 4 do
            for j:=0 to 7 do
              if newf[i,j] = 0 then
                begin
                  t:=j;
                  while (t<=7) and (newf[i,t]=0) do inc(t);
                  if t>7 then break;;
                  for g:=0 to t-j do
                    begin
                      newf[i,g+j]:=newf[i,g+t];
                      newf[i,g+t]:=0;
                    end;
                  pan:=false;
                end;
        end;
    if (k<> n +1) and (check(newf)) then exit;
    if (k=n+1) and (check(newf)) then print;
    dfs(k,newf);
  end;

procedure dfs(k:longint;newf:sta);
var i,j,t:longint;
begin
  if k>n then exit;
  for i:=0 to 4 do
    for j:=0 to 7 do
      begin
        if newf[i,j]=0 then break;
        if (newf[i-1,j]=0) and (i<>0) and(newf[i,j]<>newf[i-1,j]) then
          begin
          x[k]:=i;y[k]:=j;z[k]:=-1;
          t:=newf[i,j];newf[i,j]:=newf[i-1,j];newf[i-1,j]:=t;
          checkup(k+1,newf);
          x[k]:=0;y[k]:=0;z[k]:=0;
          t:=newf[i,j];newf[i,j]:=newf[i-1,j];newf[i-1,j]:=t;
          end;
        if i=4 then continue;
        if newf[i,j]=newf[i+1,j] then continue;
        x[k]:=i;y[k]:=j;z[k]:=1;
        t:=newf[i,j];newf[i,j]:=newf[i+1,j];newf[i+1,j]:=t;
        checkup(k+1,newf);
        t:=newf[i,j];newf[i,j]:=newf[i+1,j];newf[i+1,j]:=t;
        x[k]:=0;y[k]:=0;z[k]:=0;
      end;
end;

begin
  readln(n);
  for i:=0 to 4 do
  begin
    b:=-1;
    repeat
       inc(b);
       read(f[i,b]);
    until f[i,b]=0;
  end;
  dfs(1,f);
  writeln('-1');
end.