汇编语言-016（SCASB 、STOSB 、LODSD 、数组中的取值、二维数组操作、冒泡排序和二分查找、CMPSW ）

最新推荐文章于 2023-04-14 10:10:18 发布
最新推荐文章于 2023-04-14 10:10:18 发布
阅读量1.9k 收藏 9
点赞数
分类专栏： 汇编 文章标签： 反汇编
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/m0_37599645/article/details/111772676
版权

1： SCASB : (字节)将AL的值与EDI寻址的一个字比较。进行在一个字符串检索特定的字符

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data 
alpha BYTE "ABCDEFGH",0

.code
main PROC
   mov edi,OFFSET alpha  ;EDI指向字符串
   mov al,'F'            ;检索字符F
   mov ecx,LENGTHOF alpha ;设置检索计数器
   cld                   ;方向为正向
   repne scasb            ;不相等则重复
   jnz  quit               ;若未发现字符则退出
   dec edi       ;发现字符，EDI减1，因为执行scasb后,edi增加1了

quit:
   INVOKE ExitProcess,0 
main ENDP
END main

2：STOSB : (字节)将AL的值复制到EDI寻址的位置上，可以加上rep重复操作

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
Count =100
string1 BYTE Count DUP(?)

.code
main PROC
  mov al,0FFh   ;要保存的数值
  mov edi,OFFSET string1 ;EDI指向目标字符串
  mov ecx,Count
  cld
  rep stosb  ;用AL的内容实现填充
  INVOKE ExitProcess,0
main ENDP
END main

3：LODSD : (双字)交一个双字数组中的每个元素都乘以同一个常数

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
array DWORD 1,2,3,4,5,6,7,8,9,10
multiplier DWORD 10  

;将一个32位整数数组中的每个元素都乘以一个常数

.code
main PROC
  cld 
  mov esi,OFFSET array  ;源数组索引
  mov edi,esi   ;目标数组索引
  mov ecx,LENGTHOF array  ;循环计数器
L1:
  lodsd   ;将[ESI]加载到EAX
  mul multiplier  ;与常数相乘
  stosd    ;将EAX保存到[EDI]
  loop L1  

  INVOKE ExitProcess,0
main ENDP
END main

4：数组中的取值，基址——变址操作数，将两个寄存器（称为基址和变址）相加，生成一个偏移地址

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
array WORD 1000h,2000h,3000h

.code
main PROC

   mov ebx,OFFSET array
   mov esi,2
   mov ax,[ebx+esi]  ;AX=2000h

   mov edi,OFFSET array
   mov ecx,4
   mov ax,[edi+ecx]   ;AX = 3000h

   mov ebp,OFFSET array
   mov esi,0
   mov ax,[ebp+esi]

   INVOKE ExitProcess,0
main ENDP
END main

5：二维数组中取值

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
tableB BYTE 10h,20h,30h,40h,50h
RowSize = ($ - tableB)
       BYTE 60h,70h,80h,90h,0A0h
	   BYTE 0B0h,0C0h,0D0h,0E0h,0F0h


.code
main PROC

   row_index = 1
   column_index = 2

   mov ebx,OFFSET tableB ;表的偏移量
   add ebx,RowSize * row_index  ;行的偏移量
   mov esi,column_index
   mov al,[ebx+esi]     ;AL = 80h

   INVOKE ExitProcess,0
main ENDP
END main

6：计算二维数组中某一行的之和

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
tableB BYTE 10h,20h,30h,40h,50h
RowSize = ($ - tableB)
       BYTE 60h,70h,80h,90h,0A0h
	   BYTE 0B0h,0C0h,0D0h,0E0h,0F0h


.code
main PROC

   row_index = 1
   column_index = 2

   mov ebx,OFFSET tableB ;表的偏移量
   add ebx,RowSize * row_index  ;行的偏移量
   mov esi,column_index
   mov al,[ebx+esi]     ;AL = 80h

   INVOKE ExitProcess,0
main ENDP

;计算字节矩阵中一行的和数
;接收：EBX=表偏移量，EAX=行索引
;ECX=按字节计的行大小
;返回：EAX为和数
calc_row_sum PROC USES ebx ecx edx esi
      mul ecx   ;行索引 * 行大小
	  add ebx,eax ;行偏移量
	  mov eax,0   ;累加器
	  mov esi,0   ;列索引
