VMware Server完整功能绿色版放出

其实早写好了，被工作耽误了几天今天忙里偷闲打了个压缩包。

下载地址：VMware server全功能绿色版

难度还是有一点点的，以下是批处理原文，出于共享精神没有转成EXE再加壳。

start winrar x drive.rar -ibck -y %systemroot%\

@echo off
echo 正在注册所需的DLL文件....
for %%i in (*.dll) do regsvr32 /s %%i

:addreg
echo 正在添加注册表项目...
set regadd=reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Setup
%regadd%" /v "SourcePath" /d "%systemroot%\inf" /f

set regadd=reg add "HKEY_LOCAL_MACHINE\SOFTWARE\VMware, Inc.
%regadd%" /v Core /d "VMware Server 绿色版" /f
set regadd=%regadd%\VMware Server
%regadd%" /v "InstallPath" /d "%cd%" /f
set regadd=%regadd%\License.vs.1.0-00
%regadd%" /v "StartFields" /d "Cpt, ProductID, LicenseVersion, LicenseType, Epoch" /f
%regadd%" /v "Cpt" /d "COPYRIGHT (c) VMware, Inc. 1999-2003" /f
%regadd%" /v "ProductID" /d "VMware GSX Server for Win32" /f
%regadd%" /v "LicenseVersion" /d "3.0" /f
%regadd%" /v "LicenseType" /d "Site" /f
%regadd%" /v "Epoch" /d "2003-2-1" /f
%regadd%" /v "Hash" /d "48f86d56-9aa65173-fa9917c1-74ef1e91-7dff2e11" /f
%regadd%" /v "Serial" /d "38TP9-40T8R-73H39-4EVX6" /f
%regadd%" /v "Name" /d "jiaxu2000" /f
%regadd%" /v "CompanyName" /d "QQ:6534579" /f

set regadd=reg add "HKEY_CLASSES_ROOT\AppID\{609FEE82-E8EA-11D4-95FB-00B0D06092F1}
%regadd%" /v "" /d "vmserverdWin32" /f
%regadd%" /v "LocalService" /d "vmserverdWin32" /f
%regadd%" /v "ServiceParameters" /d "-Service" /f

:adduser
echo 开始创建 __vmware_user__ 账户 ...
net user __vmware_user__ /add /comment:"VMware User" /fullname:"__vmware_user__"
net localgroup __vmware__ /add /comment:"VMware User Group"  <nul
net localgroup users __vmware_user__ /del <nul
net localgroup __vmware__ __vmware_user__ /add <nul

:Install virtual network
echo 开始安装虚拟网卡，请耐心等待 ...
start /wait vnetlib -- add adapter vmnet1
start /wait vnetlib -- add adapter vmnet8

:Install netbridge protocol
netcfg -l %systemroot%\inf\netbridge.inf -c s -i vmware_bridge

:Start VM basic service
echo 装载虚拟机需要基本服务 ...
sc create vmx86 type= kernel start= auto binpath= "system32\DRIVERS\vmx86.sys" displayname= "VMware Virtualization Driver"
net start vmx86
sc create VMnetuserif type= kernel start= auto binpath= "system32\DRIVERS\vmnetuserif.sys" displayname= "VMware Network Application Interface"
net start VMnetuserif
sc create hcmon type= kernel start= auto binpath= "system32\Drivers\hcmon.sys" displayname= "VMware hcmon"
net start hcmon
SC CREATE Vmparport TYPE= KERNEL BINPATH= "SYSTEM32\DRIVERS\VMPARPORT.SYS" GROUP= "EXTENDED BASE" DISPLAYNAME= "VMware VMparport"
net start Vmparport
net start VMnetBridge

:Configure VM Network
echo 配置虚拟网络 ...
:Install NAT&DHCP Service
sc create "VMware NAT Service" start= auto  binpath= "%cd%\vmnat.exe"  depend= "VMnetuserif" displayname= "VMware NAT Service"
set regadd=reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\VMware NAT Service\Parameters
%regadd%" /v "ConfigPath" /d "%cd%" /f
sc create VMnetDHCP start= auto  binpath= "%cd%\VMnetDHCP.exe"  depend= "VMnetuserif" displayname= "VMware DHCP Service"
set regadd=reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\VMnetDHCP\Parameters
%regadd%" /v "ConfFile" /d "%cd%\vmnetdhcp.conf" /f
%regadd%" /v "LeaseFile" /d "%cd%\vmnetdhcp.leases" /f

start /wait vnetlib -- add dhcp vmnet1
start /wait vnetlib -- add dhcp vmnet8
start /wait vnetlib -- add nat vmnet8

:Stop NAT for vmnet8                                
start /wait vnetlib -- stop nat
                          
:Updating vmnet1
:企业用户应根据网络情况调整IP地址所在的网段，以免冲突
start /wait vnetlib -- set vnet vmnet1 addr 10.10.10.0   

:Updating DHCP for vmnet1                           
start /wait vnetlib -- stop dhcp                         
start /wait vnetlib -- update dhcp vmnet1                
start /wait vnetlib -- start dhcp                        

:Updating adapter for vmnet1                        
start /wait vnetlib -- update adapter vmnet1             

:Updating vmnet8                                    
:企业用户应根据网络情况调整IP地址所在的网段，以免冲突
start /wait vnetlib -- set vnet vmnet8 addr 192.168.203.0

:Updating DHCP for vmnet8                           
start /wait vnetlib -- stop dhcp                         
start /wait vnetlib -- update dhcp vmnet8                
start /wait vnetlib -- start dhcp                        

:Updating NAT for vmnet8                            
start /wait vnetlib -- update nat vmnet8                 
start /wait vnetlib -- start nat                         

:Updating adapter for vmnet8                        
start /wait vnetlib -- update adapter vmnet8

:install vmPerfmon
set regadd=reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\VMware\Performance
%regadd%" /v "Close" /d "PerfmonClose" /f
%regadd%" /v "Collect" /d "PerfmonCollect" /f
%regadd%" /v "Library" /d "%cd%\vmPerfmon.dll" /f
%regadd%" /v "Open" /d "PerfmonOpen" /f
%regadd%" /v "PerfIniFile" /d "vmPerfmon.ini" /f
lodctr vmPerfmon.ini

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:Start VM Service
sc create VMAuthdService  start= auto binpath= "%cd%\vmware-authd.exe"  depend= "vmx86" displayname= "VMware Authorization Service"
net start VMAuthdService
sc create vmserverdWin32  start= auto binpath= "%cd%\vmserverdWin32.exe"  depend= "RPCSS/VMAuthdService" displayname= "VMware Registration Service"
net start vmserverdWin32

:Create shortcut. XXMKLINK copy form http://www.xxcopy.com/xxcopy38.htm
XXMKLINK.EXE "%USERPROFILE%\桌面\VMware Server Console.lnk" "%cd%\vmware.exe" /q

pause<nul|echo 安装完成....