OLE 对象

sp_OACreate 创建 OLE 对象实例。

• 第一个参数为 OLE 对象的程序标识符（ProgID）或类标识符（CLSID）。
• 第二个参数为返回的对象令牌，必须是数据类型为 int 的局部变量，在后面的方法中都要用到对象令牌。输出参数，必须加 OUT 或 OUTPUT。

sp_OAMethod 调用 OLE 对象的方法。

• 第一个参数为对象令牌。
• 第二个参数为方法名称。
• 第三个参数为方法的返回值，如果方法返回的是对象，则该参数类型为 int。输出参数，必须加 OUT 或 OUTPUT。
• 第四个及以后的参数为方法的参数值，如果方法的参数是输出参数，则要加上 OUT 或 OUTPUT。
• sp_OAMethod 也可用来获取属性值。

sp_OAGetErrorInfo 获取 OLE 自动化错误信息。

• 第一个参数为对象令牌。
• 第二个参数为错误信息的来源。输出参数，必须加 OUT 或 OUTPUT。
• 第三个参数为错误的描述。输出参数，必须加 OUT 或 OUTPUT。

sp_OADestroy 释放已创建的 OLE 对象。

• 第一个参数为对象令牌。

另外，sp_OAGetProperty 获取 OLE 对象的属性值，sp_OASetProperty 将 OLE 对象的属性设置为新值，sp_OAStop 停止服务器范围内的 OLE 自动化存储过程执行环境。 

 

DECLARE @errCode int

DECLARE @fso int

EXEC @errCode = sp_OACreate 'Scripting.FileSystemObject', @fso OUT /*等效于：set fso = Server.CreateObject("Scripting.FileSystemObject")*/
if @errCode <> 0
BEGIN
    DECLARE @description varchar(256)
    EXEC sp_OAGetErrorInfo @fso, NULL, @description OUT
    PRINT @description /*SQL 查询分析器中有效*/
END

DECLARE @exists bit
EXEC sp_OAMethod @fso, 'FileExists', @exists OUT, 'C:/foo.txt' /*等效于：exists = fso.FileExists("C:/foo.txt")*/
PRINT @exists /*SQL 查询分析器中有效*/

DECLARE @f int
EXEC sp_OAMethod @fso, 'CreateTextFile', @f OUT, 'C:/foo.txt', 1 /*等效于：set f = fso.CreateTextFile("C:/foo.txt", true)*/
EXEC sp_OAMethod @f, 'Write', NULL, '写一行内容' /*等效于：f.Write("写入内容")*/
EXEC sp_OAMethod @f, 'Close' /*等效于：f.Close*/
EXEC sp_OADestroy @f /*等效于：set f = nothing*/

EXEC sp_OADestroy @fso /*等效于：set fso = nothing*/