new String()会创建几个对象

问题一：new String("ab")会创建几个对象?

        会创建2个对象：

• 对象1：new关键字在堆空间中创建的String。
• 对象2：字符串常量池中的对象“ab”。

public void test1(){
    String str = new String("ab");
}

        字节码如下：

 0 new #2 <java/lang/String>  // 创建String（对象1）
 3 dup // 复制引用地址
 4 ldc #3 <ab> // 加载字符串常量ab（对象2）
 6 invokespecial #4 <java/lang/String.<init> : (Ljava/lang/String;)V> // 调用构造方法
 9 astore_1 // 将引用存入栈帧的局部变量表
10 return

问题二：new String("a") + new String("b") 会创建几个对象？

        会创建了6个对象：

• 对象1：new StringBuilder()
• 对象2：new String("a")
• 对象3：常量池的 a
• 对象4：new String("b")
• 对象5：常量池的 b
• 对象6：调用StringBuilder.toString()中会创建一个 new String("ab")

        （ps：调用toString方法，不会在常量池中生成新对象ab）

public void test2(){
    String str = new String("a") + new String("b");
}

        字节码如下：

 0 new #2 <java/lang/StringBuilder> // 创建StringBuilder（对象1）
 3 dup
 4 invokespecial #3 <java/lang/StringBuilder.<init> : ()V>
 7 new #4 <java/lang/String> // 创建String（对象2）
10 dup
11 ldc #5 <a> // 加载字符串常量a（对象3）
13 invokespecial #6 <java/lang/String.<init> : (Ljava/lang/String;)V>
16 invokevirtual #7 <java/lang/StringBuilder.append : (Ljava/lang/String;)Ljava/lang/StringBuilder;>
19 new #4 <java/lang/String> // 创建String（对象4）
22 dup
23 ldc #8 <b> // 加载字符串常量b（对象5）
25 invokespecial #6 <java/lang/String.<init> : (Ljava/lang/String;)V>
28 invokevirtual #7 <java/lang/StringBuilder.append : (Ljava/lang/String;)Ljava/lang/StringBuilder;>
31 invokevirtual #9 <java/lang/StringBuilder.toString : ()Ljava/lang/String;> // 调用StringBuilder.toString（对象6）
34 astore_1
35 return