Word插入页脚,删除页眉横线
;作者:sunwind1576157
;时间:2019年12月3日
;最新版网址:https://blog.csdn.net/liuyukuan/article/details/103369405
;功能:利用Word.Application COM对象,操纵word插入页脚,并删除页眉中的横线
;参数:第一个参数标识页码位置、第二个参数是首页是否插入页码。
F7::
InsertPageNumber("Center", true)
return
InsertPageNumber(strType, bHeader)
{
;word常数参考 https://www.autohotkey.com/boards/viewtopic.php?f=22&t=1672
;~ WdPageNumberAlignment 5 members.
wdAlignPageNumberLeft := 0
wdAlignPageNumberCenter := 1
wdAlignPageNumberRight := 2
wdAlignPageNumberInside := 3
wdAlignPageNumberOutside := 4
;~ WdHeaderFooterIndex 3 members.
wdHeaderFooterPrimary:= 1
wdHeaderFooterFirstPage := 2
wdHeaderFooterEvenPages := 3
;~ WdBorderType 8 members.
wdBorderTop := -1
wdBorderLeft := -2
wdBorderBottom = -3
wdBorderRight := -4
wdBorderHorizontal := -5
wdBorderVertical := -6
wdBorderDiagonalDown := -7
wdBorderDiagonalUp := -8
;~ WdLineStyle 25 members.
wdLineStyleNone := 0
wdLineStyleSingle := 1
wdLineStyleDot := 2
;...
oWordApplic:=ComObjActive("Word.Application")
oAlignment := wdAlignPageNumberCenter
oFirstPage := bHeader
WdFooterIndex:=wdHeaderFooterPrimary
switch strType
{
case "Center":
oAlignment := wdAlignPageNumberCenter
case "Right":
oAlignment := wdAlignPageNumberRight
case "Left":
oAlignment := wdAlignPageNumberLeft
}
;.Item(1)改成[1]
;.Item(WdFooterIndex)改成[WdFooterIndex]
oWordApplic.Selection.Sections[1].Footers[WdFooterIndex].PageNumbers.Add(oAlignment,oFirstPage)
oWordApplic.Selection.Sections[1].Footers[WdFooterIndex].Range.Font.Name := "Times New Roman"
oWordApplic.Selection.Sections[1].Footers[WdFooterIndex].Range.Font.Size := 14
;去掉页眉的横线 ,如oFirstPage=false时 首页的横线去不掉的。
oWordApplic.Selection.Sections[1].Headers[WdFooterIndex].Range.ParagraphFormat.Borders[wdBorderBottom].LineStyle := wdLineStyleNone
}