ORACLE PL/SQL基础 选择(IF CASE) 、 循环(LOOP WHILE FOR)

一、PL/SQL的控制结构，包括选择结构、循环结构和跳转结构

1、选择结构

(1)IF语句

IF condition1 THEN  statement1 ;
[ ELSIF condition2 THEN statement2 ; ]
...
[ ELSE else_statements ; ]
END IF;

Attention：PL/SQL的逻辑运算结果有 TRUE 、 FALSE 、NULL 三种情况，所以在进行条件选择判断时，要考虑条件结果为NULL的情况。

Example：

create or replace procedure detector_plsql_if(
       v_control_type in varchar2)
as
    v_pre_print varchar2(100) := 'value of parameter [in] v_control_type';
begin

    if v_control_type = 'if' then
       dbms_output.put_line(v_pre_print || ' (if) :' || v_control_type);
    elsif v_control_type = 'case' then
       dbms_output.put_line(v_pre_print || ' (case) :' || v_control_type);
    elsif v_control_type is null then
       dbms_output.put_line(v_pre_print || ' (null) :' || v_control_type);
    else
       dbms_output.put_line(v_pre_print || ' :' || v_control_type);
    end if;

end detector_plsql_if;

（2）、CASE 语句

CASE语句有两种形式：一种只进行等值比较，另一种可以进行多各种条件比较。

A、只进行等值比较

CASE test_value
 WHEN value1 THEN statement1;
[ WHEN value2 THEN statement2; ]
...
[ ELSE else_statement ; ]
END CASE;

Example：

create or replace procedure detector_plsql_case(
   v_control_type in varchar2)
is
   v_pre_print varchar2(100) := 'value of parameter [in] v_control_type';
begin

    case v_control_type
      when 'if' then
           dbms_output.put_line(v_pre_print || ' (if) :' || v_control_type);
      when 'case' then
           dbms_output.put_line(v_pre_print || ' (case) :' || v_control_type);
      else
           dbms_output.put_line(v_pre_print || ' :' || v_control_type);
    end case;

end detector_plsql_case;

B、进行多种条件的比较

CASE
         WHEN condition1 THEN statement1 ;
         [ WHEN condition2 THEN statement2; ]
         ...
         [ ELSE else_statements ; ]
END CASE;

CASE语句对每一个WHEN条件进行判断，当条件为真时，执行其后面的语句；如果所有条件都不为真，则执行ELSE后的语句。

Attention：在CASE语句中，当第一个WHEN条件为真时，执行其后的操作，操作完成后结束CASE语句，其它的WHEN条件不再判断，其后的操作也不执行。

Example：

create or replace procedure detector_plsql_case2(
 v_control_type in varchar2)
as 
  v_pre_print varchar2(100) := 'value of parameter [in] v_control_type';
begin 

  case
     when v_control_type = 'if' then
         dbms_output.put_line(v_pre_print || ' (if) :' || v_control_type);
     when v_control_type = 'case' then
          dbms_output.put_line(v_pre_print || ' (case) :' || v_control_type);
     when v_control_type is null then
          dbms_output.put_line(v_pre_print || ' (null) :' || v_control_type);
     else
          dbms_output.put_line(v_pre_print || ' :' || v_control_type);      
  end case;

end detector_plsql_case2;

二、循环结构

循环结构有3种形式，分别为简单循环、WHILE循环和FOR循环。

1、简单循环

LOOP
      sequence_of_statements ;
      EXIT [ WHEN condition ] ;
END LOOP;

Attetion：循环体一定要有EXIT语句，否则程序进入死循环。

Example：

create or replace procedure detector_plsql_loop(
    v_insert_cnt in number)
as
   v_deptno_max number ;
   v_cnt number := 0;
begin
   select max(deptno) into v_deptno_max from DEPT;
   loop
      v_deptno_max := v_deptno_max + 1;
      insert into DEPT(DEPTNO,DNAME,LOC) values
       (v_deptno_max,'name of '||v_deptno_max,'loc of '||v_deptno_max);
      v_cnt := v_cnt + 1;
      exit when v_cnt >= v_insert_cnt;
   end loop;
   commit;
end detector_plsql_loop;

2、WHILE循环

WHILE condition LOOP
      sequence_of_statements ;
END LOOP;

Example：

create or replace procedure detector_plsql_while(
       v_insert_cnt in number)
is
   v_deptno_max number;
   v_cnt number := 0;
begin
   select max(deptno) into v_deptno_max from dept;
   while v_cnt < v_insert_cnt loop
       v_deptno_max := v_deptno_max + 1;
       insert into dept (deptno,dname,loc) values
        (v_deptno_max,'name of ' || v_deptno_max,'loc of ' || v_deptno_max);
       --记得累加1, 否则,进入死循环
       v_cnt := v_cnt + 1;
   end loop;
   commit;
end detector_plsql_while;

3、FOR循环

在简单循环和WHILE循环中，程序需要定义循环变量v_cnt、v_insert_cnt来控制循环的结束，但在FOR循环中，不需要我们显示地定义循环变量，系统会自动一个循环变量，每次循环中，循环变量会自动增1或减1，以控制循环的次数。

FOR  loop_counter  IN  [ REVERSE ]  low_bound..high_bound  LOOP

       sequence_of_statement ;

LOOP END;

loop_counter为循环变量，low_bound为循环变量的下界，high_bound 为循环变量的上界。

Attention：系统会自动将循环变量定义为BINARY_INTERGER变量；

                   系统默认是从下界往上界循环，如果需要从上界往下界循环，需要使用REVERSE关键字；

                   循环变量只能在循环体中使用，不能在循环体外使用。

Example：

create or replace procedure detector_plsql_for
as
  v_deptno_max number;
begin
  select max(deptno) into v_deptno_max from dept;
  for v_cnt in reverse 1..5 loop
      v_deptno_max := v_deptno_max + 1;
      insert into dept (deptno,dname,loc) values
      (v_deptno_max,'name of ' || v_cnt ,'loc of ' || v_cnt);
  end loop;
  commit;
end detector_plsql_for;