uboot 第一阶段源码分析

最新推荐文章于 2024-03-20 20:08:14 发布
最新推荐文章于 2024-03-20 20:08:14 发布
阅读量374 收藏 2
点赞数
分类专栏： linux设备驱动 文章标签： linux
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/jhertz/article/details/126718745
版权

uboot start.s源码分析

最近面试不少被问到了启动流程相关的东西，自己总结下吧。

linux操作系统的启动流程可以分为 bootloader-->kernel-->rootfs，其中uboot是一种常用的bootloader工具，该篇文章就简单写一下自己对bootloader过程的理解。

bootloader制作uboot

  1. 下载u-boot源码
    u-boot源码下载地址

  2. 下载对应交叉编译工具并配置到环境变量
    工具链下载地址
    sudo apt-get install libc6-i386 安装32位库支持
    .zshrc文件加上 export PAHT=$PATH:/usr/arm-linux-toolschains4.4.3/bin

  3. make smdk2410_config 确定平台
    生成include/config.mk include/config.h

  4. make 生成uboot.bin文件

uboot代码体系

image-20220720161018449
Bootloader的启动过程又分为两个阶段stage1和stage2。

stage1全部由汇编编写，即start.s，它的主要工作是:

  1. 初始化硬件设备
  2. 为加载Bootlodader的stage2准备RAM空间
  3. 拷贝Bootloader的stage2到RAM空间
  4. 设置好堆栈段为stager2的C语言环境做准备。

stage2全部由C语言编写，其的主要工作是:

  1. 初始化本阶段要使用到的硬件设备
  2. 将内核映像和根文件系统映像从 flash 上读到RAM
  3. 调用内核

start.s代码分析

/* 汇编中的.globl或.global = C语言中的extern */
.globl _start	/
_start:	b	start_code
	ldr	pc, _undefined_instruction		/* 未定义异常 */
	ldr	pc, _software_interrupt			/* 软中断 */
	ldr	pc, _prefetch_abort				/* 预取中止 */
	ldr	pc, _data_abort					/* 数据中止 */
	ldr	pc, _not_used					/* 未使用 */
	ldr	pc, _irq						/* 中断异常IRQ */
	ldr	pc, _fiq						/* 快中断异常FIQ */


/* 申请一个字的空间将.word的地址写入 */
_undefined_instruction:	.word undefined_instruction
_software_interrupt:	.word software_interrupt
_prefetch_abort:	.word prefetch_abort
_data_abort:		.word data_abort
_not_used:		.word not_used
_irq:			.word irq
_fiq:			.word fiq

	.balignl 16,0xdeadbeef
/* .balignl来指定接下来的代码要16字节对齐，空缺的用0xdeadbeef，方便更加高效的访问内存 */

这部分是裸机开发最开始必须要写的，但不会一上电就执行，接下来我们看一下真正的start_code

start_code:
	/* 上电后将系统设置为管理模式 */
	mrs	r0, cpsr
	bic	r0, r0, #0x1f
	orr	r0, r0, #0xd3
	msr	cpsr, r0

	bl	coloured_LED_init
	bl	red_LED_on

#if	defined(CONFIG_AT91RM9200DK) || defined(CONFIG_AT91RM9200EK)
	/* 重定位异常表 */
	ldr	r0, =_start
	ldr	r1, =0x0
	mov	r2, #16
copyex:
	subs	r2, r2, #1
	ldr	r3, [r0], #4
	str	r3, [r1], #4
	bne	copyex
#endif

#ifdef CONFIG_S3C24X0
	/* 关闭开门狗*/
	ldr	r0, =pWTCON
	mov	r1, #0x0
	str	r1, [r0]

	/* 屏蔽IRQ */
	mov	r1, #0xffffffff
	ldr	r0, =INTMSK
	str	r1, [r0]
# if defined(CONFIG_S3C2410)
	ldr	r1, =0x3ff
	ldr	r0, =INTSUBMSK
	str	r1, [r0]
# endif

	/* 初始化时钟 */
	/* FCLK:HCLK:PCLK = 1:2:4 */
	/* default FCLK is 120 MHz ! */
	ldr	r0, =CLKDIVN
	mov	r1, #3
	str	r1, [r0]
#endif	/* CONFIG_S3C24X0 */

#ifndef CONFIG_SKIP_LOWLEVEL_INIT
	bl	cpu_init_crit
#endif

/* Set stackpointer in internal RAM to call board_init_f 设置栈指针 */
call_board_init_f:
	ldr	sp, =(CONFIG_SYS_INIT_SP_ADDR)
	bic	sp, sp, #7 /* 8-byte alignment for ABI compliance */
	ldr	r0,=0x00000000
	bl	board_init_f

