批处理删除指定时间前脚本

/s  连目录一起拷贝。不加此参数则至拷贝d盘目录下的文件，忽略文件夹

/h  也复制隐藏文件和系统文件

/d  如果文件出现更新，则用新的文件覆盖旧的文件

/y  覆盖文件时，直接覆盖，不做“。。文件已存在，是否将现有文件。。替换为。。”提示

/c  如果出现错误，则忽略错误继续复制。
/f 强制删除只读文件 
/q 指定静音状态。不提示您确认删除。 
/s 从当前目录及其所有子目录中删除指定文件。显示正在被删除的文件名。 
/a的意思是按照属性来删除了

%date:~x,y% 
冒号后的~x,y表示截取date返回值中第x位后的y个字符。在上面的第一个粒子的日期格式下，如果我们输入echo %date:~5,5%，则会得到以下结果（截取到第5位后的5个字符，也就是只取月和日）： 
C:\Documents and Settings\Simon>echo %date:~5,5% 
09-09

====================================================

1. forfiles /p D:\uploadfiles\leaveword /s /m *.* /d -300 /c "cmd /c del /f /q /a @path" 

pause

2.=======================

rem 指定待删除文件的存放路径
set SrcDir=E:\fileAutoBak\file\uploadfiles\leaveword
rem 指定天数
set DaysAgo=100
for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%
for /r "%SrcDir%" %%a in (*.*) do (
  if "%%~ta" leq "%DstDate%" (
    if exist "%%a" (
       del /f /q "%%a"
    )
  )
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof


:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF


:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %

3================================

【方案一】删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件：BAT + REG + VBS

@echo off
::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例调用了临时VBS代码进行日期计算
::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
::处理完毕之后再把日期格式恢复成原来的状态。

rem 指定待删除文件的存放路径
set SrcDir=C:\Test\BatHome
rem 指定天数
set DaysAgo=1
for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
>"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
for /r "%SrcDir%" %%a in (*.*) do (
  if "%%~ta" leq "%DstDate%" (
    if exist "%%a" (
      echo del /f /q "%%a"
    )
  )
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause



【方案二】删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件：BAT + REG + Ritchie Lawrence 日期函数

@echo off
::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例调用了 Ritchie Lawrence 的日期函数进行日期计算
::日期转换的核心算法请参考http://bbs.bathome.net/thread-3056-1-1.html
::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
::处理完毕之后再把日期格式恢复成原来的状态。

rem 指定待删除文件的存放路径
set SrcDir=C:\Test\BatHome
rem 指定天数
set DaysAgo=1
for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%
for /r "%SrcDir%" %%a in (*.*) do (
  if "%%~ta" leq "%DstDate%" (
    if exist "%%a" (
      echo del /f /q "%%a"
    )
  )
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF



【方案三】删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件：BAT + VBS

@echo off
::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例调用了临时VBS代码进行日期计算，并统一设置系统日期格式，处理完毕
::之后再把日期格式恢复成原来的状态。摆脱了对reg命令（XP系统自带）的依赖。

rem 指定待删除文件的存放路径
set SrcDir=C:\Test\BatHome
rem 指定天数
set DaysAgo=1
>"%temp%\BackupDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\BackupDate.vbs" echo WScript.Echo WshShell.RegRead ("HKEY_CURRENT_USER\Control Panel\International\sShortDate")
for /f %%a in ('cscript /nologo "%temp%\BackupDate.vbs"') do (
  set "RegDateOld=%%a"
)
>"%temp%\UnifyDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\UnifyDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "yyyy-M-d", "REG_SZ"
cscript /nologo "%temp%\UnifyDate.vbs"
>"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
for /r "%SrcDir%" %%a in (*.*) do (
  if "%%~ta" leq "%DstDate%" (
    if exist "%%a" (
      echo del /f /q "%%a"
    )
  )
)
>"%temp%\RecoverDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\RecoverDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "%RegDateOld%", "REG_SZ"
cscript /nologo "%temp%\RecoverDate.vbs"
pause



【方案四】删除指定路径下指定天数之前（以文件的创建日期为准）的文件：BAT + REG + Ritchie Lawrence 日期函数

@echo off
::演示：删除指定路径下指定天数之前（以文件的创建日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例调用了 Ritchie Lawrence 的日期函数进行日期计算
::日期转换的核心算法请参考http://bbs.bathome.net/thread-3056-1-1.html
::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
::处理完毕之后再把日期格式恢复成原来的状态。

rem 指定待删除文件的存放路径
set SrcDir=C:\Test\BatHome
rem 指定天数
set DaysAgo=1
for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%

for /f "delims=/" %%a in ('dir /s /b /a-d "%SrcDir%"') do (
  call :CompareTime "%%a"
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

:CompareTime
for /f "skip=5 tokens=1-2 delims= " %%h in ('dir /a-d /tc %1') do (
  if "%%h" leq "%DstDate%" (
    if exist %1 (
      echo del /a /f /q %1
    )
  )
  goto :eof
)



【方案五】删除指定路径下指定天数之前（以文件的修改日期为准）的文件：forfiles


@echo off
::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例需要Win2003/Vista/Win7系统自带的forfiles命令的支持

rem 指定待删除文件的存放路径
set SrcDir=C:\Test\BatHome
rem 指定天数
set DaysAgo=1

forfiles /p %SrcDir% /s /m *.* /d -%DaysAgo% /c "cmd /c echo del /f /q /a @path"
pause

****************************************

@echo off&color 1f
:: 删除 N 天前“创建”或“修改”的文件
:: by 小楼一夜听春雨 @bbs.bathome.net 2007-11-13
:: 2009-01-09 日更新 （可处理含特殊符号&!的文件（夹）名）
:: 日期必须是 yyyy-mm-dd 格式
:: 计算日期部分出自 @cn-dos by will sort
set "f=%date:~4,1%"
for %%a in (wjj c m z cw cuowu leixin tian zml yes) do set "%%a="
:start
setlocal
echo\&echo  请输入要处理的文件夹全路径，或拖放文件夹来此窗口。
echo.&set /p wjj= 
set "wjj=%wjj:"=%"
if "%wjj:~-1%"=="\" set "wjj=%wjj:~0,-1%"
set "wjj=%wjj%"&cls
if not exist "%wjj%" (
   echo\&echo  没有 "%wjj%" 这个文件夹，请重新输入。
   endlocal&goto start
)
endlocal&set "wjj=%wjj%"&cls
:loop1
setlocal
title "%wjj%"
echo\&echo  请选择要删除的文件类型，c 为创建的文件， w 为修改的文件
echo.&set /p cw= 请选择 [ c , w ] ? &cls
if /i not "%cw%"=="c" if /i not "%cw%"=="w" set cuowu=a
if defined cuowu (
   echo\&echo  输入错误，请重新输入。
   endlocal&goto loop1
)
endlocal&set "leixin=/t%cw%"
if /i "%leixin%"=="/tc" (set c=创建) else set c=修改&cls
:loop2
setlocal
title 删除 "%wjj%" %c% 的文件
echo\&echo  请输入天数，即：需要删除多少天前 “%c%” 的文件。
echo.&set /p tian= 请输入： &cls
echo %tian%|findstr "^[0-9]*$" >nul|| (
  echo\&echo  输入错误，必须是纯数字，请重新输入。
  endlocal&goto loop2
)
endlocal&set "tian=%tian%"&cls
title 删除 "%wjj%" %tian% 前 %c% 的文件
echo\&echo  请选择是否处理子目录, y 是， n 否。
echo\&set /p zml= [ y , n ] ? 
if /i "%zml%"=="y" (set zml=/s&set z=（含子目录）
  ) else set "zml="&set z=（不含子目录）
call :Date2Day "%date%" %tian% Day
cls&color fc
echo\&echo  即将删除 "%wjj%" 中%z% %Day% 以前 “%c%” 的文件
echo\&echo  回车继续，其它键退出。
echo\&set /p yes= 
if defined yes exit
cls
title 删除 "%wjj%" 中%z% %Day% 以前 “%c%” 的文件
::::::::::::::::::::     判断并删除文件   ::::::::::::::::::::::::::::::::::
for /f "tokens=*" %%i in (
'dir /a-d %leixin% %zml% "%wjj%"^|findstr /b "[0-9] ..:"'
) do (
   for /f "tokens=1* delims=\" %%a in ("%%i") do (
     if not "%%b"=="" (set ml=%%i) else (
       for /f "tokens=1-3* delims= " %%c in ("%%i") do (
         set "str=%%~nxf"
         setlocal enabledelayedexpansion
         if exist "!ml:~0,-4!\!str!" (
           if "%%c" lss "%Day%" (
              del /F /S /Q "!ml:~0,-4!\!str!"
              endlocal&set /a m+=1
            )
          ) else endlocal
))))
color 0a&echo\
if not defined m (echo 文件夹 "%wjj%" 中没有 %Day% 以前 %c% 的文件.
) else (echo   删除完成。。。&echo\&echo\  共删除 %m% 个文件)
echo\&pause&exit
:::::::::::::::::::::::::::     计算日期   ::::::::::::::::::::::::::::::::::
rem   使用方法：call :Date2Day 2007-11-12 2 Day
rem   变量 Day 就是2007-11-12 减2的结果。
:Date2Day 计算指定天数 前/后 的日期 （封装）
@echo off&setlocal
for /f "tokens=1-3 delims=/-:\, " %%a in ('echo/%~1') do (
set /a yy=%%a,mm=100%%b%%100,dd=100%%c%%100)
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
set /a i=j-%~2,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %~3=%yy%%f%%mm%%f%%dd%&goto :EOF