【BZOJ1015】【JSOI2008】星球大战starwar

【Description】

　　很久以前，在一个遥远的星系，一个黑暗的帝国靠着它的超级武器统治者整个星系。某一天，凭着一个偶然的机遇，一支反抗军摧毁了帝国的超级武器，并攻下了星系中几乎所有的星球。这些星球通过特殊的以太隧道互相直接或间接地连接。 但好景不长，很快帝国又重新造出了他的超级武器。凭借这超级武器的力量，帝国开始有计划地摧毁反抗军占领的星球。由于星球的不断被摧毁，两个星球之间的通讯通道也开始不可靠起来。现在，反抗军首领交给你一个任务：给出原来两个星球之间的以太隧道连通情况以及帝国打击的星球顺序，以尽量快的速度求出每一次打击之后反抗军占据的星球的连通快的个数。（如果两个星球可以通过现存的以太通道直接或间接地连通，则这两个星球在同一个连通块中）。

---

【Input】

　　输入文件第一行包含两个整数，N (1 < = N < = 2M) 和M (1 < = M < = 200,000)，分别表示星球的数目和以太隧道的数目。星球用 0 ~ N-1的整数编号。接下来的M行，每行包括两个整数X, Y，其中（0 < = X <> Y 表示星球x和星球y之间有“以太”隧道，可以直接通讯。接下来的一行为一个整数k，表示将遭受攻击的星球的数目。接下来的k行，每行有一个整数，按照顺序列出了帝国军的攻击目标。这k个数互不相同，且都在0到n-1的范围内

---

【Output】

　　输出文件的第一行是开始时星球的连通块个数。接下来的N行，每行一个整数，表示经过该次打击后现存星球的连通块个数。

---

【Sample Input】

8 13
0 1
1 6
6 5
5 0
0 6
1 2
2 3
3 4
4 5
7 1
7 2
7 6
3 6
5
1
6
3
5
7

---

【Sample Output】

1
1
1
2
3
3

---

【Solution】

　　倒着维护即可。根据攻击顺序逆序用并查集维护连通块数量。
　　
　　代码如下：

/**************************************************************
    Problem: 1015
    User: llgyc
    Language: Pascal
    Result: Accepted
    Time:2564 ms
    Memory:16632 kb
****************************************************************/

const maxm = 400005; maxn = 800005;
type etype = record
               go,next:longint;
             end;
var n,m,k,cnt,top,now:longint;
    e:array[0..maxm] of etype;
    head,fa:array[0..maxn] of longint;
    stack,ans:array[0..maxn] of longint;
    exist:array[0..maxn] of boolean;
procedure insert(u,v:longint);
  begin inc(cnt); e[cnt].go:=v; e[cnt].next:=head[u]; head[u]:=cnt; end;
function getfather(x:longint):longint;
  begin if fa[x]=x then exit(x); fa[x]:=getfather(fa[x]); exit(fa[x]); end;
function union(x,y:longint):boolean;
  var a,b:longint;
  begin
    if getfather(x)=getfather(y) then exit(false);
    a:=getfather(x); b:=getfather(y); fa[a]:=b;
    exit(true);
  end;
procedure init();
  var i,j,x,y:longint;
  begin
    readln(n,m); cnt:=0;
    for i:=1 to m do begin
      readln(x,y); insert(x,y); insert(y,x);
    end;
    readln(k); top:=0;
    fillchar(exist,sizeof(exist),true);
    while (top<k) do begin
      inc(top); readln(stack[top]); exist[stack[top]]:=false;
    end;
    now:=n-k;
    for i:=0 to n-1 do fa[i]:=i;
    for i:=0 to n-1 do begin
      if not exist[i] then continue;
      j:=head[i];
      while (j<>0) do begin
        if exist[e[j].go] and union(i,e[j].go) then dec(now);
        j:=e[j].next;
      end;
    end;
    ans[top]:=now; dec(top);
  end;
procedure main;
  var i,tmp:longint;
  begin
    while top>=0 do begin
      tmp:=stack[top+1]; exist[stack[top+1]]:=true; inc(now);
      i:=head[tmp];
      while (i<>0) do begin
        if exist[e[i].go] and union(tmp,e[i].go) then begin
          dec(now);
        end;
        i:=e[i].next;
      end;
      ans[top]:=now; dec(top);
    end;
    for i:=0 to k do writeln(ans[i]);
  end;
begin
  init();
  main();
end.