HOWTO：在 Visual Basic 中自动运行 Microsoft Excel

最新推荐文章于 2024-11-18 18:58:24 发布
最新推荐文章于 2024-11-18 18:58:24 发布
阅读量632 收藏
点赞数
文章标签： microsoft basic excel integer alignment 服务器

HOWTO：在 Visual Basic 中自动运行 Microsoft Excel

更多信息

<script type="text/javascript">loadTOCNode(1, 'moreinformation');</script>
有两种方法可以控制自动化服务器：通过使用晚期绑定或早期绑定。若使用晚期绑定，则在声明运行时和自动化服务器为“对象”之前不绑定方法。若使用早期绑定，则您的应用程序在设计阶段知道要与之通信的对象的确切类型，并可以作为一个特定类型声明其对象。本示例使用早期绑定，早期绑定被认为是在多数情况下都很适用的方法，因为它可以提供更高的性能和更好的类型安全性。

要早期绑定到自动化服务器，您需要设置对该服务器类型库的引用。在 Visual Basic 中，该操作是通过“项目”|“引用”菜单下的“引用”对话框完成的。对于本示例，您需要向 Excel 的类型库中添加一个引用，然后才能运行代码。关于如何添加引用，请参见下面的步骤。

生成自动化示例

<script type="text/javascript">loadTOCNode(2, 'moreinformation');</script>
1.启动 Visual Basic，新建一个标准 EXE 项目。默认情况下会创建 Form1。
2.选择“项目”|“引用”以显示“引用”对话框。向下滚动列表，直到找到“Microsoft Excel 10.0 对象库”，然后选择此项目以向 Excel 2002 中添加一个引用。如果列表中未显示该项目，请检查是否已正确安装了 Excel 2002。

