2.操作系统引导——揭开钢琴的盖子

一、计算机历史

1.

最开始的图灵机，有控制器，只是在纸带上做简单运算
计算3+2=5时，先从纸带读入3，再读入2，再读入 +，计算完 3 + 2 = 5 后，再将 5 写入 纸带

2.

通用图灵机，控制器的内容是可以修改的。控制器像个厨师，控制的程序就是一个菜谱。设置不同的程序，完成不同的任务。

3.

系统将 程序 放到 存储器，指针（IP或PC）指向当前要处理的指令，载入指令，形成当前的控制逻辑，解释执行该指令。执行完一条指令，指针+1，执行下一条指令，系统不断的取指执行。

二、从打开电源开始……

打开电源，计算机就开始工作了，计算机是怎么工作的？
开机动画背后发生了什么？
打开电源，计算机执行的第一句指令是什么？

计算模型，我们需要关注 指针IP 及其 指向的内容，打开电源时，IP=？是由硬件设计决定的

1.x86的PC

1. x86 PC 刚开机时，CPU处于实模式（实模式与保护模式相对应，两种方式寻址不一样），实模式的寻址 CS : IP （CS左移4位 + IP，CS是段寄存器）
2. 开机时，CS=0xFFFF; IP=0x0000
3. 寻址 0xFFFF0（ROM BIOS映射区，BIOS：basic input output system）
4. 检查RAM，键盘，显示器，软硬磁盘
5. 将磁盘 0磁道0扇区 读入0x7c00处（0磁道0扇区 是操作系统的 引导扇区，一个扇区是512字节）
6. 设置CS=0x07c0; IP=0x0000

2.引导扇区

0x7C00 处 存放的代码 就是 从磁盘引导扇区读入的512字节

• 引导扇区是启动设备的第一个扇区（开机时按住Delete键可以进入启动设备设置界面，可以设置为光盘启动）
• 启动设备信息被设置在CMOS（CMOS：Complementary Metal Oxide Semiconductor，
  互补金属氧化物半导体，64-128B，用来存储时钟和硬件配置信息）中
• 硬盘的第一个山区上 存放着 开机后 执行的 第一段 我们可以控制的程序
  操作系统的故事从这里开始……

3.bootsect.s

! bootsect.s (C) 1991 Linus Torvalds
!
! bootsect.s is loaded at 0x7c00 by the bios-startup routines, and moves
! iself out of the way to address 0x90000, and jumps there.
!
! It then loads 'setup' directly after itself (0x90200), and the system
! at 0x10000, using BIOS interrupts.
!
! NOTE! currently system is at most 8*65536 bytes long. This should be no
! problem, even in the future. I want to keep it simple. This 512 kB
! kernel size should be enough, especially as this doesn't contain the
! buffer cache as in minix
!
! The loader has been made as simple as possible, and continuos
! read errors will result in a unbreakable loop. Reboot by hand. It
! loads pretty fast by getting whole sectors at a time whenever possible.
!
! 以下是前面这些文字的翻译：
! bootsect.s (C) 1991 Linus Torvalds 版权所有
!
! bootsect.s 被bios-启动子程序加载至0x7c00 (31k)处，并将自己
! 移到了地址0x90000 (576k)处，并跳转至那里。
!
! 它然后使用BIOS 中断将'setup'直接加载到自己的后面(0x90200)(576.5k)，
! 并将system 加载到地址0x10000 处。
!
! 注意! 目前的内核系统最大长度限制为(8*65536)(512k)字节，即使是在
! 将来这也应该没有问题的。我想让它保持简单明了。这样512k 的最大内核长度应该
! 足够了，尤其是这里没有象minix 中一样包含缓冲区高速缓冲。
!
! 加载程序已经做的够简单了，所以持续的读出错将导致死循环。只能手工重启。
! 只要可能，通过一次取所有的扇区，加载过程可以做的很快的。


.globl begtext, begdata, begbss, endtext, enddata, endbss   ! 定义了6 个全局标识符；
.text   ! 文本段；
begtext:
.data   ! 数据段；
begdata:
.bss    ! 堆栈段,未初始化数据段
begbss:
.text   ! 文本段；
! .text等是 伪操作符，告诉编译器产生文本段， .text 用于标识文本段的开始位置
!  .text, .data, .bss 表明 这3个段重叠，不分段


SETUPLEN = 4    ! nr of setup-sectors,setup 程序的扇区数(setup-sectors)值；
BOOTSEG = 0x07c0    ! original address of boot-sector,bootsect 的原始地址（是段地址，以下同）
INITSEG = 0x9000    ! we move boot here - out of the way,将bootsect 移到这里 -- 避开
SETUPSEG = 0x9020   ! setup starts here,setup 程序从这里开始
SYSSEG = 0x1000     ! system loaded at 0x10000 (65536). system 模块加载到0x10000（64 kB）处
ENDSEG = SYSSEG + SYSSIZE   ! where to stop loading,停止加载的段地址

