基于.Net3.5编写,全异步操作。支持TCP、UDP两种方式，全事件模式通知。

最新推荐文章于 2024-06-27 14:13:45 发布
最新推荐文章于 2024-06-27 14:13:45 发布
阅读量2.1k 收藏
点赞数
分类专栏： VB 文章标签： tcp .net socket 服务器 server linq
' **********************************************************************
'                 适用于 .Net3.5版本
' **********************************************************************


Imports  System.Net.Sockets
 Imports  System.Net
 Imports  System.Collections.Generic
 Imports  System.Linq

 Public   Class Socket35

#Region "自定义Socket结构体"
    Public Class MySocket
        Private MyWorkSocket As Socket
        Private MyWorkID As Int32
        Private MyWorkName As String

        ''' <summary>
        ''' 设置工作Socket
        ''' </summary>
        ''' <value>Scoket对象</value>
        ''' <returns></returns>
        ''' <remarks></remarks>
        Public Property WorkSocket() As Socket
            Get
                Return MyWorkSocket
            End Get
            Set(ByVal value As Socket)
                MyWorkSocket = value
            End Set
        End Property

        ''' <summary>
        ''' Socket工作ID
        ''' </summary>
        ''' <value>Integer值</value>
        ''' <returns></returns>
        ''' <remarks></remarks>
        Public Property WorkID() As Int32
            Get
                Return MyWorkID
            End Get
            Set(ByVal value As Int32)
                MyWorkID = value
            End Set
        End Property

        ''' <summary>
        ''' Socket工作名称
        ''' </summary>
        ''' <value>String值</value>
        ''' <returns></returns>
        ''' <remarks></remarks>
        Public Property WorkName() As String
            Get
                Return MyWorkName
            End Get
            Set(ByVal value As String)
                MyWorkName = value
            End Set
        End Property
    End Class
#End Region

#Region "Socket协义类型"
    Public Enum SocketType
        TCP
        UDP
    End Enum
#End Region

    Private SocketID As Int32
    Private Server As Socket
    Private ServerHas As New HashSet(Of MySocket)
    Private MyReceiveBuff(), MySendBuff() As Byte
    Public Delegate Sub EventHandler(ByRef Sender As MySocket, ByVal e As SocketAsyncEventArgs)

    '-------------------------------------------------------------------------------------------------------------

    Public Event OnAccept As EventHandler '客户端连接事件
    Public Event OnReceive As EventHandler '客户端传入数据事件
    Public Event OnDisconnected As EventHandler  '客户端断开事件
    Public Event OnSent As EventHandler  '数据发送完毕


    '**********************************************************************
    '      Socket对象定义、接收数据、发送数据、外部事件引发
    '**********************************************************************

#Region "构造函数"
    ''' <summary>
    ''' 初始化Socket35
    ''' </summary>
    ''' <param name="ProtocolType">协议类型</param>
    ''' <remarks></remarks>
    Sub New(ByVal ProtocolType As SocketType)
        '复位SocketID值
        SocketID = 1

        Select Case ProtocolType
            Case SocketType.TCP
                Server = New Socket(AddressFamily.InterNetwork, Sockets.SocketType.Stream, Sockets.ProtocolType.Tcp)
            Case SocketType.UDP
                Server = New Socket(AddressFamily.InterNetwork, Sockets.SocketType.Dgram, Sockets.ProtocolType.Udp)
        End Select
    End Sub

    ''' <summary>
    ''' 初始化Socket35
    ''' </summary>
    ''' <param name="ProtocolType">协议类型</param>
    ''' <param name="ReceiveBuffLength">接收缓冲区长度</param>
    ''' <param name="SendBuffLength">发送缓冲区长度</param>
    ''' <remarks></remarks>
    Sub New(ByVal ProtocolType As SocketType, ByVal ReceiveBuffLength As Int32, ByVal SendBuffLength As Int32)
        '复位SocketID值
        SocketID = 1

        If ReceiveBuffLength < 1 OrElse SendBuffLength < 1 Then
            Throw New Exception("缓冲区大小必须大于0", New OverflowException)
            Exit Sub
        End If

        Select Case ProtocolType
            Case SocketType.TCP
                Server = New Socket(AddressFamily.InterNetwork, Sockets.SocketType.Stream, Sockets.ProtocolType.Tcp)
            Case SocketType.UDP
                Server = New Socket(AddressFamily.InterNetwork, Sockets.SocketType.Dgram, Sockets.ProtocolType.Udp)
        End Select

        ReceiveBuff = ReceiveBuffLength
        SendBuff = SendBuffLength
    End Sub