L1:
      movzx edx,BYTE PTR[ebx + esi] ;取一个字节
	  add eax,edx          ;与累加器相加
	  inc esi            ;行中下一个字节
	  loop L1
	  ret
calc_row_sum ENDP
END main

7：二维数组中使用比例因子寻址取值

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
tableW WORD 10h,20h,30h,40h,50h
RowSizeW = ($ - tableW)
       WORD 60h,70h,80h,90h,0A0h
	   WORD 0B0h,0C0h,0D0h,0E0h,0F0h


.code
main PROC

   row_index = 1
   column_index = 2
   mov ebx,OFFSET tableW   ;表偏移量
   add ebx,RowSizeW * row_index ;行偏移量
   mov esi,column_index
   mov ax,[ebx + esi*TYPE tableW]  ;AX = 0080h
 
   INVOKE ExitProcess,0
main ENDP


END main

8：基址——变址——偏移量操作数，用一个偏移量、一个基址寄存器、一个变址寄存器和一个可选的比例因子生成有效地址

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
tableD DWORD 10h,20h,30h,40h,50h
RowSizeD = ($ - tableD)
       DWORD 60h,70h,80h,90h,0A0h
	   DWORD 0B0h,0C0h,0D0h,0E0h,0F0h


.code
main PROC

   row_index = 1
   column_index = 2
   mov ebx,RowSizeD * row_index   ;行索引
   mov esi,column_index           ;列索引
   mov eax,tableD[ebx + esi*TYPE tableD]  ;AX = 00000080h
 
   INVOKE ExitProcess,0
main ENDP


END main

9：64位基址——变址——偏移量操作数做法

BinarySearch.asm

include BinarySearch.inc

.code

BinarySearch PROC USES ebx edx esi edi,
        pArray:PTR DWORD, ;数组指针
		Count:DWORD,      ;数组大小
		searchVal:DWORD   ;给定查找数值
		LOCAL first:DWORD,;first的位置
		      last:DWORD, ;last的位置
			  mid:DWORD   ;中点

	mov first,0        ;first = 0
	mov eax,Count      ;last = (Count - 1)
	dec eax
	mov last,eax
	mov edi,searchVal  ;EDI = searchVal
	mov ebx,pArray     ;EBX 为 数组指针
L1:
    ;当first<=last时
	mov eax,first
	cmp eax,last
	jg L5              ;退出查找
    
	;mid = (last+first)/2
	mov eax,last
	add eax,first
	shr eax,1
	mov mid,eax

	;EDX = values[mid]
	mov esi,mid
	shl esi,2            ;将mid 值乘4
	mov edx,[ebx+esi]    ;EDX = values[mid]

	;若EDX < searchVal(EDI)
	cmp edx,edi
	jge L2
	;first = mid +1
	mov eax,mid
	inc eax
	mov first,eax
	jmp L4

	;否则，若EDX>searchVal(EDI)
L2:
    cmp edx,edi
	jle L3    ;可选项
	;last=mid - 1
	mov eax,mid
	dec eax
	mov last,eax
	jmp L4
	
	;否则返回mid
L3:
	 mov eax,mid   ;发现数值
     jmp L9        ;返回mid
L4: 
    jmp L1         ;继续循环
L5:
    mov eax,-1     ;查找失败
L9:
   ret
 BinarySearch ENDP
 END

BinarySearch.inc

.386
.model flat,stdcall

.stack 4096

;冒泡排序/对半查找程序中使用的过程原型

;在32位有符号整数数组中查找一个数
BinarySearch PROTO,
        pArray:PTR DWORD,     ;指向数组
		Count:DWORD,          ;数组大小
		searchVal:DWORD       ;查找数值

;用32位有符号随机整数填充数组
FillArray PROTO,
       pArray:PTR DWORD,       ;指向数组
	   Count:DWORD,            ;元素个数
	   LowerRange:SDWORD,      ;随机数的下限
	   UpperRange:SDWORD       ;随机数的上限

;将32位有符号整数数组定到标准输出
PrintArray PROTO,
       pArray:PTR DWORD,
	   Count:DWORD,

