前言:X86段式寻址写的人多了,我综合了网上多个版本和多本正版盗版书籍,加上自己的一点点领悟,终于貌似(之所以加个貌似,是因为可能以后还有修改)搞清楚了,特此记录。
本文特点:理论结合实践,有图有代码从而有真相。
说到X86平台,不得不说80386,因为很多操作系统原型都是基于这个平台写的,所以学习操作系统应该把这个平台搞清楚。关于硬件结构特点的介绍此处省略很多字。对于本篇文章,有两点很重要,一是物理地址的计算,CS和IP为80386的寄存器,物理地址 = (段地址 << 4) + 偏移地址 ,也就是 (CS里的值 << 4) + IP里的值。在80386PC机中,任意时刻,设CS中的内容为M, IP中的内容为N,8086CPU将从内存 M X 16 + N 单元开始,读取一条指令并执行。另外一点,就是GDT和LDT,在此我们不整那么复杂只说GDT。GDT里有很多项,每一项是个的数据结构,一共64位,里面某个位或某几位代表了一些属性,代码段和数据段的数据结构如图一。比较重要的是base,一般存放物理地址。你可以自己定义一个数据结构命名为GdtTest1,按照图一的要求分配空间,那么这个GdtTest1就是GDT其中一个项了。把多个项放在一起就形成了一个类似存储表的东西,我们称之为GDT,它放在内存的任意位置,由GTDR这个寄存器保存入口地址,如图二。
图二 多个GDT
; ==========================================
; pmtest1.asm
; 编译方法:nasm pmtest1.asm -o pmtest1.bin
; ==========================================
%include "pm.inc" ; 常量, 宏, 以及一些说明
org 07c00h
jmp LABEL_BEGIN
[SECTION .gdt]
;步骤1
;GDT,下面就是GDT,是在pm.inc中定义的宏,定义了三项,可以表述三个地址,每一项都是一个结构,分为段基址,段界限和属性(属性又可细分),参看图一
; 段基址, 段界限, 属性
LABEL_GDT: Descriptor 0, 0, 0
LABEL_DESC_CODE32: Descriptor 0, SegCode32Len - 1, DA_C + DA_32
LABEL_DESC_VIDEO: Descriptor 0B8000h, 0ffffh, DA_DRW
GdtLen equ $ - LABEL_GDT ; GDT长度,$代表当前地址
;共6 byte, 结构与寄存器 gdtr 一致. 用于保存 GDT 表信息, 通过 lgdt 加载.
;后2-5byte内容, 在下面的代码中会计算出并填入,也就是GDT基地址.
GdtPtr dw GdtLen - 1 ; GDT界限
dd 0 ; GDT基地址
; GDT 选择子
SelectorCode32 equ LABEL_DESC_CODE32 - LABEL_GDT
SelectorVideo equ LABEL_DESC_VIDEO - LABEL_GDT
[SECTION .s16]
[BITS 16]
LABEL_BEGIN:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, 0100h
;此处计算出了 LABEL_SEG_CODE32 的真实物理地址,保存于 eax 中.
xor eax, eax
mov ax, cs
shl eax, 4 ;eax 中存储 cs 段地址, 并左移四位
add eax, LABEL_SEG_CODE32 ;段+偏移地址, 计算出其真实物理首地址
;步骤2
;此处将前面计算出的真实物理地址, 按规则放入GDT相应的段基址位置. +n就是偏移n个byte,也就是图一中的base0-15, 16-23, 24-31
mov word [LABEL_DESC_CODE32 + 2], ax
shr eax, 16
mov byte [LABEL_DESC_CODE32 + 4], al
mov byte [LABEL_DESC_CODE32 + 7], ah
xor eax, eax
mov ax, ds
shl eax, 4 ;eax 中存储 ds 段地址, 并左移四位
add eax, LABEL_GDT ;段+偏移地址, 计算出真实物理首地址(即GDT开始处地址)
mov dword [GdtPtr + 2], eax ; 将此物理首地址放入 GdtPtr(共6 byte) 的2-5 byte 处.
;步骤3
; 加载到寄存器 gdtr.
lgdt [GdtPtr]
; 关中断
cli
; 打开地址线A20
in al, 92h
or al, 00000010b
out 92h, al
;步骤4
; 将寄存器 cr0 的第 0 位置设置为1, 表示 CPU 要运行于保护模式
mov eax, cr0
or eax, 1
mov cr0, eax
;步骤5
; 进入保护模式
jmp dword SelectorCode32:0 ; 执行这一句会把 SelectorCode32 装入 cs,
; 并跳转到 Code32Selector:0 处
; END of [SECTION .s16]
[SECTION .s32]; 32 位代码段. 由实模式跳入.
[BITS 32]
LABEL_SEG_CODE32:
mov ax, SelectorVideo
mov gs, ax ; 视频段选择子(目的)
mov edi, (80 * 11 + 79) * 2 ; 屏幕第 11 行, 第 79 列。
mov ah, 0Ch ; 0000: 黑底 1100: 红字
mov al, 'P'
mov [gs:edi], ax
; 到此停止
jmp $
SegCode32Len equ $ - LABEL_SEG_CODE32
; END of [SECTION .s32]
从上面代码我们可以总结一下GDT段式寻址步骤:
1、自定义GDT结构;
2、分配GDT中各项的地址,如把LABEL_SEG_CODE32的物理地址放入GDT其中一项LABEL_DESC_CODE32的base中;
3、将GDT入口地址和长度放入GDTR寄存器中,如 lgdt [GdtPtr];
4、设置cr0寄存器进入保护模式;
5、在保护模式下用GDT实现跳转,如 jmp dword SelectorCode32:0 。此时SelectorCode32就是LABEL_DESC_CODE32相对于GDT入口地址的偏移,前面已经加载了GDT的入口地址,加上这个偏移就能方便的找到LABEL_DESC_CODE32,jmp到GDT中的这一项后,通过LABEL_DESC_CODE32中的base,可以找到LABEL_SEG_CODE32,因为base中放着LABEL_SEG_CODE32的物理地址,实际上也就是jmp到了LABEL_SEG_CODE32去。
至此,完成保护模式下段式寻址。