批处理-字符串操作(截取、替换、合并)

批处理有着具有非常强大的字符串处理能力,其功能绝不低于C语言里面的字符串函数集。批处理中可实现的字符串处理功能有:截取字符串内容、替换字符串特定字段、合并字符串、扩充字符串等功能。下面对这些功能一一进行讲解。

1、截取字符串
截取字符串可以说是字符串处理功能中最常用的一个子功能了,能够实现截取字符串中的特定位置的一个或多个字符。举例说明其基本功能:

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set abc=hello world, this string come from bat
echo 原字符串为:%abc%
echo 截取前5个字符:%abc:~0,5%
echo 截取最后5个字符:%abc:~-5%
echo 截取第一个到倒数第6个字符:%abc:~1,-5%
echo 从第4个字符开始截取5个字符:%abc:~3,5%
echo 从倒数第14个字符开始截取5个字符:%abc:~-14,5%

echo 当前时间是:%time% 即 %time:~0,2%点%time:~3,2%分%time:~6,2%秒%time:~9,2%厘秒
pause

输出为:

原字符串为:hello world, this string come from bat
截取前5个字符:hello
截取最后5个字符:m bat
截取第一个到倒数第6个字符:ello world, this string come fro
从第4个字符开始截取5个字符:lo wo
从倒数第14个字符开始截取5个字符: come
当前时间是:18:37:58.75 即 18点37分58秒75厘秒

2、替换字符串
替换字符串,即将某一字符串中的特定字符或字符串替换为给定的字符串。举例:

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set aa=伟大的中国!我为你自豪
echo 替换前:%aa%
echo 替换后:%aa:中国=中华人民共和国%
echo aa=%aa%
echo %aa%
set aa=%aa:中国=中华人民共和国%
echo aa=%aa%

pause

输出为:

替换前:伟大的中国!我为你自豪
替换后:伟大的中华人民共和国!我为你自豪
aa=伟大的中国!我为你自豪

 伟大的中国!我为你自豪
aa=伟大的中华人民共和国!我为你自豪

  对于上面的例子有一点说明,对比两个echo aa = %aa%可以发现,其等价与:aa=%aa% echo aa=%aa%

3、字符串合并
其实,合并字符串就是将两个字符串放在一起就可以了。举例说明:

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set aa=伟大的中国!
set bb=我为你自豪
echo %aa%%bb%

echo aa=%aa%
echo bb=%bb%
set “aa=%aa%%bb%”
echo aa=%aa%
pause

输出为:

伟大的中国!我为你自豪
aa=伟大的中国!
bb=我为你自豪
aa=伟大的中国!我为你自豪
复制代码
同样,如果要改变变量aa的内容的话,就需要将合并结果“%aa%%bb%”赋值给变量aa。

4、扩充字符串
“扩充”这个词汇来自于微软自己的翻译,意思就是对表示文件路径的字符串进行特殊的处理,具体功能罗列如下:
  ~I - 删除任何引号(“),扩充 %I
  %~fI - 将 %I 扩充到一个完全合格的路径名
  %~dI - 仅将 %I 扩充到一个驱动器号
  %~pI - 仅将 %I 扩充到一个路径
  %~nI - 仅将 %I 扩充到一个文件名
  %~xI - 仅将 %I 扩充到一个文件扩展名
  %~sI - 扩充的路径只含有短名
  %~aI - 将 %I 扩充到文件的文件属性
  %~tI - 将 %I 扩充到文件的日期/时间
  %~zI - 将 %I 扩充到文件的大小
  %~ PATH:I:         PATH:i - 查找列在路径环境变量的目录,并将 %I 扩充到找到的第一个驱动器号和路径。
  %~ftzaI - 将 %I 扩充到类似输出线路的 DIR
  

  以上内容引用于for /?帮助信息。其中的I代表变量I,不过需要说明的是,不是所有的变量都能够进行扩充的,有两个条件:1、该字符串代表一个文件路径;2、变量要用%x来表示,x可取a-z A-Z 0-9共62个字符中的任意一个。举例说明:

复制代码
@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

echo 正在运行的这个批处理:
echo 完全路径:%0
echo 去掉引号:%~0
echo 所在分区:%~d0
echo 所处路径:%~p0
echo 文件名:%~n0
echo 扩展名:%~x0
echo 文件属性:%~a0
echo 修改时间:%~t0
echo 文件大小:%~z0
echo %~nxtza0

pause

输出为:
正在运行的这个批处理:
完全路径:C:\Users\dsw\Desktop\test.BAT
去掉引号:C:\Users\dsw\Desktop\test.BAT
所在分区:C:
所处路径:\Users\dsw\Desktop\
文件名:test
扩展名:.BAT
文件属性:–a——
修改时间:2016/04/25 18:52
文件大小:295

–a—— 2016/04/25 19:11 99 test.BAT

复制代码
其中的%0是批处理里面的参数,代表当前运行的批处理的完全路径。类似的还有%1-%9,分别代表传递来的第1-9个参数。例子如下:

复制代码
@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set aa=C:\windows\ppp\a.dsw
call:deal aaa %aaa% “c C” ddd eee
echo call func exit
pause>nul
exit

:deal
echo %%0=%0
echo %%1=%1
echo %%2=%2
echo %%3=%3
echo %%4=%4
echo %%5=%5

pause

输出为:
%0=:deal
%1=aaa
%2=C:\windows\ppp\a.dsw
%3=”c C”
%4=ddd
%5=eee

复制代码
  其中,变量aa在之前是不可以扩充的,通过call命令并将aa作为参数传递给子函数:deal,将aa变量转换成了变量%1,即符合%x格式,从而可以进行字符串扩充。
至于%x中x取a-z A-Z的形式,可以复习一下for语句,for语句里面的变量就是用%x来表示的,因而可以直接进行扩充。

字符串操作结合set使用

复制代码
@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set a=abcd efgh ijkl
echo 替换前的值为:”%a%”
set var=%a: =%
echo 替换后的值为:”%var%”

set b=bbs.verybat.cn
set var=%b:~1,2%
echo 截取的字符串为:%var%
set var=%a:~3%
echo 截取的字符串为:%var%
set var=%a:~0,-3%
echo 截取的字符串为:%var%

pause

输出为:

替换前的值为:”abcd efgh ijkl”
替换后的值为:”abcdefghijkl”
截取的字符串为:bs
截取的字符串为:d efgh ijkl
截取的字符串为:abcd efgh i
复制代码

-表示字符串右边的意思, -3表示从字符串右边为0,向左移动3个位置

转载至:
https://www.cnblogs.com/DswCnblog/p/5432326.html

©️2020 CSDN 皮肤主题: 大白 设计师:CSDN官方博客 返回首页