批处理根据MAC地址自动改IP，计算机名，计算机描述 ...

这个批处理是我本人以前在批处理之家发贴的时候综合各路大虾的回复，是我在实践中通过去测试，不断的修完善的，一切以实际运行的效果说话，原帖地址：
http://www.bathome.net/viewthread.php?tid=13161&highlight=
感谢批处理之家的hanyeguxing 、 lxzzr 、ArdentMan ，提供的代码和指导性意见，对于里面每段代码的意思，本人因为批处理功底差，有些代码至今还没有明白意思，不过根据实际情况更改能用就行了。这个批处理还需要做完善，欢迎大家来拍砖，QQ:1102946175 
     机房70台电脑刚装完，网络克隆装完系统后，IP地址是DHCP服务器自动分配的，要全部改成192.168.103.0网段的静态IP，计算机名为计算机编号，第一排为计算机名为
A1 A2 A3……A8 A9 A10
IP地址分别为192.168.103.101  102  103…… 108 109 110

第一步，统计MAC地址
   所有电脑开机，统计现在获取的IP地址，抄的时候记两样东西，计算机编号，IP地址最后一位，统计完以后，用一个局域网扫描软件扫描一次网段内所有机器，然后运行cmd,用ARP-A命令就可以获取到所有电脑的现在的IP以及电脑的MAC地址
 

192.168.1.24	00-e0-66-02-db-a2
192.168.1.25	54-04-a6-66-bd-bd
192.168.1.26	00-30-67-ba-0c-ac
192.168.1.27	00-e0-62-0b-1f-6c
192.168.1.28	bc-ae-c5-5d-65-c0
192.168.1.31	00-e0-66-02-29-5e
192.168.1.59	50-e5-49-be-c0-dc
192.168.1.60	00-e0-66-0d-71-d9
192.168.1.63	00-e0-66-02-dd-d8

第二步，规划
        制作一个excel表，分五列，先把用ARP-A命令获取到的IP地址和MAC地址粘贴进去，在cmd命令窗口中复制的时候要记住，先复制IP，粘贴到一列，再复制MAC地址，粘贴到另一列，不要IP、MAC一起复制，这样一粘贴IP和MAC会在一个单元格里，再输入这台电脑规划的计算机名
 

原IP地址	计算机名	新规划地址	MAC地址	计算机描述
192.168.1.24	A06		00-e0-66-02-db-a2
192.168.1.25	A03		54-04-a6-66-bd-bd
192.168.1.26	A05		00-30-67-ba-0c-ac
192.168.1.27	A01		00-e0-62-0b-1f-6c
192.168.1.28	A04		bc-ae-c5-5d-65-c0
192.168.1.31	A09		00-e0-66-02-29-5e
192.168.1.59	A02		50-e5-49-be-c0-dc
192.168.1.60	A07		00-e0-66-0d-71-d9
192.168.1.63	A08		00-e0-66-02-dd-d8

最后排序计算机名，新地址好办，先输入两个再拖到底，excel这个功能还是强大的

原IP地址	计算机名	新规划地址	MAC地址	计算机描述
192.168.1.24	A01	192.168.103.101	00-e0-66-02-db-a2	北三楼A1
192.168.1.25	A02	192.168.103.102	54-04-a6-66-bd-bd	北三楼A2
192.168.1.26	A03	192.168.103.103	00-30-67-ba-0c-ac	北三楼A3
192.168.1.27	A04	192.168.103.104	00-e0-62-0b-1f-6c	北三楼A4
192.168.1.28	A05	192.168.103.105	bc-ae-c5-5d-65-c0	北三楼A5
192.168.1.31	A06	192.168.103.106	00-e0-66-02-29-5e	北三楼A6
192.168.1.59	A07	192.168.103.107	50-e5-49-be-c0-dc	北三楼A7
192.168.1.60	A08	192.168.103.108	00-e0-66-0d-71-d9	北三楼A8
192.168.1.63	A09	192.168.103.109	00-e0-66-02-dd-d8	北三楼A9

第三步，制作批处理
      把这个表弄好后，直接把这个做个批处理，代码如下，感谢批处理之家技术支持，把它按照自已的实际情况修改下子网掩码，网关，DNS，WINS，还有就是exit后面的内容，这个是直接从excel表中直接粘贴过去的。