/*------------------------------------------------------------------------------*/

这部分代码是上电之后真正会干的事情，简单总结以下：

  1. 执行设置CPSR程序程序状态寄存器为管理模式
  2. 关闭看门狗
  3. 屏蔽所有中断
  4. 进入cpu_init_crit函数关闭MMU，进入lowlevel_init初始化BANK寄存器来初始化SDRAM

接下来就看一下cpu_init_crit函数具体干了啥，先记录一些基本概念

mcr/mrc:

MCR指令将ARM处理器的寄存器中的数据传送到协处理器的寄存器中
MRC指令将协处理器的寄存器中数值传送到ARM处理器的寄存器中

Caches:

是一种高速缓存存储器，用于保存CPU频繁使用的数据。在使用Cache技术的处理器上，当一条指令要访问内存的数据时，首先查询cache缓存中是否有数据以及数据是否过期，如果数据未过期则从cache读出数据。处理器会定期回写cache中的数据到内存。根据程序的局部性原理，使用cache后可以大大加快处理器访问内存数据的速度。
其中DCaches和ICaches分别用来存放数据和执行这些数据的指令

TLB:

就是负责将虚拟内存地址翻译成实际的物理内存地址,TLB中存放了一些页表文件，文件中记录了虚拟地址和物理地址的映射关系。
当应用程序访问一个虚拟地址的时候，会从TLB中查询出对应的物理地址，然后访问物理地址。
TLB通常是一个分层结构，使用与Cache类似的原理。处理器使用一定的算法把最常用的页表放在最先访问的层次。
这里禁用MMU，是方便后面直接使用物理地址来设置控制寄存器

/*
#ifndef CONFIG_SKIP_LOWLEVEL_INIT
cpu_init_crit:
	/*
	 * flush v4 I/D caches
	 */
	mov	r0, #0
	/* 关闭ICaches(指令缓存,关闭是为了降低MMU查表带来的开销)和DCaches(数据缓存,DCaches使用的是虚拟地址，开启MMU之前必须关闭) */
	mcr	p15, 0, r0, c7, c7, 0	/* flush v3/v4 cache */

	/* 使无效整个数据TLB和指令TLB(TLB就是负责将虚拟内存地址翻译成实际的物理内存地址) */
	mcr	p15, 0, r0, c8, c7, 0	/* flush v4 TLB */

	/*
	 * disable MMU stuff and caches
	 */
	mrc	p15, 0, r0, c1, c0, 0
	//bit8:系统不保护,bit9:ROM不保护,bit13:设置正常异常模式0x0~0x1c,即异常模式基地址为0X0
	bic	r0, r0, #0x00002300	@ clear bits 13, 9:8 (--V- --RS)
	//bit0~2:禁止MMU，禁止地址对齐检查,禁止数据Cache.bit7:设为小端模式
	bic	r0, r0, #0x00000087	@ clear bits 7, 2:0 (B--- -CAM)
	//bit2:开启数据Cache
	orr	r0, r0, #0x00000002	@ set bit 2 (A) Align
	//bit12:开启指令Cache
	orr	r0, r0, #0x00001000	@ set bit 12 (I) I-Cache
	mcr	p15, 0, r0, c1, c0, 0
	
	/*
	 * before relocating, we have to setup RAM timing
	 * because memory timing is board-dependend, you will
	 * find a lowlevel_init.S in your board directory.
	 */
	mov	ip, lr

	bl	lowlevel_init	//跳转到lowlevel_init，前后的操作是保存和恢复环境的指令

	mov	lr, ip
	mov	pc, lr
#endif /* CONFIG_SKIP_LOWLEVEL_INIT */

接下来就看一下lowlevel_init函数具体干了啥，在board文件夹下随便找一个lowlevel_init.S学习

.globl lowlevel_init
lowlevel_init:
	/* memory control configuration */
	/* make r0 relative the current location so that it */
	/* reads SMRDATA out of FLASH rather than memory ! */
	ldr     r0, =SMRDATA	// 将SMRDATA的首地址(0x33F806C8)存到r0中
	ldr	r1, _TEXT_BASE		// r1等于_TEXT_BASE内容，也就是TEXT_BASE(0x33F80000)
	sub	r0, r0, r1			// 将0x33F806C8与0x33F80000相减，得到现在13个寄存器值在NOR Flash上存放的开始地址
	ldr	r1, =BWSCON			/* Bus Width Status Controller 将BWSCON寄存器地址值存到r1中 (第一个存储器寄存器首地址) */
	add     r2, r0, #52		// r2 保存NOR Flash上13个寄存器值最后一个地址