! 将自身(bootsect)从目前段位置0x07c0(31k)
! 移动到0x9000(576k)处，共256 字（512 字节），然后跳转到
! 移动后代码的go 标号处，也即本程序的下一语句处。
entry start     !关键字entry告诉链接器“程序入口”，告知连接程序，程序从start 标号开始执行。
start: 
mov ax,#BOOTSEG     ! ax 置为0x7C0
mov ds,ax   ! ds 置为0x7C0
mov ax,#INITSEG     !将ax置为0x9000
mov es,ax   !将es 置为0x9000
mov cx,#256     !移动计数值=256 字；
sub si,si   !置si为0，源地址 ds:si = 0x07C0:0x0000，ds和si组成地址 0x7c00
sub di,di   !置di为0，目的地址 es:di = 0x9000:0x0000，es和di组成地址 0x90000
rep     !重复执行，直到cx = 0
movw    !移动1 个字；rep movw 重复移动256个字（512个字节），将0x7C00处的256个字节移动到0x90000处，腾出空间
jmpi go,INITSEG     !间接跳转。这里INITSEG 指出跳转到的段地址。
! jmpi(jump intersegment段间跳转)go=IP，cs=INITSEG

源地址 ds:si = 0x07C0:0x0000，ds和si组成地址 0x7c00
目的地址 es:di = 0x9000:0x0000，es和di组成地址 0x90000
将0x07C0:0x0000处的256个字 移动到 0x9000:0x0000处

go: mov ax,cs   ! cs=0x9000
mov ds,ax   !由于程序中有堆栈操作(push,pop,call)，因此必须设置堆栈。
mov es,ax   
mov ss,ax   !将ds、es 和ss 都置成移动后代码所在的段处(0x9000)。
mov sp,#0xFF00  ! arbitrary value >>512
! put stack at 0x9ff00. 
! 将堆栈指针sp 指向0x9ff00(即0x9000:0xff00)处
! 由于代码移动过了，所以要重新设置堆栈段的位置，指针只要大于512偏移（0x90200）处都可以
! 0x90200地址开始要放置setup程序，setup程序大约为4个扇区，指针要指向大于（0x200 + 0x200 * 4 + 堆栈大小）处

指针指向远大于0x90200的地方，如0x9ff00，为setup程序留出空间

! load the setup-sectors directly after the bootblock.
! Note that 'es' is already set up.
! 在bootsect 程序块后紧根着加载setup 模块的代码数据。
! 注意es 已经设置好了。（在移动代码时es 已经指向目的段地址处0x9000）。