;将数组按升序排列
BubbleSort PROTO,
       pArray:PTR DWORD,
	   Count:DWORD

BinarySearchTest.asm

include Irvine32.inc
include BinarySearch.inc

LOWVAL = -5000       ;最小值
HIGHVAL = +5000      ;最大值
ARRAY_SIZE = 50      ;数组大小

.data
array DWORD ARRAY_SIZE DUP(?)

.code
main PROC
    call Randomize
	;用有符号随机整数填充数组
	INVOKE FillArray,ADDR array,ARRAY_SIZE,LOWVAL,HIGHVAL

	;显示数组
	INVOKE PrintArray,ADDR array,ARRAY_SIZE
	call WaitMsg

	;执行冒泡排序并再次显示数组
	INVOKE BubbleSort ,ADDR array,ARRAY_SIZE
	INVOKE PrintArray,ADDR array,ARRAY_SIZE

	;实现对半查找
	call AskForSearchVal   ;用EAX返回
	INVOKE BinarySearch,
	    ADDR array,ARRAY_SIZE,eax
	call ShowResults

	exit
main ENDP

;请求用户输入一个有符号整数
;接收：无
;返回：EAX = 用户输入的数值
AskForSearchVal PROC
.data
prompt BYTE "Enter a signed decimal integer "
       BYTE "in the range of -5000 to +5000 "
	   BYTE "to find in the array: ",0
.code
    call Crlf
	mov edx,OFFSET prompt
	call WriteString
	call ReadInt
	ret
AskForSearchVal ENDP


;显示对半查找的结果值
;接收：EAX = 被显示数的位置
;返回：无
ShowResults PROC
.data
msg1 BYTE "The value was not found,",0
msg2 BYTE "The value was found at position ",0
.code
.IF eax == -1
   mov  edx,OFFSET msg1
   call WriteString
.ELSE
   mov edx,OFFSET msg2
   call WriteString
   call WriteDec
.ENDIF
   call Crlf
   call Crlf
   ret
ShowResults ENDP
END main

BubbleSort.asm

include BinarySearch.inc

.code

;使用冒泡算法，将一个32位有符号整数数组升序进行排列
;接收：数组指针，数组大小
;返回：无
BubbleSort PROC USES eax ecx esi,
       pArray:PTR DWORD,        ;数组指针
	   Count:DWORD              ;数组大小

	   mov ecx,Count
	   dec ecx        ;计数值减1
L1:
       push ecx       ;保存外循环计数值
	   mov esi,pArray; 指向第一个数值
L2:
       mov eax,[esi]   ;取数组元素值
	   cmp [esi+4],eax ;比较两个数值
	   jg L3           ;如果[ESI]<=[ESI+4],不交换
	   xchg eax,[esi+4];交换两数
	   mov [esi],eax
L3:
       add esi,4   ;两个指针都向前移动一个元素
	   loop L2     ;内循环

	   pop ecx     ;恢复外循环计数值
	   loop L1     ;若计数值不等于0，则继续外循环
L4:
       ret
BubbleSort ENDP
END

FillArray.asm

include Irvine32.inc

.code
;用LowerRange到(UpperRange-1之间的32位随机有符号整数序列填充数组)
;返回：无
FillArray PROC USES eax edi ecx edx,
        pArray:PTR DWORD,      ;数组指针
	    Count:DWORD,          ;元素个数
	    LowerRange:SDWORD,     ;范围下限
	    UpperRange:SDWORD     ;范围上限

	mov edi,pArray    ;EDI为数组指针
	mov ecx,Count     ;循环计数器
	mov edx,UpperRange
	sub edx,LowerRange   ;EDX = 绝对范围0..n
	cld   ;方向标志位清零
L1:
    mov eax,edx   ;偏移处理结果
	call RandomRange
	add eax,LowerRange  ;偏移处理结果
	stosd    ;将EAX 保存到[edi]
	loop L1

	ret
FillArray ENDP
END

PrintArray.asm

include Irvine32.inc

.code
;将32位有符号十进制整数数组写到标准输出，数值用逗号隔开
;接收：数组指针，数组大小
;返回：无
PrintArray PROC USES eax ecx edx esi,
        pArray:PTR DWORD,  
		Count:DWORD