@echo off
echo 正在配置IP地址、DNS请稍候……
set MASK=255.255.255.0
set GATEWAY=192.168.103.254
set DNS1=202.96.128.143
set DNS2=202.96.128.68 
set WINS=192.168.103.254
for /f "tokens=12 delims= " %%i in ('ipconfig /all^|find /i "Physical Address"') do set mac=%%i
for /f "tokens=1,2*" %%i in ('ipconfig /all^|find "Ethernet adapter"')  do set Ethernet=%%k
for /f "tokens=1,2" %%i in ('more /e +21 %0 ^|find /i "%mac:~,-1%"') do set "name=%%i"&set "IP=%%j"
for /f "tokens=4" %%j in ('more /e +21 %0 ^|find /i "%mac:~,-1%"') do set "p=%%j"
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\lanmanserver\parameters" /v srvcomment /t reg_sz /d %p% /f >nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\lanmanserver\parameters" /v srvcomment /t reg_sz /d %p% /f >nul 2>nul
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\ComputerName\ComputerName" /v ComputerName /t reg_sz /d %name% /f >nul 2>nul
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /t reg_sz /d %name% /f >nul 2>nul
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v Hostname /t reg_sz /d %name% /f >nul 2>nul
netsh interface ip set address "%Ethernet:~,-2%" static %IP% %Mask% %GATEWAY% 1 >nul 2>nul
netsh interface ip set dns "%Ethernet:~,-2%" static %DNS1% register=PRIMARY >nul 2>nul
netsh interface ip add dns "%Ethernet:~,-2%"  %DNS2% index=2 >nul 2>nul
netsh interface ip set wins "%Ethernet:~,-2%" static %WINS%  >nul 2>nul
exit
A01 192.168.103.101 10-60-4b-77-fe-a0 北三楼A01
A02 192.168.103.102 10-60-4b-8b-50-be 北三楼A02
A03 192.168.103.103 10-60-4b-88-61-7f 北三楼A03
A04 192.168.103.104 10-60-4b-88-70-a6 北三楼A04
A05 192.168.103.105 10-60-4B-89-46-CE 北三楼A05
A06 192.168.103.106 10-60-4b-8b-51-3f 北三楼A06
A07 192.168.103.107 10-60-4b-8b-53-cd 北三楼A07
A08 192.168.103.108 10-60-4b-8b-51-38 北三楼A08
A09 192.168.103.109 10-60-4b-77-e5-c4 北三楼A09
A10 192.168.103.110 10-60-4b-77-ea-c2 北三楼A10
B01 192.168.103.111 10-60-4b-77-e7-e6 北三楼B01
B02 192.168.103.112 10-60-4b-77-fe-80 北三楼B02
B03 192.168.103.113 10-60-4b-88-5e-cc 北三楼B03
B04 192.168.103.114 10-60-4b-77-ea-a9 北三楼B04
B05 192.168.103.115 10-60-4b-77-fe-9e 北三楼B05
B06 192.168.103.116 10-60-4b-77-e7-eb 北三楼B06
B07 192.168.103.117 10-60-4b-88-70-a1 北三楼B07
B08 192.168.103.118 10-60-4b-8b-50-99 北三楼B08
B09 192.168.103.119 10-60-4b-86-2f-d2 北三楼B09
B10 192.168.103.120 10-60-4b-77-fe-f4 北三楼B10

 

      后话：做过统计后，以后重装系统什么的，只要有这个批处理，一运行，IP地址，计算机名，计算机描述全部都改成你规划中的，我机房70台电脑，统计以后，后面重装系统，把这个集成到封装的系统做个GHO镜像，再网络克隆，每台机安装完系统进入桌面后会自动运行这个批处理，IP地址，计算机名，计算机描述，全改了，哈哈，是不是很贴切啊，如果你不会封装，用的是网上下载的那种ghost系统，如果全公司都要装，你可以做个这个批处理，再用Ghost Explorer 把这个批处理扔到gho镜像文件开始菜单里面的启动 文件夹，这个系统装完进入桌面会自动运行这个批处理，你以后就可以省掉改IP，计算机名，计算机描述了，你公司的电脑计算机名是不是还乱七八糟啊，赶紧的做个这个批处理，发给每个人运行一下吧

   本案例的批处理原文件下载地址

http://down.51cto.com/data/780362

附：本文转自http://bbs.51cto.com/thread-1031829-1.html