! 载入setup模块
load_setup:
mov dx,#0x0000  ! drive 0, head 0
mov cx,#0x0002  ! sector 2, track 0，bootsect占用了第一个扇区，从第2个扇区开始读
mov bx,#0x0200  ! address = 512, in INITSEG
mov ax,#0x0200+SETUPLEN ! service 2, nr of sectors
! ax前两位是 ah=0x02，后两位是al=SETUPLEN=4 是扇区数量
int 0x13    ! read it，0x13是BIOS读磁盘扇区的中断
jnc ok_load_setup   ! ok - continue
mov dx,#0x0000
mov ax,#0x0000  ! reset the diskette 复位
int 0x13
j load_setup    !重读

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!  
!!INT 13 - DISK - READ SECTOR(S) INTO MEMORY  
!! AH = 02h  读磁盘扇区到内存
!! AL = number of sectors to read (must be nonzero)，需要读出的扇区数量，SETUPLEN=4
!! CH = low eight bits of cylinder number，磁道（柱面）号的低8位
!! CL = sector number 1-63 (bits 0-5)，开始扇区（0-5位），磁道号高2位（6-7位）
!! high two bits of cylinder (bits 6-7, hard disk only)  
!! DH = head number，磁头号
!! DL = drive number (bit 7 set for hard disk)，驱动器号（如果是硬盘则要置位7）
!! ES:BX ->; data buffer，指向数据缓冲区
!! Return: CF set on error，如果出错则CF置位
!! if AH = 11h (corrected ECC error), AL = burst length  
!! CF clear if successful  
!! AH = status (see #00234)  
!! AL = number of sectors transferred (only valid if CF set for some  
!! BIOSes)  
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

读到 es:bx处，即0x9000:0x0200
利用BIOS中断int 0x13 将setup模块从磁盘第2个扇区开始读到0x90200处，共读4个扇区，如果读出错，则复位驱动器，并重试。

! 读入setup模块后
ok_load_setup:
mov dl,#0x00
mov ax,#0x0800  ! AH=8 is get drive parameters,ah=8获得磁盘参数
int 0x13
mov ch,#0x00
seg cs  ! 表示下一条语句的操作数在cs 段寄存器所指的段中。
mov sectors,cx  ! 保存每磁道扇区数。
mov ax,#INITSEG
mov es,ax   ! 因为上面取磁盘参数中断改掉了es 的值，这里重新改回。

! Print some inane message ! 在显示一些信息('Loading system ...'回车换行，共24 个字符)。

mov ah,#0x03 ! read cursor pos
xor bh,bh   ! 读光标位置。
int 0x10    ! int 0x10是在屏幕上的字符的BIOS中断

mov cx,#24  ! 共24 个字符，Loading system ...的字符数量。
mov bx,#0x0007  ! page 0, attribute 7 (normal)，7是显示属性
mov bp,#msg1    ! bp是要显示在屏幕的字符对应的内存地址,#msg1是一个偏移，指向要显示的字符串，Loading system ...。
mov ax,#0x1301  ! write string, move cursor
int 0x10    ! 写字符串并移动光标。


! ok, we've written the message, now
! we want to load the system (at 0x10000) ! 现在开始将system 模块加载到0x10000(64k)处。

mov ax,#SYSSEG
mov es,ax   ! segment of 0x010000 ! es = 存放system 的段地址。
call read_it    ! 读磁盘上system 模块
call kill_motor     ! 关闭驱动器马达，这样就可以知道驱动器的状态了。

! After that we check which root-device to use. If the device is
! defined (!= 0), nothing is done and the given device is used.
! Otherwise, either /dev/PS0 (2,28) or /dev/at0 (2,8), depending
! on the number of sectors that the BIOS reports currently.
! 此后，我们检查要使用哪个根文件系统设备（简称根设备）。如果已经指定了设备(!=0)
! 就直接使用给定的设备。否则就需要根据BIOS 报告的每磁道扇区数来
! 确定到底使用/dev/PS0 (2,28) 还是 /dev/at0 (2,8)。
! 上面一行中两个设备文件的含义：
! 在Linux 中软驱的主设备号是2(参见第43 行的注释)，次设备号 = type*4 + nr，其中
! nr 为0-3 分别对应软驱A、B、C 或D；type 是软驱的类型（2??1.2M 或7??1.44M 等）。
! 因为7*4 + 0 = 28，所以 /dev/PS0 (2,28)指的是1.44M A 驱动器,其设备号是0x021c
! 同理 /dev/at0 (2,8)指的是1.2M A 驱动器，其设备号是0x0208。
……

! after that (everyting loaded), we jump to
! the setup-routine loaded directly after
! the bootblock:
! 到此，所有程序都加载完毕，我们就跳转到被
! 加载在bootsect 后面的setup 程序去。

jmpi 0,SETUPSEG ! IP=0，CS=SETUPSEG=0x9020，跳转到CS：IP = 0x9020:0000(setup.s 程序的开始处)。

数据在bootsect.s的末尾

sectors:
.word 0 ! 存放当前启动软盘每磁道的扇区数。

msg1:
.byte 13,10 ! 回车、换行的ASCII 码。
.ascii "Loading system ..."
.byte 13,10,13,10 ! 共24 个ASCII 码字符。

!BIOS用以识别引导扇区
.org 508 ! 表示下面语句从地址508(0x1FC)开始，所以root_dev
! 在启动扇区的第508 开始的2 个字节中。
root_dev:
.word ROOT_DEV ! 这里存放根文件系统所在的设备号(init/main.c 中会用)。
boot_flag:
.word 0xAA55 ! 硬盘有效标识，扇区的最后2个字节。

! bootsect.s的两个子程序
! read_it 读入system模块，system模块可能很大，要跨磁道
read_it:
……
! 判断是否已经读入全部数据。比较当前所读段是否就是系统数据末端所处的段(#ENDSEG)，如果不是就
! 跳转至下面ok1_read 标号处继续读数据。否则退出子程序返回。
! ENDSEG=SYSSEG+SYSSIZE，SYSSIZE=0x8000,该变量可根据Image大小在编译操作系统时设定
mov ax,es
cmp ax,#ENDSEG   ! have we loaded all yet? ! 是否已经加载了全部数据？
jb ok1_read
ret


ok1_read:
! 计算和验证当前磁道需要读取的扇区数，放在ax 寄存器中。
! 根据当前磁道还未读取的扇区数以及段内数据字节开始偏移位置，计算如果全部读取这些未读扇区，所
! 读总字节数是否会超过64KB 段长度的限制。若会超过，则根据此次最多能读入的字节数(64KB – 段内
! 偏移位置)，反算出此次需要读取的扇区数。
seg cs
mov ax,sectors  ! 取每磁道扇区数。
sub ax,sread    ! 减去当前磁道已读扇区数。sread是当前磁道已读扇区数，ax是未读扇区数
……
call read_track ! 读磁道

bootsect工作：读system，setup。bootsect结束，通过jmpi 0,SETUPSEG跳转，将控制权交给setup，执行setup.s