#End Region

#Region "连接服务器"
    ''' <summary>
    ''' 连接到服务器端
    ''' </summary>
    ''' <param name="Ip">IP地址</param>
    ''' <param name="Port">端口</param>
    ''' <returns>MySocket对象</returns>
    ''' <remarks></remarks>
    Public Function Connect(ByVal Ip As String, ByVal Port As Int32) As MySocket
        Dim MS As New MySocket

        '复位SocketID值
        SocketID = 1

        Server.Connect(Ip, Port)
        MS.WorkID = SocketID
        MS.WorkSocket = Server
        ServerHas.Add(MS)

        Return MS
    End Function

    ''' <summary>
    ''' 连接到服务器端
    ''' </summary>
    ''' <param name="RemotoEndPoint">远程服务器节点</param>
    ''' <returns>MySocket对象</returns>
    ''' <remarks></remarks>
    Public Function Connect(ByVal RemotoEndPoint As IPEndPoint) As MySocket
        Dim MS As New MySocket

        '复位SocketID值
        SocketID = 1

        Server.Connect(RemotoEndPoint)
        MS.WorkID = SocketID
        MS.WorkSocket = Server
        ServerHas.Add(MS)

        Return MS
    End Function
#End Region

#Region "接收缓冲区大小"
    ''' <summary>
    ''' 读取或设置接收缓冲区大小
    ''' </summary>
    ''' <value></value>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Property ReceiveBuff() As Int32
        Get
            Return MyReceiveBuff.Length
        End Get
        Set(ByVal value As Int32)
            ReDim MyReceiveBuff(value)
        End Set
    End Property
#End Region

#Region "发送缓冲区大小"
    ''' <summary>
    ''' 读取或设置发送缓冲区大小
    ''' </summary>
    ''' <value></value>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Property SendBuff() As Int32
        Get
            Return MySendBuff.Length
        End Get
        Set(ByVal value As Int32)
            ReDim MySendBuff(value)
        End Set
    End Property
#End Region

#Region "绑定地址和端口"
    ''' <summary>
    ''' 绑定地址和端口
    ''' </summary>
    ''' <param name="Ip">Ip地址</param>
    ''' <param name="Port">端口</param>
    ''' <remarks></remarks>
    Public Overloads Sub Bind(ByVal Ip As String, ByVal Port As Int32)

        Server.Bind(New IPEndPoint(IPAddress.Parse(Ip), Port))
    End Sub

    ''' <summary>
    ''' 绑定地址和端口
    ''' </summary>
    ''' <param name="IpEndPoint">Ip地址和端口的节点</param>
    ''' <remarks></remarks>
    Public Overloads Sub Bind(ByVal IpEndPoint As IPEndPoint)

        Server.Bind(IpEndPoint)
    End Sub
#End Region

