(delphi11最新学习资料) Object Pascal 学习笔记---第12章第1节 （ 类静态方法与Windows API回调）

12.1.4 类静态方法与Windows API回调

​ 静态类方法没有隐藏的Self参数意味着静态类方法可以作为回调函数传递给操作系统（例如，在Windows上）。实际上，您可以声明一个具有stdcall调用约定的静态类方法，并将其用作直接的Windows API回调，就像我在StaticCallBack示例中的TimerCallBack方法中所做的那样：

type  
  TFormCallBack = class(TForm)  
  ListBox1: TListBox;  
  procedure FormCreate(Sender: TObject);  
  private  
  class var  
  NTimerCount: Integer;  
  public  
  procedure AddToList (const AMessage: string);  
  class procedure TimerCallBack(hwnd: THandle;  
    uMsg, idEvent, dwTime: Cardinal); static; stdcall;  
  end;

​ 类数据被用作回调计数器。OnCreate处理器通过将地址传递给静态类过程来调用SetTimer API：

procedure TFormCallBack.FormCreate(Sender: TObject);  
var  
  Callback: TFNTimerProc;  
begin  
  NTimerCount := 0;  
  Callback := TFNTimerProc(@TFormCallBack.TimerCallBack);  
  SetTimer(Handle, TIMERID, 1000, Callback);  
end;

注解：TFNTimeProc的参数是一个方法指针，这就是为什么方法的名称要以@开头或者通过使用Addr函数来获取方法地址。这是因为我们需要获取方法的地址，而不是执行方法。

​ 现在实际的回调函数增加了计时器并更新了窗体，通过引用相应的全局变量来指代它——这应该避免，但需要在演示中增加一些复杂性，因为类方法不能将窗体作为Self引用：

class procedure TFormCallBack.TimerCallBack(  
  hwnd: THandle; uMsg, idEvent, dwTime: Cardinal);  
begin  
  try  
    Inc(NTimerCount);  
    FormCallBack.AddToList(  
      IntToStr(NTimerCount) + ' at ' + TimeToStr(Now));  
  except on E: Exception do  
    Application.HandleException(nil);  
  end;  
end;

​ try-except块在那里是为了避免任何异常被发送回Windows——这是您必须对回调或DLL函数一致遵守的规则。

12.1.5 类属性

使用静态类方法的原因之一是实现类属性。什么是类属性？与标准属性一样，类属性是一个与读写机制关联的符号。与标准属性不同的是，类属性与类相关，并且必须使用类数据或静态类方法来实现。TBase 类（再次来自 ClassStatic 示例）用这两种方式中定义了两个类属性：

type
  TBase = class
  private
    class var
      FMyName: string;
  public
    class function GetMyName: string; static;
    class procedure SetMyName(Value: string); static;
    class property MyName: string read GetMyName write SetMyName;
    class property DirectName: string read FMyName write FMyName;
  end;

在这个例子中，TBase 类有两个类属性，一个是 MyName，它通过类方法 GetMyName 和 SetMyName 进行读写，另一个是 DirectName，它直接读写类变量 FMyName。

12.1.6 带有实例计数器的类

​ 类数据和类方法可用于保存类整体方面的信息。这种类型的信息的一个示例可以是该类创建的实例总数或当前存在的实例数。CountObj 示例演示了这种情景。该程序并不是非常有用，因为它只关注一个特定的问题。目标对象有一个简单的类，只存储一个数值：

type
  TCountedObj = class(TObject)
  private
    FValue: Integer;
  private
    class var
      FTotal: Integer;
      FCurrent: Integer;
  public
    constructor Create;
    destructor Destroy; override;
    property Value: Integer read FValue write FValue;
  public
    class function GetTotal: Integer;
    class function GetCurrent: Integer;
  end;

​ 每次创建对象时，程序都会递增两个计数器。每次销毁对象时，当前计数器都会减少：

constructor TCountedObj.Create(AOwner: TComponent);
begin
  inherited Create;
  Inc(FTotal);
  Inc(FCurrent);
end;

destructor TCountedObj.Destroy;
begin
  Dec(FCurrent);
  inherited Destroy;
end;

​ 可以在不引用特定对象的情况下访问类信息。实际上，可能在某个时刻内存中没有对象：

class function TCountedObj.GetTotal: Integer;
begin
  Result := FTotal;
end;

​ 可以使用类似以下的代码显示当前状态：

Label1.Text := TCountedObj.GetCurrent.ToString + '/' + TCountedObj.GetTotal.ToString;

​ 在演示中，这段代码在一个定时器中执行的，它更新一个标签，因此它不需要引用任何特定的对象实例，也不是直接由任何手动操作触发的。示例中的按钮只是创建和释放一些对象，或者将一些对象保留在内存中（实际上，该程序存在一些潜在的内存泄漏）。