.data
comma BYTE ", ",0
.code
   mov esi,pArray
   mov ecx,Count
   cld
L1:
   lodsd       ;加载[ESI]到EAX
   call WriteInt  ;发送到输出
   mov edx,OFFSET comma
   call WriteString
   loop L1

   call Crlf
   ret
PrintArray ENDP

END

10：CMPSW : 比较两个16位数组，找出第一个相同的值

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwEixtCode:DWORD

.data
sourceW WORD 1,2,3,4,5
targetW WORD 5,4,3,2,1

.code
main PROC
   mov esi,OFFSET sourceW
   mov edi,OFFSET targetW
   cld
   mov ecx,LENGTHOF sourceW
   repne cmpsw
   sub esi,TYPE WORD
   mov ax,[esi]
   INVOKE ExitProcess,0
main ENDP
END main
“好记性不如烂“博客
关注
  • 0
    点赞
  • 踩
  • 9
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
第三章、 汇编语言指令集和汇编语言语法
weixin_54707168的博客
02-07 392
第三章 汇编语言指令集 文章目录第三章 汇编语言指令集3.1 概述3.2 操作数3.3 ​寻址方式寄存器寻址存储器操作数寻址方式约定访问逻辑段 省略段基址3.4 汇编语言语法一、概述1.可执行文件的生成( Microsoft Windows系统)2.汇编源程序中的语句类型和格式二、常用伪指令数据定义伪指令**字节定义伪指令** `变量名 DB 一个或多个用逗号间隔的单字节数**字定义伪指令** `变量名 DW 一个或多个用逗号间隔的双字节数`**双字定义伪指令**`变量名 DD 一串用逗号间隔的4字
操作系统开发--所有汇编指令集合
wenwushq的博客
04-04 1929
想要开发操作系统，怎么能不知道汇编指令呢？于是翻看intel开发文档，把所有的汇编指令都做了一个整理，大家也可以收藏一下，以后肯定会用得着。1 通用指令1.1 数据传输指令MOV——Move指令：可以在通用寄存器之间移动数据；在内存和通用寄存器或段寄存器之间移动数据；把立即数移动到通用寄存器。CMOVE/CMOVZ——满足相等条件时移动/满足是0条件时移动。CMOVNE/CMOVNZ——满足不相等...
ES6之数组reduce()方法详解
小王的技术库
09-24 1523
reduce() 方法对数组中的每个元素执行一个由我们提供的reducer函数，且该函数为升序执行，并将其结果汇总为单个返回值。最近找到一个VUE的文档，它将VUE的各个知识点进行了总结，整理成了《Vue 开发必须知道的36个技巧》。内容比较详实，对各个知识点的讲解也十分到位。有需要的小伙伴，可以点击下方卡片领取，无偿分享。
LeetCode刷题-动态规划
weixin_45406155的博客
09-12 435
动态规划做题思路 1.定义数组元素来表示解，并且清晰的描述数组的含义，我们习惯用一个一维数组或者二维数组，来保存历史数组，假设用一维数组 df[] 吧，那么df[i] 你能否清楚的描述是什么意思呢？ 2.找出递推式，动态规划就是要利用曾经计算过的解的集合，因此递推式显得尤为重要，第一个步骤我们定义出数组的含义之后，你们df[n]和df[n-1]、df[n-2]有什么递推关系呢? 3.找出初始值。递推式递推到最后必须有初始值才能求解出问题。所以初始值也显得很为重要。 63.股票的最大利润 1.定义数组来表示
ES6的reduce用法
记得抬头微笑
08-24 7212
1. 求和数组(基本用法) let list = '12345'.split('') const total = list.reduce((val, oldVal) => val + oldVal) console..log(total) // 15 2. 去重数组
es6---reduce使用
最爱松露巧克力
03-11 5371
reduce()方法详解及高级技巧 reduce()方法可以搞定的东西，for循环，或者forEach方法有时候也可以搞定，那为啥要用reduce()？这个问题，之前我也想过，要说原因还真找不到，唯一能找到的是：通往成功的道路有很多，但是总有一条路是最捷径的，亦或许reduce()逼格更高... 1、语法 arr.reduce(callback,[initialValue]) ...
ES6之reduce用法
zuo_zuo_blog的博客
11-09 723
arr.reduce(function(prev,cur,index,arr){ arr表示原数组 prev表示上一次调用回调时的返回值，初始值init cur表示当前正在处理的数组元素 index表示当前正在处理的数组元素的索引 },init) 1.求数组项之和 var arr = [1,2,3,4,5,6]; var sum = arr.reduce(function (prev, cur){ return prev + cur; },0) 2.求数组项最大值 var max = arr.redu
汇编语言中的字符串和数组应用，可用于汇编语言的入门教程之一
最新发布
05-18
### 汇编语言中的字符串和数组应用 #### 引言 在计算机编程领域，汇编语言因其直接操控硬件的能力而备受关注。尤其在需要精确控制内存和数据处理的应用场景中，汇编语言的重要性不言而喻。本文将详细介绍汇编语言中...
X86汇编指令movsb、cmpsb、scasb、stosb、lodsb等简介
13岁的少年相当白帽子的博客
07-04 6967
movsb指令将esi的值按照字节（byte）为单位将数据传送到edi的内存地址上。 当DF =0时ESI和EDI的值增加1，DF=1时ESI和EDI的值减少1 movsw指令将esi的值按照字（word）为单位将数据传送到edi的内存地址上。 当DF =0时ESI和EDI的值增加2，DF=1时ESI和EDI的值减少2 movsd指令将esi的值按照双字（dword）为单位将数据传送到edi的内存地址上。 当DF =0时ESI和EDI的值增加4，DF=1时ESI和EDI的值减少4REP方法使用的示例
x86汇编指令集大全（带注释）.pdf
03-08
X86汇编指令集是计算机体系结构中不可或缺的一部分，特别是在32位和64位的x86架构处理器中。这篇文档详细列举了汇编指令，并为每条指令提供了注释说明。以下知识点涵盖了文档中提及的关键指令及其功能。 一、数据...
ES6常用方法整理《一》
余_小凡 的博客
09-30 300
1、数组去重 let arr = ['a','b','c','b']; let set = new Set(arr) // {'a','b','c'} let newArr = Array.from(set) // 再把set转变成array console.log(newArr) // ['a','b','c']
es6 中的reduce
zy_1558538904的博客
10-12 1100
语法： arr.reduce(callback,[initialValue]) 参数： callback： 执行数组中的每个值得回调函数其包含四个参数： accumulator: 这是一个累加参数，上一次调用的累积值，如果指定intiaValue则其初始值为0，否则其初始值为数组的第一个元素的值。 let arr = [1,3,5,8]; ...
ES6之数组reduce()方法详解及使用场景
luoboshang的博客
04-14 3156
ES6之数组reduce()方法详解及使用场景
ES6中的reduce
m0_58151273的博客
01-11 165
reduce(function(acc,currentValue,currentIndex){},{}) 对数组中的每一个元素进行一次回调，升序执行将回调汇总一个返回值 1.回到函数 其中有三个参数 1） acc：每次回调之后返回值汇总 2）currentValue 数组当前进行回调的值 3）currentIndex 数组当前进行回调的值得index 2.可选参数 如果传入acc就是这个值，不传acc就是数组中的第一个值 const str = 'asdadasdasdfaggh'
ES6 reduce方法
m0_45887053的博客
07-02 390
reduce（）是数组的归并方法 可同时将前面数组遍历产生的结果与当前项进行运算
es6中reduce的用法_理解 JavaScript 中 Reduce()
weixin_39530269的博客
01-04 121
关于前言reduce() 是一个有用的函数式编程技术，特别在需求上需要对象或数组降维的时时候。本文将要介绍 reduce() 方法，并对比使用 map() 与 filter()reduce() 的一般用法：const array1 = [1, 2, 3, 4]; const reducer = (accumulator, currentValue) => accumulator + curr...
ES6中的reduce函数详解
qq_44606064的博客
11-07 2037
ES6中的reduce函数详解
汇编语言课后习题解析：栈操作与字符串查找
"汇编语言课后习题答案" 这些题目是关于汇编语言编程的，主要涉及到过程定义、堆栈操作以及字符串处理等基本概念。 8.1 题目涉及过程定义。在汇编语言中，一个过程通常由`PROC`开始，`ENDP`结束。括号中应填入的...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值