注意：如果正在自动运行 Microsoft Office Excel 2003，则该类型库在“引用”列表中显示为“Microsoft Excel 11.0 对象库”。如果正在自动运行 Microsoft Excel 2000，则该类型库在“引用”列表中显示为“Microsoft Excel 9.0 对象库”，如果您使用的是 Microsoft Excel 97，则该类型库显示为“Microsoft Excel 8.0 对象库”。
3.单击“确定”，关闭“引用”对话框。
4.将 CommandButton 添加到 Form1 中。
5.在 Form1 的代码窗口中，插入下面的代码：
   Option Explicit
   
   Private Sub Command1_Click()
      Dim oXL As Excel.Application
      Dim oWB As Excel.Workbook
      Dim oSheet As Excel.Worksheet
      Dim oRng As Excel.Range
      

      'On Error GoTo Err_Handler
      
   ' Start Excel and get Application object.
      Set oXL = CreateObject("Excel.Application")
      oXL.Visible = True
      
   ' Get a new workbook.
      Set oWB = oXL.Workbooks.Add
      Set oSheet = oWB.ActiveSheet
      
   ' Add table headers going cell by cell.
      oSheet.Cells(1, 1).Value = "First Name"
      oSheet.Cells(1, 2).Value = "Last Name"
      oSheet.Cells(1, 3).Value = "Full Name"
      oSheet.Cells(1, 4).Value = "Salary"
      

   ' Format A1:D1 as bold, vertical alignment = center.
      With oSheet.Range("A1", "D1")
         .Font.Bold = True
         .VerticalAlignment = xlVAlignCenter
      End With
      
   ' Create an array to set multiple values at once.
      Dim saNames(5, 2) As String
      saNames(0, 0) = "John"
      saNames(0, 1) = "Smith"
      saNames(1, 0) = "Tom"
      saNames(1, 1) = "Brown"
      saNames(2, 0) = "Sue"
      saNames(2, 1) = "Thomas"
      saNames(3, 0) = "Jane"

      saNames(3, 1) = "Jones"
      saNames(4, 0) = "Adam"
      saNames(4, 1) = "Johnson"
      
    ' Fill A2:B6 with an array of values (First and Last Names).
      oSheet.Range("A2", "B6").Value = saNames
      
    ' Fill C2:C6 with a relative formula (=A2 & " " & B2).
      Set oRng = oSheet.Range("C2", "C6")
      oRng.Formula = "=A2 & "" "" & B2"
      
    ' Fill D2:D6 with a formula(=RAND()*100000) and apply format.
      Set oRng = oSheet.Range("D2", "D6")
      oRng.Formula = "=RAND()*100000"
      oRng.NumberFormat = "$0.00"
      
    ' AutoFit columns A:D.
      Set oRng = oSheet.Range("A1", "D1")
      oRng.EntireColumn.AutoFit
      
    ' Manipulate a variable number of columns for Quarterly Sales Data.
      Call DisplayQuarterlySales(oSheet)
      
    ' Make sure Excel is visible and give the user control
    ' of Microsoft Excel's lifetime.
      oXL.Visible = True
      oXL.UserControl = True
      
    ' Make sure you release object references.
      Set oRng = Nothing
      Set oSheet = Nothing
      Set oWB = Nothing
      Set oXL = Nothing
      
   Exit Sub
   Err_Handler:
      MsgBox Err.Description, vbCritical, "Error: " & Err.Number
   End Sub
   
   Private Sub DisplayQuarterlySales(oWS As Excel.Worksheet)
      Dim oResizeRange As Excel.Range
      Dim oChart As Excel.Chart
      Dim iNumQtrs As Integer
      Dim sMsg As String
      Dim iRet As Integer
      
    ' Determine how many quarters to display data for.
      For iNumQtrs = 4 To 2 Step -1
         sMsg = "Enter sales data for" & Str(iNumQtrs) & " quarter(s)?"
         iRet = MsgBox(sMsg, vbYesNo Or vbQuestion _
            Or vbMsgBoxSetForeground, "Quarterly Sales")
         If iRet = vbYes Then Exit For
      Next iNumQtrs
      

      sMsg = "Displaying data for" & Str(iNumQtrs) & " quarter(s)."
      MsgBox sMsg, vbMsgBoxSetForeground, "Quarterly Sales"
      
    ' Starting at E1, fill headers for the number of columns selected.
      Set oResizeRange = oWS.Range("E1", "E1").Resize(ColumnSize:=iNumQtrs)

      oResizeRange.Formula = "=""Q"" & COLUMN()-4 & CHAR(10) & ""Sales"""
      
    ' Change the Orientation and WrapText properties for the headers.
      oResizeRange.Orientation = 38
      oResizeRange.WrapText = True
      
    ' Fill the interior color of the headers.
      oResizeRange.Interior.ColorIndex = 36
      
    ' Fill the columns with a formula and apply a number format.
      Set oResizeRange = oWS.Range("E2", "E6").Resize(ColumnSize:=iNumQtrs)
      oResizeRange.Formula = "=RAND()*100"
      oResizeRange.NumberFormat = "$0.00"
      
    ' Apply borders to the Sales data and headers.
      Set oResizeRange = oWS.Range("E1", "E6").Resize(ColumnSize:=iNumQtrs)
      oResizeRange.Borders.Weight = xlThin
      
    ' Add a Totals formula for the sales data and apply a border.
      Set oResizeRange = oWS.Range("E8", "E8").Resize(ColumnSize:=iNumQtrs)
      oResizeRange.Formula = "=SUM(E2:E6)"
      With oResizeRange.Borders(xlEdgeBottom)
         .LineStyle = xlDouble
         .Weight = xlThick
      End With
      
    ' Add a Chart for the selected data
      Set oResizeRange = oWS.Range("E2:E6").Resize(ColumnSize:=iNumQtrs)
      Set oChart = oWS.Parent.Charts.Add
      With oChart
         .ChartWizard oResizeRange, xl3DColumn, , xlColumns
         .SeriesCollection(1).XValues = oWS.Range("A2", "A6")
            For iRet = 1 To iNumQtrs
               .SeriesCollection(iRet).Name = "=""Q" & Str(iRet) & """"
            Next iRet
         .Location xlLocationAsObject, oWS.Name
      End With
      
    ' Move the chart so as not to cover your data.
      With oWS.Shapes("Chart 1")
         .Top = oWS.Rows(10).Top
         .Left = oWS.Columns(2).Left

      End With
      
    ' Free any references.
      Set oChart = Nothing
      Set oResizeRange = Nothing
   
   End Sub
6.按 F5 键运行该项目。
 
jeffzsy
关注
HOW TO： 从 Visual C# .NET 使用自动化运行 Office 宏 (From MSDN)
10-09 2469
有关本文的 Microsoft Visual Basic .NET 版本，请参见 CHS306682。有关本文的 Microsoft Visual C++ 版本，请参见 CHS306686。 本任务的内容概要 创建包含宏的 Office 文档 创建 Visual C# .NET 自动化客户端 运行并测试自动化客户端参考概要使用 Microsoft Off
vfb查询excel
qq_24499417的博客
06-19 686
visual free basic 通过ado连接excel文件。注意程序的位数和驱动程序的位数要保持一致。 #include once "Afx/CADODB/CADODB.inc" DIM pRecordset AS CAdoRecordset Dim r As CVAR = "" Dim f As CAdoField Dim arr() As CVAR DIM Connstr AS CVAR = "Provider=Microsoft.ace.OLEDB.12.0;Extended proper
如何用VBA在打开EXCEL文件时自动运行宏
热门推荐
冯修聿
08-05 1万+
例子： Sub Auto_open() '一种方法是将宏的名称改为这个即可 MsgBox "欢迎回来继续学习VBA！" End Sub 还有一种方法就是使用VBE在工作簿的Open事件中编写VBA过程。  ...
VisualFreeBasic编程教程(从零开始学或VB进阶)
yfvb2010的专栏
02-25 1万+
VisualFreeBasic 是 可视化 FreeBASIC 集成编程环境现在我来带大家入门到美妙而神奇的编程世界！为了能顺利使用 VisualFreeBasic ，必须了解以下内容一、所有窗口和控件以【句柄】控制，VB6是类控制 。二、显示窗口用 Form2_Show (父窗口, True|False) （Form2 是窗口名，根据软件修改）。三、关闭窗口用 CloseForm 句柄。四、代码...
中文版的:VisualFreeBasic 3.9.3
过客2019
04-25 2910
因为第一门语言是BASIC,最早的开发工具也是QuickBASIC，所以对BASIC一直怀念。今天找到一个汉化的FreeBASIC,有兴趣的朋友去下载一个体验一下。顺便点个赞。下载地址：http://www.yfvb.com/soft48.html软件简介相关论坛、评论、教程、帮助等等....类似VisualBasic6的FreeBasic语言集成开发环境。拥有和VB6高度相似的语法规则，具有和C...
Excel VBA教程–如何使用Visual Basic在电子表格中编写代码
08-21 5551
介绍 (Introduction) This is a tutorial about writing code in Excel spreadsheets using Visual Basic for Applications (VBA). 这是一个有关使用Visual Basic for Applications(VBA)在Excel电子表格中编写代码的教程。 Excel is one of...
(257819) HOWTO：在 Visual Basic 或 VBA 中使用 ADO 来处理 Excel 数据
10-18 2188
概要本文介绍如何使用 ActiveX Data Objects (ADO) 来处理数据源为 Microsoft Excel 电子表格的数据。本文还着重讨论特定于 Excel 的语法问题和限制。本文不讨论 OLAP 或 PivotTable 技术，或 Excel 数据的其他特殊用法。有关其他信息，请单击下面的文章编号，查看 Microsoft 知识库中相应的文章： 303814 HOWT
text_how-to-use-microsoft-excel-v1.1:如何使用 Microsoft Excel，v1.1
06-18
在这个"如何使用Microsoft Excel，v1.1"的指南中，我们将会深入探讨Excel的关键功能和实用技巧，帮助用户充分利用这款工具。 首先，让我们从基础开始。Excel的核心是工作簿，由多个工作表组成，每个工作表又包含一...
将数据从 Visual Basic 传输到 Excel
江湖·郎中·路
08-04 2648
INFO：将数据从 Visual Basic 传输到 Excel 的方法适用于 概要本文介绍将数据从 Microsoft Visual Basic 应用程序传输到 Microsoft Excel 的多种方法。本文还介绍了每种方法的优缺点，这样您可以选择最适合您的解决方案。 更多信息将数据传输到 Excel 工作簿最常用的方法是“自动化”功能。“自动化”功能为您提供了指定数据在工作簿
Excel中的宏、VBA
RichardYang2020的博客
09-15 3151
宏通过使我们执行的大多数日常工作自动化来简化我们的工作生活。Excel 中的宏由 Visual Basic for Applications 驱动。Step 2)单击自定义功能区将复选框标记为开发人员选项点击确定按钮Step 2)单击自定义功能区将复选框标记为开发人员选项点击确定按钮Step 3)Step 3)Step 4)在驱动器 C 中创建一个名为 Bank Receipts 的文件夹粘贴您下载的 receives.csv 文件Step 4)Step 5)单击开发人员选项卡。
INFO：使用 Visual Studio .NET 开发 Microsoft Office 解决方案 (From MSDN)
10-09 1319
概要开发人员在使用 Microsoft Visual Studio .NET 来生成使用 Microsoft Office 系列产品的解决方案时，可参考本文。本文是 Microsoft Developer Network (MSDN) 中有关使用 Visual Studio 6.0 进行 Office 开发的内容的补充材料，而 MSDN 中有关使用 Visual Studio 6.0 进行 O
如何为 Excel 工作表函数创建 Visual Basic 自动化加载项
陈志明的专栏
08-18 2707
如何为 Excel 工作表函数创建 Visual Basic 自动化加载项概要loadTOCNode(1, summary);在 Microsoft Excel 2000 中，不能直接从工作表单元格公式中调用组件对象模型 (COM) 加载项中的函数，而是必须为该 COM 加载项函数创建一个 Visual Basic for Applications (VBA) 包装，以此来间接
RHCE——系统的延迟任务及定时任务
Curtis0980的博客
11-17 458
是一个后台运行的守护进程，用于调整内核中运行的系统时钟和时钟服务器同步。SSH是一个守护进程，负责实时监听客户端请求，并进行处理。分钟执行，如果今天的这个时间点已经过了，则明天执行。定时任务执行时如果遇到系统处于关闭状态，那么在开启时。任务执行时如果遇到系统处于关闭状态，那么在开启时。算机上工作，也可以在一台不同的远程计算机上工作。如果不指定用户，则表示编辑当前用户的。文件内容，如果不指定用户，则表示显示当前用户的。，写入此文件中的用户会被禁止使用定时任务。的别名，可列出目前系统上面的所有该用户的。
“乐鑫组件注册表”简介
最新发布
乐鑫 Espressif
11-18 658
​ 当启动一个新的开发项目时，开发者们通常会利用库和驱动程序等现有的代码资源。这种做法不仅节省时间，还简化了项目的维护工作。本文将深入探讨乐鑫组件注册表的概念及其核心理念，旨在指导您高效地使用和贡献组件。
C# 面向对象的接口
hccee的博客
11-18 411
C# 面向对象的多接口详解
【微软：多模态基础模型】（4）统一视觉模型
youcans的博客
11-18 255
2023 年，微软在 CVPR2023 发表论文「 多模态基础模型：从专家到通用助手 」（Multimodal Foundation Models: From Specialists to General-Purpose Assistants） 。本文全面综述了多模态基础模型的分类和演化，这些模型展示了视觉和视觉语言能力，并重点关注了从专家向通用助手的过渡。
亿咖通科技应邀出席微软汽车行业智享会，分享ECARX AutoGPT全新实践
高工智能汽车
11-18 467
作为微软携手汽车智能化领域合作伙伴的重要活动，本届微软汽车行业智享会以“AI赋能，扬帆出海”为主题，在以AI大模型主导的智能化竞争力，逐步成为产业和企业新的发展高地和战略支点的背景下，邀请行业专家、整车品牌与科技企业参与，分享对AI大模型前沿科技的探索和实践心得，洞见未来AI时代浪潮下汽车行业的发展趋势，实现全球化业务拓展，亿咖通科技作为微软在汽车智能化领域的全球生态合作伙伴，应邀出席本届活动，并分享了在双方合作背景下的技术优势加持与研发推进。
马斯克诉OpenAI新进展：加入微软等被告
haleycat的博客
11-18 367
埃隆·马斯克再次升级对OpenAI的诉讼，新增微软等被告，诉状揭示了他与OpenAI早期的矛盾，包括未能成为CEO。邮件中，OpenAI首席科学家伊利亚·苏斯克沃表达了对马斯克可能掌控AGI的担忧，认为这种结构可能导致独裁。苏斯克沃对OpenAI现CEO萨姆·阿尔特曼的动机也表示怀疑，显示出内部矛盾加剧。
使用MSChart控件从Visual Basic中提取数据库图形化展示
资源包中包含一个Visual Basic项目文件（Project1.vbp），一个窗体文件（Form1.frm）及其对应的资源文件（Form1.frx），一个HTML文档（howto_mschart_graph_database.html）提供相关操作的指导，以及一个Microsoft ...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值