远程备份与还原mysql数据库

mysql的备份还原使用了mysql安装程序中bin目录中的mysqldump.exe 和 mysql.exe，所以我们需要提前设置好环境变量，简化操作

一、环境变量

二、启动cmd并跳转至脚本目录

1、win+R, 输入 cmd

2、跳转目录

c:
cd C:\Users\liujie\Desktop\mysql_winserver

三、备份mysql远程数据库

> cmd /c backup.bat 192.168.11.14 3306 “ss_auth ss_gateway” root abc@123

说明：

• cmd /c dir 是执行完dir命令后关闭命令窗口。
• cmd /k dir 是执行完dir命令后不关闭命令窗口。
• cmd /c start dir 会打开一个新窗口后执行dir指令，原窗口会关闭。
• cmd /k start dir 会打开一个新窗口后执行dir指令，原窗口不会关闭。
• 192.168.11.14 3306 “ss_auth ss_gateway” root abc@123 都是参数，空格分割，参数中含有空格用引号引起来

backup.bat文件：

@echo off & setlocal ENABLEEXTENSIONS 

:: ---------- 配置项 ----------  
:: 要备份数据库所在服务器IP
set HOST=%1

:: 要备份数据库所在服务器端口
set PORT=%2

:: 要备份的数据库名称，多个用逗号或者空格分隔(%~2会自动将引号删除,%2不会删除)
set DATABASES=%~3

:: MySQL 用户名 
set USERNAME=%4

:: MySQL 密码 
set PASSWORD=%5

:: 备份放置的路径，加 \ 
set BACKUP_PATH=D:\mysqldata\Backup\ 

:: MySQL Bin 目录，加 \ 
:: 如果可以直接使用 mysqldump（安装时添加 MySQL Bin 目录到了环境变量），此处留空即可 
set MYSQL=D:\Program Files\mysql-5.7.20-winx64\bin\


:: ---------- 以下请勿修改 ---------- 

set YEAR=%date:~0,4% 
set MONTH=%date:~5,2% 
set DAY=%date:~8,2% 
:: 如果在 dos 下输入 time 返回的不是 24 小时制（没有 0 填充），请自行修改此处 
set HOUR=%time:~0,2% 
set MINUTE=%time:~3,2% 
set SECOND=%time:~6,2% 

set DIR=%BACKUP_PATH%%YEAR%\%MONTH%\%DAY%\ 
set ADDON=%YEAR%%MONTH%%DAY%%HOUR%%MINUTE%%SECOND% 
set "DIR=%DIR: =%"
set "ADDON=%ADDON: =%"

:: create dir 
if not exist %DIR% ( 
mkdir %DIR% 2>nul 
) 
if not exist %DIR% ( 
echo Backup path: %DIR% not exists, create dir failed. 
goto exit 
) 


:: backup 
echo Start backup databases...  
for %%D in (%DATABASES%) do ( 

cd /d %DIR% 
mysqldump -h%HOST% -P%PORT% -u%USERNAME% -p%PASSWORD% %%D > %%D.%ADDON%.sql 2>nul 

   
) 
echo Done 

:exit 
 

四、还原数据库备份sql文件

cmd /c restore.bat 192.168.11.14 3306 ss_auth root JsonLiu@123 D:/mysqldata/Backup/2021/07/22/ss_auth.20210722202430.sql

restore.bat文件：

@echo off & setlocal ENABLEEXTENSIONS 

:: ---------- 配置项 ----------  

:: 要备份数据库所在服务器IP
set HOST=%1

:: 要备份数据库所在服务器端口
set PORT=%2

:: 要备份的数据库名称，多个用逗号或者空格分隔(%~2会自动将引号删除,%2不会删除)
set DATABASES=%~3

:: MySQL 用户名 
set USERNAME=%4

:: MySQL 密码 
set PASSWORD=%5

:: 备份放置的路径，加 \ 
set BACKUP_PATH=%~6

:: MySQL Bin 目录，加 \ 
:: 如果可以直接使用 mysqldump（安装时添加 MySQL Bin 目录到了环境变量），此处留空即可 
set MYSQL=D:\Program Files\mysql-5.7.20-winx64\bin\

:: backup 
echo Start restore databases...  
for %%D in (%DATABASES%) do (  
 
mysql -h%HOST% -P%PORT% -u%USERNAME% -p%PASSWORD% %%D< %BACKUP_PATH%
  
 
) 
echo Done 

:exit