#Region "侦听数"
    ''' <summary>
    ''' 设置侦听数
    ''' </summary>
    ''' <param name="val">侦听数</param>
    ''' <remarks></remarks>
    Public Sub Listen(ByVal val As Int32)
        Server.Listen(val)
    End Sub
#End Region

#Region "开始侦听"
    ''' <summary>
    ''' 开始侦听客户端连接
    ''' </summary>
    ''' <remarks></remarks>
    Public Sub Start()
        Select Case Server.ProtocolType
            Case ProtocolType.Tcp
                StartForTcp()
            Case ProtocolType.Udp
                StartForUdp()
        End Select
    End Sub

    Private Sub StartForTcp()
        Dim acc As New SocketAsyncEventArgs

        AddHandler acc.Completed, AddressOf Accept_Completed
        Server.AcceptAsync(acc)
    End Sub

    Private Sub StartForUdp()
        Dim acc As New SocketAsyncEventArgs

        AddHandler acc.Completed, AddressOf UDP_Receive_Completed
        acc.RemoteEndPoint = Server.LocalEndPoint
        acc.SetBuffer(MyReceiveBuff, 0, MyReceiveBuff.Length)
        Server.ReceiveFromAsync(acc)
    End Sub
#End Region

#Region "客户端连接"
    Private Sub Accept_Completed(ByVal Sender As Object, ByVal e As SocketAsyncEventArgs)
        '事件进入
        Dim MS As New MySocket
        Dim Client As Socket

        Client = e.AcceptSocket
        MS.WorkID = SocketID
        MS.WorkSocket = Client

        RaiseEvent OnAccept(MS, e)

        If IsNothing(Client) OrElse Not Client.Connected Then
            If Not IsNothing(ServerHas) Then
                ServerHas.Remove(MS)
            End If

            Exit Sub
        Else
            ServerHas.Add(MS)
        End If

        '接收数据
        RemoveHandler e.Completed, AddressOf Accept_Completed
        AddHandler e.Completed, AddressOf TCP_Receive_Completed
        e.SetBuffer(MyReceiveBuff, 0, MyReceiveBuff.Length)
        Client.ReceiveAsync(e)
        SocketID += 1
        Start()
    End Sub
#End Region

#Region "客户端传入数据(TCP)"
    Private Sub TCP_Receive_Completed(ByVal Sender As Object, ByVal e As SocketAsyncEventArgs)
        Dim MS As MySocket
        Dim Client As Socket

        Client = Sender
        MS = GetMySocketBySocket(Client)

        If e.BytesTransferred = 0 Then
            On Error Resume Next

            ServerHas.Remove(MS)
            '引发客户端断开事件
            RaiseEvent OnDisconnected(MS, e)
            '执行断开操作
            Client.Close()
            Client = Nothing
            Exit Sub
        End If

        '事件进入
        RaiseEvent OnReceive(MS, e)

        If IsNothing(Client) OrElse Client.Connected = False Then
            If Not IsNothing(ServerHas) Then
                ServerHas.Remove(MS)
            End If

            Exit Sub
        End If

        '清理缓冲数据
        Array.Clear(e.Buffer, 0, e.Buffer.Length)

        '接收数据
        Client.ReceiveAsync(e)
    End Sub
#End Region

#Region "客户端传入数据(UDP)"
    Public Sub UDP_Receive_Completed(ByVal Sender As Object, ByVal e As SocketAsyncEventArgs)
        Dim MS As New MySocket
        Dim Client As Socket

        Client = Sender
        MS.WorkSocket = Client

        '事件进入
        RaiseEvent OnReceive(MS, e)

        If IsNothing(Client) OrElse Client.Connected = False Then
            If Not IsNothing(ServerHas) Then
                ServerHas.Remove(MS)
            End If

            Exit Sub
        End If

        '清理缓冲数据
        Array.Clear(e.Buffer, 0, e.Buffer.Length)

        '接收数据
        Client.ReceiveFromAsync(e)
    End Sub
#End Region

#Region "发送数据"
    ''' <summary>
    ''' 发送Socket数据
    ''' </summary>
    ''' <param name="SocketID">Socket ID值</param>
    ''' <param name="DataBuff">Byte数组</param>
    ''' <returns>True:发送成功 False:发送失败</returns>
    ''' <remarks></remarks>
    Public Overloads Function Send(ByVal SocketID As Int32, ByVal DataBuff() As Byte) As Boolean
        Dim MS As MySocket
        Dim SD As New SocketAsyncEventArgs

        MS = GetMySocketByID(SocketID)

        If IsNothing(MS) OrElse IsNothing(MS.WorkSocket) OrElse MS.WorkSocket.Connected = False Then
            Return False
        End If

        SD.SetBuffer(DataBuff, 0, DataBuff.Length)
        SD.UserToken = MS.WorkSocket
        AddHandler SD.Completed, AddressOf Send_Completed
        MS.WorkSocket.SendAsync(SD)

        '进入接收数据异步
        Call ReceiveAfterSent(MS.WorkSocket)

        Return True
    End Function

    ''' <summary>
    ''' 发送Socket数据
    ''' </summary>
    ''' <param name="SocketName">Socket 名称</param>
    ''' <param name="DataBuff">Byte数组</param>
    ''' <returns>True:发送成功 False:发送失败</returns>
    ''' <remarks></remarks>
    Public Overloads Function Send(ByVal SocketName As String, ByVal DataBuff() As Byte) As Boolean
        Dim MS As MySocket
        Dim SD As New SocketAsyncEventArgs

        MS = GetMySocketByName(SocketName)

        If IsNothing(MS) OrElse IsNothing(MS.WorkSocket) OrElse MS.WorkSocket.Connected = False Then
            Return False
        End If

        SD.SetBuffer(DataBuff, 0, DataBuff.Length)
        SD.UserToken = MS.WorkSocket
        AddHandler SD.Completed, AddressOf Send_Completed
        MS.WorkSocket.SendAsync(SD)

        '进入接收数据异步
        Call ReceiveAfterSent(MS.WorkSocket)

        Return True
    End Function

    ''' <summary>
    ''' 发送Socket数据
    ''' </summary>
    ''' <param name="Socket">Socket名称</param>
    ''' <param name="DataBuff">Byte数组</param>
    ''' <returns>True:发送成功 False:发送失败</returns>
    ''' <remarks></remarks>
    Public Overloads Function Send(ByVal Socket As Socket, ByVal DataBuff() As Byte) As Boolean
        Dim SD As New SocketAsyncEventArgs

        If IsNothing(Socket) OrElse Socket.Connected = False Then
            Return False
        End If

        SD.SetBuffer(DataBuff, 0, DataBuff.Length)
        SD.UserToken = Socket
        AddHandler SD.Completed, AddressOf Send_Completed
        Socket.SendAsync(SD)

        '进入接收数据异步
        Call ReceiveAfterSent(Socket)

        Return True
    End Function

    Private Sub Send_Completed(ByVal Sender As Socket, ByVal e As SocketAsyncEventArgs)
        '异步发送完成操作
        Dim MS As MySocket

        MS = GetMySocketBySocket(Sender)
        RaiseEvent OnSent(MS, e)

        If IsNothing(Sender) OrElse Sender.Connected = False Then
            If Not IsNothing(ServerHas) Then
                ServerHas.Remove(MS)
            End If
        End If
    End Sub

    Private Sub ReceiveAfterSent(ByVal Socket As Socket)
        '发送数据后开始接收
        Dim SA As New SocketAsyncEventArgs

        SA.SetBuffer(MyReceiveBuff, 0, MyReceiveBuff.Length)

        Select Case Server.ProtocolType
            Case ProtocolType.Tcp
                'TCP接收
                AddHandler SA.Completed, AddressOf TCP_Receive_Completed
                Socket.ReceiveAsync(SA)
            Case ProtocolType.Udp
                'UDP接收
                AddHandler SA.Completed, AddressOf UDP_Receive_Completed
                SA.RemoteEndPoint = Socket.LocalEndPoint
                Socket.ReceiveFromAsync(SA)
        End Select
    End Sub
