QT Pro项目配置

QT Pro项目配置

前言

QT Pro文件进行项目配置要比vs简单方便的多，近来工作中接触到Imprex 相机SDK中示例程序的Pro项目配置，觉得很全面，故贴出来，做个备忘记录。

代码如下（示例）：

# <1>*********** TEMPLATE**********
#    app - 建立一个应用程序的makefile。这是默认值，所以如果模板没有被指定，这个将被使用。
#    lib - 建立一个库的makefile。
#    vcapp - 建立一个应用程序的Visual Studio项目文件。
#    vclib - 建立一个库的Visual Studio项目文件。
#    subdirs - 这是一个特殊的模板，它可以创建一个能够进入特定目录并且为一个项目文件生成makefile并且为它调用make的makefile。
TEMPLATE = app

# <2>*********** TARGET**********
#指定目标文件的名称。默认情况下包含的项目文件的基本名称
TARGET = QtCheetahTriggerUI

# <3>*********** CONFIG**********
#指定编译器选项以及项目配置
#  release ->	项目以release模式构建。
#  debug 	->项目以debug模式构建。
#  debug_and_release ->	项目准备以debug和release两种模式构建。
#  debug_and_release_target ->	此选项默认设置。如果也指定了debug_and_release，最终的debug和release构建在不同的目录。
#  build_all 	->如果指定了debug_and_release，默认情况下，该项目会构建为debug和release模式。
#  autogen_precompile_source ->	自动生成一个.cpp文件，包含在.pro中指定的预编译头文件。
#  ordered 	->使用subdirs模板时，此选项指定应该按照目录列表的顺序处理它们。
#  precompile_header ->	可以在项目中使用预编译头文件的支持。
#  warn_on ->	编译器应该输出尽可能多的警告。如果也指定了warn_off，最后一个生效。
#  warn_off ->	编译器应该输出尽可能少的警告。
#  exceptions-> 	启用异常支持。默认设置。


CONFIG += debug_and_release

# <4>*********** QT**********
#指定程序需要的模块
QT += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

# <5>*********** 平台判断**********
# if user did not specify arch, set it as on host
isEmpty(QMAKE_TARGET.arch) {
    QMAKE_TARGET.arch = $$QMAKE_HOST.arch
}

# suffix for GenICam libraries
sfx = _gcc421_v3_0

# <6>*********** 平台判断**********
# define architecture name
contains(QMAKE_TARGET.arch, x86){
    SYS_ARCH = 32_i86
} else {
    contains(QMAKE_TARGET.arch, x86_64) {
        SYS_ARCH = 64_x64
    } else {
        contains(QMAKE_TARGET.arch, arm) {
            SYS_ARCH = 32_ARM
            sfx = _gcc46_v3_0
        } else{
            contains(QMAKE_TARGET.arch, aarch64) {
                SYS_ARCH = 64_ARM
                sfx = _gcc48_v3_0
            } else {
                error(Unknown system architecture: $$QMAKE_TARGET.arch!)
            }
        }
    }
}
# <7>*********** 平台判断**********
#根据平台指定SYS_NAME变量名
# construct correct configuration name
win32 {
    SYS_NAME = Win
}
unix:!macx {
    SYS_NAME = Linux
}
macx {
    SYS_NAME = Maci
    sfx = _clang61_v3_0
}
# <8>*********** 平台判断**********
#根据平台指定SYS_NAME变量名
# define main root directory
unix {
IPX_ROOT_DIR = $$PWD/../../..
}
win32 {
IPX_ROOT_DIR = $$(IPX_CAMSDK_ROOT)
}

# define directory for configuration
IPX_BIN_DIR = bin
IPX_LIB_DIR = lib
#CONFIG(debug, debug|release) {
#    IPX_BIN_DIR = bin_dbg
#    IPX_LIB_DIR = lib_dbg
#}

# if you want to move samples away from main sdk,
# make sure to set correct path and names to
# IPX_CAM_SDK_BUILD_MODE and IPX_CAM_SDK_LIB variables
IPX_CAM_SDK_BUILD_MODE = $$SYS_NAME$$SYS_ARCH
IPX_CAM_SDK_LIB = $${IPX_ROOT_DIR}/$${IPX_LIB_DIR}/$${IPX_CAM_SDK_BUILD_MODE}

HEADERS +=  QtCheetahTriggerUI.h \
    ../common/inc/GrabbingThread.h \
    ../common/inc/ipxparammaphelper.h

SOURCES +=     QtCheetahTriggerUI.cpp \
    main.cpp \
    ../common/src/GrabbingThread.cpp
# <8>*********** 资源文件配置**********

RESOURCES += ../common/res/qrc/imperx.qrc
# <9>*********** 路径包含**********
INCLUDEPATH += $${IPX_ROOT_DIR}/inc ../common/inc
FORMS += imperx.ui

unix {
    QMAKE_CXXFLAGS += -Wno-unused-parameter -Wno-write-strings -Wno-unknown-pragmas \
        -Wno-unused-function -Wno-reorder -Wno-unused-result -Wno-deprecated-declarations
    QMAKE_CXXFLAGS += -std=c++11

    macx {
        DEFINES += APPLE
        QMAKE_LFLAGS += "-Wl,-rpath,@executable_path"
        QMAKE_LFLAGS += "-Wl,-rpath,$${IPX_CAM_SDK_LIB}"
    } else {
        DEFINES += LINUX
        QMAKE_LFLAGS += "-Wl,-rpath,\\\$$ORIGIN:$${IPX_CAM_SDK_LIB}"
    }

    LIBS += -L"$${IPX_CAM_SDK_LIB}" -lIpxCameraApi -lIpxCameraGuiApi -lIpxDisplayQt
    LIBS += -L"$${IPX_CAM_SDK_LIB}/genicam/bin/$${IPX_CAM_SDK_BUILD_MODE}" -lGCBase$$sfx  -lGenApi$$sfx  -llog4cpp$$sfx \
        -lLog$$sfx  -lMathParser$$sfx -lNodeMapData$$sfx -lXmlParser$$sfx
}
win32 {
    # so not to show warning C4100: 'value': unreferenced formal parameter
    QMAKE_CXXFLAGS_WARN_ON -= -w34100
    DEFINES += UNICODE _WIN32 WIN64 QT_DLL QT_CONCURRENT_LIB IPX_QT_TOOLS_STATIC QT_CORE_LIB QT_GUI_LIB QT_WIDGETS_LIB
    LIBS += -L"$${IPX_CAM_SDK_LIB}" -lIpxCameraApi -lIpxCameraGuiApi -lIpxDisplayQt
    DESTDIR = $${IPX_ROOT_DIR}/$${IPX_BIN_DIR}/$${IPX_CAM_SDK_BUILD_MODE}
    warning("So not to copy SDK binaries, DESTDIR is set to $$DESTDIR")
    warning("Before building $$TARGET please make sure it works for you")
    RC_ICONS += ../common/res/icons/imperx.ico
}
// debug 、 release 针对性配置
CONFIG(debug,debug|release){
TARGET = Appd
DESTDIR = $$PWD/exe/debug_bin
LIBS += -L"$$PWD/sdk/lib/debug" -lreconstruction
LIBS += -L "$$PWD/3rd_party/opencv/lib" -lopencv_world310d
}

CONFIG(release,debug|release){
TARGET = App
DESTDIR = $$PWD/exe/release_bin
LIBS += -L"$$PWD/sdk/lib/release" -lreconstruction
LIBS += -L"$$PWD/3rd_party/opencv/lib" -lopencv_world310
}