【4001】产生数

产生数

题目描述

给出一个整数 n（n<10^30) 和 k 个变换规则（k<=15）。
规则：一位数可变换成另一个一位数，规则的右部不能为零。
例如：n=234。有规则（k＝2）：
2－>5
3－>6
上面的整数 234 经过变换后可能产生出的整数为（包括原数）:
234 534 264 564 共 4 种不同的产生数
问题：给出一个整数 n 和 k 个规则。
求出：经过任意次的变换（0次或多次），能产生出多少个不同整数。

输入

键盘输人，格式为：
n k
x1 y1
x2 y2
… …
xn yn

输出

一个整数（满足条件的个数）

题解

　　一个挺简单的题目，外加一点乘法原理就行了，下面引用郭仲英老师的题解：
　　本题只需计数而不需要求出具体方案，可以用乘法原理直接进行计数。

　　设F[i]表示从数字i出发可以变换成的数字个数（这里的变换可以是直接变换，也可以是间接变换，比如样例1可以变换成2，而2又可以变换成3，所以1也可以变换成3；另外自己本身不变换也是一种情况），那么对于一个长度为m位的整数a，根据乘法原理，能产生的不同的整数的个数为：F[a[1]]F[a[2]]*F[a[31]]…*F[a[m-1]]*F[a[m]]。

　　下面的问题是如何求F[i]呢？由于这些变换规则都是反映的数字与数字之间的关系，所以定义一个布尔型的二维数组g[0..9,0..9]来表示每对数字之间是否可以变换，初始时都为false；根据输入的数据，如果数字i能直接变换成数字j，那么g[i,j]置为true，这是通过一次变换就能得到的；接下来考虑那些间接变换可得到的数字，很明显：如果i可以变换成k，k又可以变换成j，那么i就可以变换成j，即：

    for k:=0 to 9 do

         for  i:=0 to 9 do

               for j:=0 to 9 do

                    g[i,j]:=g[i,j] or (g[i,k] and g[k,j]);

　　最后还要注意，当a很大时，解的个数很大，所以要用高精度运算。
　　下面附上Pascal代码：
　　

program m4001;
var u:array[0..9,0..9] of boolean;
    f:array[0..9] of longint;
    a,b:array[0..999] of longint;
    m,i,j,x,y,g,k,h,z,t:longint;
    n:string;

procedure print;
begin
  for i:= g downto 1 do
    write(a[i]);
  writeln;
end;

procedure work(k:integer);//高精度
var i:longint;
begin
y:=0;
for i:=1 to g do
  begin
    z:=a[i]*k+y;
    a[i]:=z mod 10;
    y:=z div 10;
  end;
  while y>0 do
    begin
      g:=g+1;
      a[g]:=y mod 10;
      y:=y div 10;
    end;
end;

begin
readln(n);
readln(k);
for i:=1 to k do
  begin
    readln(x,y);
    u[x,y]:=true;
  end;
for k:=0 to 9 do
  for i:=0 to 9 do
    for j:=0 to 9 do
      u[i,j]:=u[i,j] or (u[i,k] and u[k,j]);
for i:=0 to 9 do
  for j:=0 to 9 do
     if (u[i,j]) and (i <> j)then inc(f[i]);

g:=1;
a[1]:=1;
for i:=1 to length(n) do
  begin
  val(n[i],k);
  if f[k]>0 then
  work(f[k]+1);  //f[k]为第i位为k的数可以转变成的数的个数，但在乘法时还得加上其本身，因而乘f[k]+1，如果f[k]为0，那f[k]+1=1，乘了也白乘。
  end;
print;
end.