自动关机脚本

学了下,做了一个自己用的自动关机的脚本,贴出来给大家看看.

要是没有启动at服务请启动,不然定时关机没有用.

 

//把下面的程序黏贴到写字板,保存为 bat文件,打开就可以了,注意at服务要开启

rem -- 作者：泛 lyc557@163.com
rem -- 发布时间：2008年10月22日1:43:10
rem -- 版本: 1.0
rem -- 100行

@ECHO off
rem 关闭回显

TITLE 自动关机小程序 作者:泛 lyc557@163.com  版本 1.0
rem 标题

:start
COLOR 07
rem  使用COLOR命令对控制台输出颜色进行更改,07为白底黑字

MODE con: cols=70 lines=20
rem MODE对于设置做更改,语句为设定窗体的宽和高,

set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%

rem  设置时间的变量,存储现在的时刻并在后面显示

rem  对于time:~0,2 time一般现实为xx:yy:zz:rr 0表示从第0位开始2表示偏移2位所以time的为xx的值

ECHO 现在时间 %tm1%点%tm2%分%tm3%秒 %date%
ECHO =========================================
ECHO 请选择要进行的操作，然后按回车
ECHO ───────────────
ECHO.
ECHO 1. 定时关机
ECHO 2. 倒计时关机
ECHO 3. 关闭所有关机任务
ECHO 4. 查看定时关机任务
ECHO 5. 立即关机
ECHO 6. 退出
ECHO.
ECHO 说明: 如果at服务没开启请进入
ECHO  控制面板→管理工具→服务→Task Scheduler
ECHO  开启该服务
ECHO.
ECHO.

:cho
SET Choice=
SET /P Choice=请选择:
rem 设定变量"Choice"为用户输入的字符 请选择为提示符

IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
rem 为避免出现返回值含空格cmd解释为两个分开的命令从而导致程序异常,在变量外加了双引号
rem 如果输入大于1位,取第1位,比如输入1234,则choice的值为1

IF "%Choice%"=="1" GOTO SetHour
IF "%Choice%"=="2" GOTO outtime
IF "%Choice%"=="3" GOTO off
IF "%Choice%"=="4" GOTO see
IF "%Choice%"=="5" GOTO down
IF "%Choice%"=="6" GOTO end
rem 如果输入的字符不是以上的数字,将返回要求重新输入

ECHO 选择无效，请重新输入
GOTO cho

:SetHour
CLS
ECHO 制定关机时间 格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:

at %shutdowntime% shutdown -s
IF errorlevel 0 GOTO start

rem shutdown 部分情况不能完全关闭计算机,可能有点问题

ECHO %shutdowntime% 不是标准的时间格式,请重新输入
PAUSE >nul
GOTO SetHour

:outtime
CLS
ECHO 请输入倒计时秒数
SET timed=
SET /p timed=输入:
shutdown -s -t %timed%
GOTO start

:off
ECHO 取消所有关机任务
shutdown -a
at /delete /yes
ECHO 已经关闭所有任务键入任意键返回选择提示处
PAUSE >nul
rem 关闭所有at任务 /yes 默认是是的at不再询问
GOTO start

:see
at
ECHO 键入任意键返回选择提示处
PAUSE >nul
REM 输入任意键后执行下一条语句
GOTO start

:down
tsshutdn 0 /delay:0 /powerdown >nul

Tags： 批处理小程序 , 自动关机