BAT批处理在windows下面实现从FTP上传下载文件

以下内容拷贝保存为.bat文件即可，注意不要保存为ftp.bat(该名字在windows下面可能会导致批处理进入死循环)，其他名字都可以：

@ECHO OFF
COLOR 3F
rem ========修改设置相关默认连接参数=====================

rem 设置连接FTP的默认IP地址
set p_ip_default=192.168.0.11
rem 设置连接FTP的默认用户名
set p_username=admin
rem 设置连接FTP的默认密码
set p_password=ftp123

rem 设置指定FTP目录
set p_ftp_dir=update
rem 设置指定本地目录
set p_local_dir=.\update

echo ================================================
echo 注：直接按回车连接默认ftp:【%p_ip_default%】
echo ================================================
set /P p_ip=请输入IP：
if {%p_ip%}=={} (set p_ip=%p_ip_default%) else (
set /P p_username=请输入登陆名：
set /P p_password=请输入密码：
)

cls
echo.
echo ================================================
echo FTP:%p_ip%
echo FTP目录：%p_ftp_dir%
echo 本地目录：%p_local_dir%
echo.
echo 【1】上传文件       【2】下载文件
echo ================================================
:set_p_tag
set /P p_tag=请输入(1或2)选择：
if {%p_tag%}=={} goto set_p_tag

if not exist %p_local_dir% md %p_local_dir%

echo =========FTP：%p_ip%===========================
echo open %p_ip%>tmp.up
echo %p_username%>>tmp.up
echo %p_password%>>tmp.up
echo cd %p_ftp_dir%>>tmp.up
Echo binary>>tmp.up
Echo prompt>>tmp.up
Echo lcd %p_local_dir%>>tmp.up
rem 把本地指定目录的所有文件拷贝到FTP指定目录
if %p_tag% == 1 Echo mput *.*>>tmp.up
rem 把FTP指定目录的所有文件拷贝到本地指定目录
if %p_tag% == 2 Echo mget *.*>>tmp.up
Echo bye>>tmp.up
FTP -s:tmp.up
del /f /q tmp.up
echo =================ok=============================
pause