配置文件加载组件

在开发过程中，按照一定的规则去写配置文件，就可以方便的进行引用。
组件代码：
config.xml

<?xml version="1.0" encoding="utf-8"?>
<configuration>
	<data id="info" name="信息" remark="1">
		文字信息
	</data>
</configuration>

package pizazz.flex4.resource.component.configloader{
	public class ConfigItem{
		private var _id:String = "";
		private var _name:String = "";
		private var _remark:String = "";
		private var _content:String = "";

		public function get id():String{
			return _id;
		}

		public function get name():String{
			return _name;
		}

		public function get remark():String{
			return _remark;
		}

		public function get content():String{
			return _content;
		}

		public function ConfigItem(id:String, name:String, 
				remark:String, content:String){
			_id = id;
			_name = name;
			_remark = remark;
			_content = content;
		}
	}
}

package pizazz.flex4.resource{
	import flash.utils.Dictionary;
	import mx.rpc.events.ResultEvent;
	import pizazz.flex4.remote.HttpConn;
	import pizazz.flex4.resource.component.configloader.ConfigItem;

	public class ConfigLoader{
		private static const _config:Dictionary = new Dictionary();
		private var _key:Object;

		public function ConfigLoader(){}

		public static function getConfigById(key:String, 
				id:String = null):ConfigItem{
			var _param:Object = getConfig(key);
			return _param.hasOwnProperty(id) ? _param[id] 
				as ConfigItem : new ConfigItem("null", null, null, null);
		}

		public static function getConfig(key:String):Object{
			return _config.hasOwnProperty(key) ? _config[key] : {};
		}

		public static function setConfig(key:Object, url:String):void{
			const _loader:ConfigLoader = new ConfigLoader();
			_loader._key = key;
			HttpConn.getRemote(url, _loader.configResult, 
				{"resultFormat": "e4x"}).send();
		}

		private function configResult(event:ResultEvent):void{
			var _list:XMLList = (event.result as XML).data;
			var _item:Object = {};
			for each(var _xml:XML in _list){
				var id:String = _xml["@id"];
				var name:String = _xml["@name"];
				var remark:String = _xml["@remark"];
				var content:String = _xml.text();
				_item[id] = new ConfigItem(id, name, remark, content);
			}
			if(_key != null){
				_config[_key] = _item;
			}
		}
	}
}

组件执行：

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
			   xmlns:s="library://ns.adobe.com/flex/spark" 
			   xmlns:mx="library://ns.adobe.com/flex/mx" 
			   minWidth="955" minHeight="600" creationComplete="init()">
	<s:layout>
		<s:HorizontalLayout />
	</s:layout>
	<fx:Script>
		<![CDATA[
			import mx.controls.Alert;
			import pizazz.flex4.resource.ConfigLoader;
			import pizazz.flex4.resource.component.configloader.ConfigItem;

			private function init():void{
				ConfigLoader.setConfig("config", "config.xml");
			}

			private function show():void{
				var _item:ConfigItem = ConfigLoader.getConfigById("config", 
					"info");
				Alert.show(_item.content, _item.name, Number(_item.remark));
			}
		]]>
	</fx:Script>
	<s:Button width="100" label="信息" click="show()" />
</s:Application>

视图：
[img]http://dl.iteye.com/upload/attachment/341861/03669489-f170-364d-9abc-8e0ec412cf79.png[/img]