0:
	ldr     r3, [r0], #4
	str     r3, [r1], #4
	cmp     r2, r0
	bne     0b

	/* everything is fine now */
	mov	pc, lr

	.ltorg
/* the literal pools origin */

SMRDATA:
	.word	0x2211d644	/* d->Ethernet, 6->CPLD, 4->SRAM, 4->FLASH */
	.word	((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC)) /* GCS0 */
	.word	((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC)) /* GCS1 */
	.word	((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC)) /* GCS2 */
	.word	((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC)) /* GCS3 */
	.word	((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC)) /* GCS4 */
	.word	((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC)) /* GCS5 */
	.word	((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN)) /* GCS6 */
	.word	((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN)) /* GCS7 */
	.word	((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)
#ifndef CONFIG_RAM_16MB		/* 32 MB RAM */
	.word	0x10	/* BUSWIDTH=32, SCLK power saving mode, BANKSIZE 32M/32M */
#else	/* CONFIG_RAM_16MB	=  16 MB RAM */
	.word	0x17	/* BUSWIDTH=32, SCLK power saving mode, BANKSIZE 16M/16M */
#endif	/* CONFIG_RAM_16MB */
	.word	0x20	/* MRSR6, CL=2clk */
	.word	0x20	/* MRSR7 */

初始化SDRAM结束后继续返回start.S看代码，之后的代码与我在网上参考的文章有些不同，参考文章代码会跳转到clock_init函数设置时钟，而我的版本在之前已经设置好了时钟，应该是uboot版本不同导致的，但是干的事情都大同小异，参考的文章链接将会放在文末。

relocate_code:
	mov	r4, r0	/* save addr_sp */
	mov	r5, r1	/* save addr of gd */
	mov	r6, r2	/* save addr of destination */

	/* Set up the stack	*/
stack_setup:	//设置栈,方便调用C函数
	mov	sp, r4

	adr	r0, _start
	cmp	r0, r6
	beq	clear_bss		/* skip relocation */
	mov	r1, r6			/* r1 <- scratch for copy_loop */
	ldr	r2, _TEXT_BASE
	ldr	r3, _bss_start_ofs
	add	r2, r0, r3		/* r2 <- source end address	    */

copy_loop:	/* 将uboot复制到SDRAM */
	ldmia	r0!, {r9-r10}		/* copy from source address [r0]    */
	stmia	r1!, {r9-r10}		/* copy to   target address [r1]    */
	cmp	r0, r2			/* until source end address [r2]    */
	blo	copy_loop
/.../

clear_bss:
#ifndef CONFIG_PRELOADER
	ldr	r0, _bss_start_ofs
	ldr	r1, _bss_end_ofs
	ldr	r3, _TEXT_BASE		/* Text base */
	mov	r4, r6			/* reloc addr */
	add	r0, r0, r4
	add	r1, r1, r4
	mov	r2, #0x00000000		/* clear	用来清bss所有段   */

clbss_l:str	r2, [r0]		/* clear loop...		    */
	add	r0, r0, #4
	cmp	r0, r1
	bne	clbss_l

	bl coloured_LED_init
	bl red_LED_on
#endif

该部分的主要功能是拷贝u-boot到SDRAM，接下来继续往下看


/*
 * We are done. Do not return, instead branch to second part of board
 * initialization, now running from RAM.
 */
#ifdef CONFIG_NAND_SPL
	ldr     r0, _nand_boot_ofs
	mov	pc, r0

_nand_boot_ofs:
	.word nand_boot
#else
	ldr	r0, _board_init_r_ofs
	adr	r1, _start
	add	lr, r0, r1
	add	lr, lr, r9
	/* setup parameters for board_init_r */
	mov	r0, r5		/* gd_t */
	mov	r1, r6		/* dest_addr */
	/* jump to it ... */
	mov	pc, lr

_board_init_r_ofs:
	.word board_init_r - _start
#endif

_rel_dyn_start_ofs:
	.word __rel_dyn_start - _start
_rel_dyn_end_ofs:
	.word __rel_dyn_end - _start
_dynsym_start_ofs:
	.word __dynsym_start - _start

这段代码是跳转到nand_boot函数处执行bootloader的第二阶段，可以留意代码中的英文注释。

自此bootloader的第一阶段结束，对第一阶段进行总结：

  1. 执行设置CPSR程序程序状态寄存器为管理模式
  2. 关看门狗
  3. 屏蔽中断
  4. 初始化时钟
  5. 关闭MMU,初始化SDRAM
  6. 设置栈
  7. 重定位(代码从Flash拷贝至SDRAM中)
  8. 清bss段(未初始的全局/静态变量)
  9. 跳转到nand_boot函数(位于u-boot-1.1.6/lib_arm/borad.c,用来实现第2阶段硬件相关的初始化)

第二阶段后面有时间再写~

以下为参考的博客，侵删~
第1阶段——uboot分析之硬件初始化start.S(4)

超详细分析Bootloader（Uboot）到内核的启动流程

jhertz
关注
  • 0
    点赞
  • 踩
  • 2
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
u-boot源码分析
小王的博客
01-15 5256
u-boot源码分析
NXP BootLoader源码分析并改写SD卡启动
主要分享硬件、嵌入式软件部分知识
11-17 1339
NXP BootLoader的分析并改写为SD启动
ARM uboot 源码分析7 - uboot的命令体系
weixin_42109053的博客
02-24 768
一、uboot 命令体系基础 1、使用 uboot 命令 (1) uboot 启动后进入命令行环境下，在此输入命令按回车结束，uboot 会收取这个命令然后解析，然后执行。 2、uboot 命令体系实现代码在哪里 (1) uboot 命令体系的实现代码在 uboot/common/cmd_xxx.c 中。有若干个 .c 文件和命令体系有关。（还有 command.c main.c 也是和命令有关的） 3、每个命令对应一个函数 (1) 每一个 uboot 的命令背后都对应一个函数。这就是 uboot
Linux 系统构成：bootloader、kernel、rootfs
夏沫的杂物间
02-18 2077
Linux 系统构成：bootloader、kernel、rootfs
完全理解ARM启动流程：Uboot-Kernel
最新发布
叫好与叫座虽然不是对立面，但想在同一个作品中达到双重效果很难。
03-20 1758
bootloader是系统上电后最初加载运行的代码。它提供了处理器上电复位后最开始需要执行的初始化代码。PC机上引导程序一般由BIOS开始执行，然后读取硬盘中位于MBR(Main Boot Record，主引导记录)中的Bootloader(例如LILO或GRUB),并进一步引导操作系统的启动。嵌入式系统中通常没有像BIOS那样的固件程序，因此整个系统的加载启动就完全由bootloader来完成，它主要的功能是加载与引导内核映像。第一个分区：存放的当然是u-boot。
linux的uboot第一阶段源码详细分析
04-26
给想做linux的和内核相关开发的童鞋们提供详细的分析 加入个人的理解
uboot源码分析[文].pdf
10-20
在第一阶段，CPU上电后，NAND Flash的前4KB内容被自动复制到SRAM中，这部分代码执行初步的硬件初始化。这4KB代码通常由汇编语言编写，如`/cpu/arm920t/start.S`中的`_start`函数。在`reset`标签处，执行更复杂的初始...
uboot源码 start.S文件详解
08-03
跳转矢量表是ARM处理器在reset时执行的第一条指令，它将跳转到_start标签所在的位置。_start标签定义了系统复位位置，是整个程序的入口点。 在_start标签后面定义了七个异常中断的初始地址，这七个地址分别对应着 ...
LINUX系统移植及UBOOT代码分析.zip
08-24
第一部分 前言....................................................................................................................................8 1 硬件环境.............................................
u-boot-2009.6.tar.gz_uboot_uboot 2009.6.tar_uboot源码
09-19
2.2 主要源文件：核心源文件有`start.S`，它是启动过程的第一段汇编代码，负责初始化CPU和内存；`main.c`是C语言入口，负责执行初始化任务和运行命令行接口；`config.h`包含了配置选项，影响编译时的行为。 三、U-...
Bootloader详解(源码+实验)研究BOOT必读
10-19
1、了解BootLoader 的基本概念和框架结构 2、了解BootLoader 引导操作系统的过程 3、掌握bootloader 程序的编译方法 4、掌握BootLoader 程序的使用方法 （1）、Boot Loader 的阶段1 通常主要包括以下步骤：  硬件设备初始化；  拷贝Boot Loader 的程序到RAM 空间中；  设置好堆栈；  跳转到阶段2 的C 入口点。 （2）、Boot Loader 的阶段2 通常主要包括以下步骤：  初始化本阶段要使用到的硬件设备；  系统内存映射(memory map)；  将kernel 映像和根文件系统映像从Flash 读到RAM 空间中；  为内核设置启动参数；  调用内核 …………………………………………………………
ARMBootloader分析及源代码
07-05
ARMBootloader分析及源代码.pdf
uboot代码完全解析
06-30
,对uboot代码的注释和分析，了解uboot的工作流程
uboot代码详细分析.pdf
03-29
所有资料来源网上，与朋友分享 u-boot-1.1.6之cpu/arm920t/start.s分析 2 u-boot中.lds连接脚本文件的分析 12 分享一篇我总结的uboot学习笔记（转） 15 U-BOOT内存布局及启动过程浅析 22 u-boot中的命令实现 25 U-BOOT环境变量实现 28 1.相关文件 28 2.数据结构 28 3.ENV 的初始化 30 3.1env_init 30 3.2 env_relocate 30 3.3*env_relocate_spec 31 4. ENV 的保存 31 U-Boot环境变量 32 u-boot代码链接的问题 35 ldr和adr在使用标号表达式作为操作数的区别 40 start_armboot浅析 42 1.全局数据结构的初始化 42 2.调用通用初始化函数 43 3.初始化具体设备 44 4.初始化环境变量 44 5.进入主循环 44 u-boot编译过程 44 mkconfig文件的分析 47 从NAND闪存中启动U-BOOT的设计 50 引言 50 NAND闪存工作原理 51 从NAND闪存启动U-BOOT的设计思路 51 具体设计 51 支持NAND闪存的启动程序设计 51 支持U-BOOT命令设计 52 结语 53 参考文献 53 U-boot给kernel传参数和kernel读取参数—struct tag (以及补充) 53 1 、u-boot 给kernel 传RAM 参数 54 2 、Kernel 读取U-boot 传递的相关参数 56 3 、关于U-boot 中的bd 和gd 59 U-BOOT源码分析及移植 60 一、u-boot工程的总体结构： 61 1、源代码组织 61 2.makefile简要分析 61 3、u-boot的通用目录是怎么做到与平台无关的？ 63 4、smkd2410其余重要的文件 ： 63 二、u-boot的流程、主要的数据结构、内存分配 64 1、u-boot的启动流程： 64 2、u-boot主要的数据结构 66 3、u-boot重定位后的内存分布： 68 三、u-boot的重要细节 。 68 关于U-boot中命令相关的编程 ： 73 四、U-boot在ST2410的移植，基于NOR FLASH和NAND FLASH启动。 76 1、从smdk2410到ST2410: 76 2、移植过程： 76 3、移植要考虑的问题： 77 4、SST39VF1601: 77 5、我实现的flash.c主要部分： 78 6、增加从Nand 启动的代码 ： 82 7、添加网络命令。 87
uboot源码分析
Linux知识积累
11-06 225
u-boot 源码版本：u-boot-2017.05-rc2u-boot文件介绍u-boot源码中文件内容如下：针对有代表性的文件，我们简单介绍其功能config.mk文件是一个Makefile文件，在某个Makefile中会去调用它Makefile文件这个是uboot源代码的主Makefile，将来整个uboot被编译时就是用这个Makefile管理编译的。api文件夹硬件无关的功能函数的API...
uboot启动流程源码分析(一)
叫好与叫座虽然不是对立面，但想在同一个作品中达到双重效果很难。
10-19 2150
其实前面我学习韦神的书的时候，学习过uboot，知道分为两个阶段。期间对这个uboot的源码没有了解深入。最近坐AVB校验，需要uboot到kernel的这个过程。这里再学习一下。与大多数BootLoader一样，uboot的启动过程分为BL1和BL2两个阶段。BL1阶段通常是开发板的配置等设备初始化代码，需要依赖依赖于SoC体系结构，通常用汇编语言来实现；BL2阶段主要是对外部设备如网卡、Flash等的初始化以及uboot命令集等的自身实现，通常用C语言来实现。
uboot源码配置编译过程
qq_42798939的博客
05-31 304
1
ARM uboot 源码分析4 -启动第二阶段
weixin_42109053的博客
02-13 596
一、start_armboot 函数简介 1、一个很长的函数 (1) 这个函数在 uboot/lib_arm/board.c 的第 444 行开始到 908 行结束。 (2) 450 行还不是全部，因为里面还调用了别的函数。 (3)为什么这么长的函数，怎么不分成两三个函数？主要因为这个函数整个构成了 uboot 启动的第二阶段。 2、一个函数组成 uboot 第二阶段 3、宏观分析：uboot 第二阶段应该做什么 (1) 概括来讲，uboot 第一阶段主要就是初始化了 SoC 内部的一些部件（譬如看门
Uboot start.S源码深度解析：CPU模式、中断与BSS段
"Uboot中start.S源码的指令级详尽解析" 本文旨在深入解析Uboot启动过程中的关键文件start.S，该文件是Uboot初始化阶段的入口，负责设置CPU模式、关闭看门狗、配置堆栈、清零BSS段以及处理异常中断等重要任务。对于...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值