Hive 数据定义 创建 删除 修改 查询 DDL

Hive的 DDL数据定义

创建数据库

1）创建一个数据库，数据库在HDFS上的默认存储路径是/user/hive/warehouse/*.db。
hive (default)> create database db_hive;
2）避免要创建的数据库已经存在错误，增加if not exists判断。（标准写法）
hive (default)> create database db_hive;
FAILED: Execution Error, return code 1 from org.apache.hadoop.hive.ql.exec.DDLTask. Database db_hive already exists
hive (default)> create database if not exists db_hive;
3）创建一个数据库，指定数据库在HDFS上存放的位置
hive (default)> create database db_hive2 location '/db_hive2.db';

查询数据库

显示数据库
hive> show databases;
过滤显示查询的数据库
hive> show databases like 'db_hive*';
OK
db_hive
db_hive_1
查看数据库详情
hive> desc database db_hive;
OK
db_hive		hdfs://hadoop102:9000/user/hive/warehouse/db_hive.db	bigdataUSER	
切换当前数据库
hive (default)> use db_hive;

删除数据库

1．删除空数据库
hive>drop database db_hive2;
2．如果删除的数据库不存在，最好采用 if exists判断数据库是否存在
hive> drop database db_hive;
FAILED: SemanticException [Error 10072]: Database does not exist: db_hive
hive> drop database if exists db_hive2;
3．如果数据库不为空，可以采用cascade命令，强制删除
hive> drop database db_hive;
FAILED: Execution Error, return code 1 from org.apache.hadoop.hive.ql.exec.DDLTask. InvalidOperationException(message:Database db_hive is not empty. One or more tables exist.)
hive> drop database db_hive cascade;

创建表

建表语法
CREATE [EXTERNAL] TABLE [IF NOT EXISTS] table_name
[(col_name data_type [COMMENT col_comment], …)]
[COMMENT table_comment]
[ROW FORMAT row_format]
[STORED AS file_format]
[LOCATION hdfs_path]
LIKE tablename
字段解释说明
（1）CREATE TABLE 创建一个指定名字的表。如果相同名字的表已经存在，则抛出异常；用户可以用 IF NOT EXISTS 选项来忽略这个异常。
（2）EXTERNAL关键字可以让用户创建一个外部表，在建表的同时指定一个指向实际数据的路径（LOCATION），Hive创建内部表时，会将数据移动到数据仓库指向的路径；若创建外部表，仅记录数据所在的路径，不对数据的位置做任何改变。在删除表的时候，内部表的元数据和数据会被一起删除，而外部表只删除元数据，不删除数据。
（3）COMMENT：为表和列添加注释。
（4）ROW FORMAT DELIMITED FIELDS TERMINATED BY char：指定分隔符
（5）STORED AS指定存储文件类型
常用的存储文件类型：SEQUENCEFILE（二进制序列文件）、TEXTFILE（文本）、RCFILE（列式存储格式文件）
如果文件数据是纯文本，可以使用STORED AS TEXTFILE。如果数据需要压缩，使用 STORED AS SEQUENCEFILE。
（6）LOCATION ：指定表在HDFS上的存储位置。
（7）LIKE允许用户复制现有的表结构，但是不复制数据。
如果当前创建的表create table table1，希望table1和已经存在的table0的表结构相同，就可以使用like指令直接创建，create table table1 like table0;
管理表（内部表）
当我们删除一个管理表时，Hive也会删除这个表中数据(元数据和表数据都会删除掉)
实操

（1）普通创建表
create table if not exists student3(
id int, name string
)
row format delimited fields terminated by '\t'
stored as textfile
location '/user/hive/warehouse/student3';
（2）根据查询结果创建表（查询的结果会添加到新创建的表中）
create table if not exists student3 as select id, name from student;
（3）根据已经存在的表结构创建表
create table if not exists student4 like student;
（4）查询表的类型
hive (default)> desc formatted student2;
Table Type:             MANAGED_TABLE  

外部表
删除该表并不会删除掉这份数据，不过描述表的元数据信息会被删除掉。
实操

建表语句
创建部门表
create external table if not exists dept(
deptno int,
dname string,
loc int
)
row format delimited fields terminated by '\t';
创建员工表
create external table if not exists emp(
empno int,
ename string,
job string,
mgr int,
hiredate string, 
sal double, 
comm double,
deptno int)
row format delimited fields terminated by '\t';
查看创建的表
hive (default)> show tables;
OK
tab_name
dept
emp
向外部表中导入数据
导入数据
hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept;
hive (default)> load data local inpath '/opt/module/datas/emp.txt' into table default.emp;
查询结果
hive (default)> select * from emp;
hive (default)> select * from dept;
查看表格式化数据
hive (default)> desc formatted dept;
Table Type:             EXTERNAL_TABLE

修改表

重命名表
语法
ALTER TABLE table_name RENAME TO new_table_name
实操

hive (default)> alter table dept_partition2 rename to dept_partition3;

增加/修改列信息
语法
更新列
ALTER TABLE table_name CHANGE [COLUMN] col_old_name col_new_name column_type [COMMENT col_comment]
增加列
ALTER TABLE table_name ADD COLUMNS (col_name data_type [COMMENT col_comment], …)
实操

（1）查询表结构
hive> desc dept_partition;
（2）添加列
hive (default)> alter table dept_partition add columns(deptdesc string);
（3）查询表结构
hive> desc dept_partition;
（4）更新列
hive (default)> alter table dept_partition change column deptdesc desc int;
（5）查询表结构
hive> desc dept_partition;

删除表

hive (default)> drop table dept_partition;