pl/sql编程中的控制结构

pl/sql编程中的控制结构

 (一) 条件分支语句

pl/sql中提供了三种条件分支语句if - then，if – then – else，if – then – elsif – then

1) 简单的条件判断 if– then - end if;

-- 输入一个人名，如果工资低于2000，就给员工工资增加10%。
create or replace procedure add_sal(name varchar2) is
  v_sal emp.sal%type;
begin
  select sal into v_sal from emp where ename = name;
  if v_sal < 2000 then
    update emp set sal = sal + sal*0.1 where ename = name;
  end if;
end;

  

2) 二重条件分支 if– then– else - end if;

-- 输入员工姓名，有补助则加100，没有则设为200；
create or replace procedure add_comm(name varchar2) is
  v_comm emp.comm%type;
begin
  select nvl(comm, 0) into v_comm from emp where ename = name;
  if v_comm <> 0 then
    update emp set comm = comm + 100 where ename = name;
  else
    update emp set comm = 200 where ename = name;
  end if;
end;

  

3) 多重条件分支 if– then– elsif– then - else - end if;

注意：elsif, 不是elseif,也不是else if

-- 输入员工编号，如果是PRESIDENT工资加1000，MANAGER加500，其他加200
create or replace procedure addSalByEmpno(eno number) is
  v_job emp.job%type;
  v_val emp.sal%type;
begin
  select job into v_job from emp where empno = eno;
  if (v_job = 'PRESIDENT') then  -- 条件语句可以不使用()
    v_val := 1000;               -- pl/sal中的赋值 :=
  elsif v_job = 'MANAGER' then   -- 切记: 是 elsif 而不是 elseif 也不是 else if
    v_val := 500;
  else
    v_val := 200;
  end if;
  update emp set sal = sal + v_val where empno = eno;
end;

  

(二) 循环语句

1) 循环语句–loop

这种循环语句以loop开头，以end loop结尾，这种循环至少会被执行一次。

-- 现有users表如下：
create table users(id number(4), name varchar2(20));
-- 输入用户名，并循环添加10个用户到users表中, 用户编号从1开始增加。
create or replace procedure add_users(name varchar2) is
  v_num number(4) := 1;
begin
  loop
    insert into users values(v_num, name);
    exit when v_num = 10;
    v_num := v_num + 1;
  end loop;
end;

  

2) 循环语句–while循环

基本循环至少要执行循环体一次，而对于while循环来说，只有条件为true时，才会执行循环体语句，while循环以while...loop

 

开始，以end loop结束。

-- 用while 循环重写add_users方法。
create or replace procedure add_users2(name varchar2) is
  v_num number(4) := 11;
begin
  while v_num <= 20 loop
    insert into users values(v_num, name);
    v_num := v_num + 1;
  end loop;
end;

  

3) 循环语句–for循环

-- 用for 循环重写add_users方法
create or replace procedure add_users3(name varchar2) is
  v_i number(4);
begin
  for v_i in reverse 1..10 loop  -- reverse可选的，倒序(10.9.8..) 如果不写为(1.2.3..)
    insert into users values(v_i, name);
  end loop;
end;

  

(三) 顺序控制语句–goto，null

1) goto语句

goto语句用于跳转到特定符号去执行语句。goto语句会增加程序的复杂性，并使得应用程序可读性变差，所有不建议使用。用法goto lable; <<label>>

-- goto语句
set serveroutput on;
declare
  i int := 1;
begin
  loop
    dbms_output.put_line('输出 i = ' || i);
    if i = 5 then
      goto end_loop;
    end if;
    i := i + 1;
  end loop;
  <<end_loop>>
  dbms_output.put_line('循环结束');
end;

  

2) null语句

null语句不会执行任何操作，并且会直接将控制传递到下一条语句。使用null语句的主要好处是可以提高pl/sql的可读性。

-- null语句
declare
  v_sal emp.sal%type;
  v_ename emp.ename%type;
begin
  select ename, sal into v_ename, v_sal from emp where empno = &no;
  if v_sal < 3000 then
    update emp set sal = sal + sal * 0.1 where ename = v_ename;
  else
    null; -- 什么也不做，为了提高可读性。
  end if;
end;