CREATE PROCEDURE sp_page
@tb varchar(50), --表名
@col varchar(50), --按该列来进行分页
@coltype int, --@col列的类型,0-数字类型,1-字符类型,2-日期时间类型
@orderby bit, --排序,0-顺序,1-倒序
@collist varchar(800),--要查询出的字段列表,*表示全部字段
@pagesize int, --每页记录数
@page int, --指定页
@condition varchar(800),--查询条件
@pages int OUTPUT --总页数
AS
/*
功能描述:对指定表中满足条件的记录按指定列进行分页查询,分页可以顺序、倒序
查询可以指定页大小、指定查询任意页、指定输出字段列表,返回总页数
作 者:Chandler Zheng
版 本:0.01
最后修改:2005-9-17
*/
DECLARE @sql nvarchar(4000),@where1 varchar(800),@where2 varchar(800)
IF @condition is null or rtrim(@condition)=''
BEGIN--没有查询条件
SET @where1=' WHERE '
SET @where2=' '
END
ELSE
BEGIN--有查询条件
SET @where1=' WHERE ('+@condition+') AND '--本来有条件再加上此条件
SET @where2=' WHERE ('+@condition+') '--原本没有条件而加上此条件
END
SET @sql='SELECT @pages=CEILING((COUNT(*)+0.0)/'+CAST(@pagesize AS varchar)+
') FROM '+@tb+@where2
EXEC sp_executesql @sql,N'@pages int OUTPUT',@pages OUTPUT--计算总页数
IF @orderby=0
SET @sql='SELECT TOP '+CAST(@pagesize AS varchar)+' '+@collist+
' FROM '+@tb+@where1+@col+'>(SELECT MAX('+@col+') '+
' FROM (SELECT TOP '+CAST(@pagesize*(@page-1) AS varchar)+' '+
@col+' FROM '+@tb+@where2+'ORDER BY '+@col+') t) ORDER BY '+@col
ELSE
SET @sql='SELECT TOP '+CAST(@pagesize AS varchar)+' '+@collist+
' FROM '+@tb+@where1+@col+'<(SELECT MIN('+@col+') '+
' FROM (SELECT TOP '+CAST(@pagesize*(@page-1) AS varchar)+' '+
@col+' FROM '+@tb+@where2+'ORDER BY '+@col+' DESC) t) ORDER BY '+
@col+' DESC'
IF @page=1--第一页
SET @sql='SELECT TOP '+CAST(@pagesize AS varchar)+' '+@collist+' FROM '+@tb+
@where2+'ORDER BY '+@col+CASE @orderby WHEN 0 THEN '' ELSE ' DESC' END
EXEC(@sql)
GO
--测试过程:TGongwen表共有86万条数据
declare @d datetime
set @d=getdate()
declare @pages int
exec sp_page 'TGongwen','Gid',2,0,'*',100,1,'fariqi>dateadd(day,-90,getdate()) and fariqi<dateadd(day,-30,getdate())',@pages output
select 总页数=@pages
select [语句执行花费时间(毫秒)]=datediff(ms,@d,getdate())
--测试结果为:显示第一页为46毫秒~60毫秒,显示最后一页1186毫秒
--每页100条数据,共3000页300000条数据
--需要注意的是用来分页的列(Gid)必须有唯一值.否则不能显示值一样的数据
--测试过程
declare @d datetime
set @d=getdate()
declare @pages int
select identity(int,1,1) id0,title,fariqi into #t from TGongwen
exec sp_page '#t','id0',2,0,'*',100,1,'fariqi>dateadd(day,-90,getdate()) and fariqi<dateadd(day,-30,getdate())',@pages output
select 总页数=@pages
select [语句执行花费时间(毫秒)]=datediff(ms,@d,getdate())
drop table #t