#End Region

#Region "得到ServerHas数据信息"
    ''' <summary>
    ''' 得到当前Socket列表
    ''' </summary>
    ''' <returns>String(,1)一维数组。0:Socket的ID 1:Socket的名称</returns>
    ''' <remarks></remarks>
    Public Function GetServerList() As String(,)
        If IsNothing(ServerHas) Then
            Throw New Exception("未初始化本类")
            Exit Function
        End If

        Dim Result(,) As String
        Dim Count As Int32
        Dim i As Int32

        i = 0
        Count = ServerHas.Count
        ReDim Result(Count - 1, 1)

        Dim Data = From s In ServerHas _
                     Select s.WorkID, s.WorkName

        For Each item In Data
            Result(i, 0) = item.WorkID.ToString
            Result(i, 1) = item.WorkName
            i += 1
        Next

        Return Result
    End Function
#End Region

#Region "清除Socket对象"
    ''' <summary>
    ''' 清除Socket对象
    ''' </summary>
    ''' <param name="SocketID">Socket的ID值</param>
    ''' <remarks></remarks>
    Public Sub Close(ByVal SocketID As Int32)
        On Error Resume Next

        Dim CS As MySocket

        CS = GetMySocketByID(SocketID)
        CS.WorkSocket.Close()
        CS.WorkSocket = Nothing
        CS = Nothing
        ServerHas.Remove(CS)
    End Sub

    ''' <summary>
    ''' 清除Socket对象
    ''' </summary>
    ''' <param name="SocketName">Socket的名称</param>
    ''' <remarks></remarks>
    Public Sub Close(ByVal SocketName As String)
        On Error Resume Next

        Dim CS As MySocket

        CS = GetMySocketByName(SocketName)
        CS.WorkSocket.Close()
        CS.WorkSocket = Nothing
        CS = Nothing
        ServerHas.Remove(CS)
    End Sub

    ''' <summary>
    ''' 清除Socket对象
    ''' </summary>
    ''' <param name="Socket">Socket对象</param>
    ''' <remarks></remarks>
    Public Sub Close(ByVal Socket As Socket)
        On Error Resume Next

        Dim CS As MySocket

        CS = GetMySocketBySocket(Socket)
        Socket.Close()
        Socket = Nothing
        CS = Nothing
        ServerHas.Remove(CS)
    End Sub

    ''' <summary>
    ''' 清除Socket对象
    ''' </summary>
    ''' <param name="MySocket">MySocket对象</param>
    ''' <remarks></remarks>
    Public Sub Close(ByVal MySocket As MySocket)
        On Error Resume Next

        MySocket.WorkSocket.Close()
        MySocket.WorkSocket = Nothing
        ServerHas.Remove(MySocket)
    End Sub
#End Region

    '**********************************************************************
    '                LinQ 查询 MySocket结构体
    '**********************************************************************

#Region "得到MySocket对象"
    ''' <summary>
    ''' 以Socket的ID值得到MySocket对象
    ''' </summary>
    ''' <param name="ID">SocketID值</param>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Function GetMySocketByID(ByVal ID As Int32) As MySocket

        If IsNothing(ServerHas) Then
            Return Nothing
        End If

        Dim Result = From s In ServerHas _
                     Where s.WorkID = ID

        If Result.Count = 0 Then
            Return Nothing
        End If

        Return Result.First
    End Function

    ''' <summary>
    ''' 以Socket的名称值得到MySocket对象
    ''' </summary>
    ''' <param name="Name"></param>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Function GetMySocketByName(ByVal Name As String) As MySocket

        If IsNothing(ServerHas) Then
            Return Nothing
        End If

        Dim Result = From s In ServerHas _
                     Where s.WorkName = Name

        If Result.Count = 0 Then
            Return Nothing
        End If

        Return Result.First
    End Function

    ''' <summary>
    ''' 以Socket对象得到MySocket对象
    ''' </summary>
    ''' <param name="Socket">Socket对象</param>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Function GetMySocketBySocket(ByVal Socket As Socket) As MySocket
        Dim SocketHandle As Int32

        SocketHandle = Socket.Handle

        If IsNothing(Socket) OrElse IsNothing(ServerHas) Then
            Return Nothing
        End If

        Dim Result = From s In ServerHas _
                            Where s.WorkSocket.Handle = SocketHandle

        If Result.Count = 0 Then
            Return Nothing
        End If

        Return Result.First
    End Function
#End Region

#Region "释放对象"
    Public Sub Dispose()
        On Error Resume Next

        Server.Close()
        Server = Nothing

        For Each item In ServerHas
            item.WorkSocket.LingerState.Enabled = False
            item.WorkSocket.Shutdown(SocketShutdown.Both)
            item.WorkSocket.Close()
            item.WorkSocket = Nothing
        Next

        ServerHas.Clear()
        ServerHas = Nothing
    End Sub
#End Region

End Class



 

调用示例:

TCP:

 

Dim  Server  As  Socket35
Server  =   New  Socket35(Socket35.SocketType.TCP,  1024 ,  1024 )
Server.Bind( New  IPEndPoint(IPAddress.Any,  5614 ))
Server.Listen( 100 )

 ' Socket事件
AddHandler  server.OnAccept,  AddressOf  accept
 AddHandler  server.OnReceive,  AddressOf  received
 AddHandler  server.OnSent,  AddressOf  sent
 AddHandler  server.OnDisconnected,  AddressOf  disconnect

 ' 开始监听
Server.Start()

 ' Socket连接进入
Private   Sub accept(ByRef Sender As Socket35.MySocket, ByVal e As SocketAsyncEventArgs)
    
    Sender.WorkName = Now.ToString
    Debug.Write(Sender.WorkID)

End Sub


' Socket接收入数
Private   Sub received(ByRef Sender As Socket35.MySocket, ByVal e As SocketAsyncEventArgs)

    Dim Content As String
    Dim SendBuff() As Byte

    Content = System.Text.Encoding.GetEncoding("gb2312").GetString(e.Buffer)
    server.Send(Sender.WorkSocket, SendBuff)

End Sub

' 查看当前Socket活动连接信息(二维数组)
Dim  SocketList(,)  As   String
SocketList  =  Socket35.GetServerList()

 

UDP:

 

Dim  Server  As  Socket35
Server  =   New  Socket35(Socket35.SocketType.UDP,  1024 ,  1024 )
Server.Bind( New  IPEndPoint(IPAddress.Any,  5614 ))

 AddHandler  server.OnAccept,  AddressOf  accept
 AddHandler  server.OnReceive,  AddressOf  received
 AddHandler  server.OnSent,  AddressOf  sent
 AddHandler  server.OnDisconnected,  AddressOf  disconnect
Server.Start()

 ' 接收UDP传来的数据
Private   Sub received(ByRef Sender As Socket35.MySocket, ByVal e As SocketAsyncEventArgs)

    Dim Content As String
    Dim SendBuff() As Byte

    Content = System.Text.Encoding.GetEncoding("gb2312").GetString(e.Buffer)

    Server.Send(Sender.WorkSocket, SendBuff)

End Sub
job_2006
关注
专栏目录
电子商务平台技术选型和架构设计
程序员光剑
08-04 1846
在这个时代，在线购物网站和电子商务平台已经成为促进互联网经济增长、服务用户和客户的重要平台。如何搭建一个具备高可用性、安全可靠的电商系统，是一个复杂的工程。作为一名技术人员，我们需要了解当前最新的电商平台架构，并对它们进行选择和优化，来满足我们的业务需求。本文将通过“十八篇”的方式，从基础知识、数据库、前端、后端、中间件、缓存、搜索引擎、消息队列等多个角度，带领读者掌握现代电商平台架构的核心技术细节。
第10课：主流的分布式消息队列方案解读及比较
Jin_Kwok的博客
10-28 871
消息队列中间件是分布式系统中重要的组件，主要解决应用耦合、异步消息、流量削锋等问题。它可以实现高性能、高可用、可伸缩和最终一致性架构，是大型分布式系统不可缺少的中间件。 消息队列在电商系统、消息通讯、日志收集等应用中扮演着关键作用，以阿里为例，其研发的消息队列（RocketMQ）在历次天猫 “双十一” 活动中支撑了万亿级的数据洪峰，为大规模交易提供了有力保障。 作为提升应用性能的重要手段，分布式消...
dot_net3.5异步收发socket--客户端
ikmb的专栏
09-08 1545
 说明：作者：敖士伟一、客户端收发类为SocketAsyncClient1、构造函数SocketAsyncClient(string ip, Int32 port)初始远程主机IP和端口；2、方法SendMsg(string msg)异步发送消息；3、委托事件ReceiveMSGEvent接收回发消息。 二、使用此类的方法注册接收回发事件SocketAsyncCli
.Net3.5 Socket事件通知封装类
Yellow 痕迹
05-06 982
基于.Net3.5编写,全异步操作。支持TCP、UDP两种方式，全事件模式通知。Socket35.vb **********************************************************************                适用于 .Net3.5版本**************************************
学懂C#编程：常用高级技术——学会C#多线程开发（二）之 处理异步Task应用
最新发布
martian665的专栏
06-27 456
学懂C#编程：常用高级技术——学会C#多线程开发（二）之 处理异步Task应用
C#基础：异步调用
DreamWeaver2015的博客
11-10 221
首先来看一个简单的例子： 小明在烧水，等水烧开以后，将开水灌入热水瓶，然后开始整理家务 小文在烧水，在烧水的过程中整理家务，等水烧开以后，放下手中的家务活，将开水灌入热水瓶，然后继续整理家务 这也是日常生活中很常见的情形，小文的办事效率明显要高于小明。从C#程序执行的角度考虑，小明使用的同步处理方式，而小文则使用的异步处理方式。 同步处理方式下，事务是按顺序一件一件处理的...
VB.NET中使用代表对方法异步调用
06-21 370
为什么要使用异步调用(Asynchronous Method Execution) 按照我们常规的思维方式，计算机应该是干完一件事，然后再干下一件。用术语来说，这种执行任务的方式叫做同步执行（Synchronous Execution）。既然这样，那么为什么要引入异步执行的概念呢？原因很简单，因为同步执行在有些情况下效果不理想，不能完成我们预期的目的。举两个简单的例子来说明一下这个问题。...
基于C#的UDP协议的异步实现
weixin_30399055的博客
08-15 166
一、摘要 　　总结UDP传输协议的异步实现。 二、实验平台 　　visual studio 2010 三、实验实例 　　服务器端代码： using System; using System.Collections.Generic; using System.Text; using System.Net; using System.Net.Sockets; us...
一系列令人敬畏的.NET核心库，工具，框架和软件
weixin_30530939的博客
06-17 3323
内容 一般 框架，库和工具 API 应用框架 应用模板 身份验证和授权 Blockchain 博特 构建自动化 捆绑和缩小 高速缓存 CMS 代码分析和指标 压缩 编译器，管道工和语言 加密 数据库 数据库驱动 数据库工具和实用程序 日期和时间 分布式计算 电子商务和支付 例外 功能编程 图像 GUI IDE 国际化 国际奥林匹克委...
通俗易懂，什么是.NET?什么是.NET Framework？什么是.NET Core? .Net Web开发技术栈...
07-02 2043
通俗易懂，什么是.NET?什么是.NET Framework？什么是.NET Core? 什么是.NET？什么是.NET Framework?本文将从上往下，循序渐进的介绍一系列相关.NET的概念，先从类型系统开始讲起，我将通过跨语言操作这个例子来逐渐引入一系列.NET的相关概念，这主要包括：CLS、CTS(CLI)、FCL、Windows下CLR的相关核心组成、Wind...
Java Web学习总结（39）——JavaEE常用的Jar详解
科技D人生
10-11 2142
activation：与javaMail有关的jar包，使用javaMail时应与mail.jar (mail.jar和activation.jar)一起加入到lib中去，具体负责mail的数据源和类型等。ApacheActiveMQ：Apache出品，最流行的，能力强劲的开源消息总线。ActiveMQ是一个完全支持JMS1.1和J2EE 1.4规范的 JMS Provider实现。ajaxtag
简单实现C#异步操作
01-01
在.net4.0以后异步操作,并行计算变得异常简单,但是由于公司项目开发基于.net3.5所以无法用到4.0的并行计算以及Task等异步编程。因此,为了以后更方便的进行异步方式的开发,我封装实现了异步编程框架,通过BeginInvoke、EndInvoke的方式实现异步编程。 一、框架结构 整个框架包括四个部分 1、基类抽象Opeartor 我把每个异步执行过程称为一个Operate,因此需要一个Opeartor去执行 2、FuncAsync 异步的Func 3、ActionAsync 异步的Action 4、Asynchorus 对ActionAsync和FuncAsync的封装 Opera
.Net 3.5 使用 System.Threading.Task
02-10
.Net 3.5 下使用的 System.Threading.Tasks。 安装完成后，添加引用时只需要在安装目录 C:\Program Files (x86)\Microsoft Reactive Extensions\Redist\DesktopV2 下找到 System.Threading.dll，添加即可
多线程线程池使用 （C#3.5） 高效
10-17
多线程线程池使用 （C#3.5） 高效
.NET 3.5 异步 socket SocketAsyncEventArgs ---Clinet
ikmb的专栏
09-07 1373
作者：敖士伟基于：http://www.codeproject.com/KB/IP/socketasynceventargssampl.aspx
.net 3.5的Socket异步完成端口
weixin_30410999的博客
06-28 109
根据.net 3.5中的异步Socket完成的一个模块，用队列来处理tcp数据包的粘包问题，用事件将数据包通知给上层调用；代码写的不是很好，发出来希望和大家共同交流学习。因为是实际项目中用的模块，所以有些地方是按照项目需求做的，大体的结构还是没问题的，除了代码写的差点外！！！一，主要类，进行异步Socket的基本处理，.net3.5中的Socket完成端口模型的实现Net_Serverp...
asp.net 3.5异步调用方法小结
weixin_30952535的博客
02-21 492
web请求 RssAsync.aspx //这是调用本网站的两个页面，也可以设置成外部网站页面 conststringrssFeed1="http://localhost:2289/AsnicTest/WebRequest1.aspx"; conststringrssFeed2="http://localhost:2289/AsnicTest/Web...
.NET3.5下Asp.net如何异步调用WebService
技术就是个纸老虎---为之，则难者亦易矣；不为，则易者亦难矣。
12-11 2744
在网上也找了一些，发现要么题目和内容不对应，明明是在Winform下异步调用，却写成在Asp.net异步调用WebService，有的调用方式在.NET3.5下不能通过，.NET3.5下取消了BeginXXXX,EndXXXX，奇怪，而用了以下方式。建立一个WebService和一个WebApplication如图所示：WebService代码为：using System;using System.Collections.Generic;using System.Linq;using System.Web;
.net如何实现异步方法
weixin_42576804的博客
02-11 567
在 .NET 中，有几种不同的方法可以实现异步方法。其中一种是使用 async 和 await 关键字，另一种是使用 Task 对象。 例如，下面是一个使用 async 和 await 关键字的示例： public async Task<int> GetDataAsync() { int data = await Task.Run(() => GetData()); ...
c#　.ｎｅｔ３．５实现异步编程
05-30
在.NET Framework 3.5中，可以使用以下方法实现异步编程： 1. 使用委托和回调函数：可以使用委托和回调函数来实现异步编程。委托可以将一个方法作为参数传递给另一个方法，并且可以异步调用该方法。回调函数则是在异步操作完成后执行的方法。 2. 使用线程池：可以使用线程池来实现异步编程。线程池是一组已创建的线程，可以在需要时重复使用，从而避免不必要的线程创建和销毁。 3. 使用异步委托：可以使用.NET Framework 3.5中新引入的异步委托来实现异步编程。异步委托可以将一个方法异步调用，并在异步操作完成后返回结果。 4. 使用异步方法：可以使用.NET Framework 3.5中的异步方法来实现异步编程。异步方法使用async和await关键字，可以将一个方法异步调用，并在异步操作完成后返回结果。 需要注意的是，异步编程需要仔细处理异常和取消操作，以确保应用程序的正确性和稳定性。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值