ASM插桩--多线程运行监测

最近需要优化App启动的时间，现有代码存在以下问题：

1. 线程未复用（使用new Thread\HandlerThread），创建线程数过多
2. 使用HandlerThread，使用后未销毁（Looper一直等待），占用内存
3. 提早start线程，却未使用
4. 部分业务方过早初始化业务代码（虽然是异步），影响启动时间

由于存在上述问题，需要扫描App从冷启动开始到首页展示出来，中间执行的子线程和主线程执行的情况。

需要监测的数据如下：

1. 创建的线程情况，包括数量和使用情况
2. 执行的runnable.run、AsyncTask.doInBackground等函数的执行时间

对于创建的线程数，Android Studio的profiler->cpu->threads中可以看出，但是我手机只要一打开profiler，就卡的不行，根本没法用。

基于上述需求，使用ASM对线程代码进行插桩。

1. 执行时间：计算run、doInBackground等的执行时间很简单，只需要在这些方法前面和最后面加入代码，然后就可以计算时间。
2. 统计线程数：由于Thread是系统代码，无法在Thread.run方法中进行插桩，也无法在Thread.start后面插代码，因为像线程池这种情况，也都是系统代码。只能在业务代码中进行插桩。因此考虑在以下代码中插入代码：

• Runnable.run
• AsyncTask.doInBackground
• Callable.call
• Handler.handleMessage、Handler.Callback.handleMessage
• Thread.run
• TimerTask.run

在这些方法都是运行在线程中，在这些方法中可以通过Thread.currentThread()获取到当前线程数据。 这样已经能覆盖到大部分情况了，因为大部分都是有任务才会创建线程，使用线程和创建线程的时间是挨着的。但是有一种特殊情况就是HandlerThread，他可以先创建，然后Looper一直等待直到有任务才执行，因此如果该looper一直等不到任务，用刚刚的办法就统计不到，因此这种情况要特殊处理。我们要逐行扫描是否有new HandlerThread 的代码，如果扫描到的话，也要统计到线程创建里去。

到这里，基本上讲完我们线程插桩的思路了。那么如何插桩呢？就是使用ASM库，他的原理是在class文件打包到dex之前，使用Gradle中的Transform对class文件进行插桩（具体可以自行查询，这里不细讲）。 我们要利用gradle的插件对代码进行插桩，如何进行插件开发呢？有以下两种方式：

1. 本工程中创建buildSrc模块（该模块名字专门用于插件开发）进行开发。
2. 独立工程开发

具体可以查看该文章。

本章采用第一种，在demo工程中创建了buildSrc。然后创建一个插件groovy文件：

class ThreadInjectPlugin implements Plugin<Project> {
    @Override
    void apply(Project project) {
        def android
        if (project.plugins.hasPlugin(AppPlugin)) {
            android = project.extensions.getByType(AppExtension)
        } else {
            android = project.extensions.getByType(LibraryExtension)
        }
        //处理runnable等方法
        android.registerTransform(new ThreadRunTransform())
        //处理new HandlerThread的
        android.registerTransform(new HandlerThreadTransform())
    }
}

复制代码

重点是这两个Transform，第一个Transform就是扫描到runnable这些，在函数前(onMethodEnter)和函数结束(onMethodExit)插入代码。第二个Transform是专门处理new HandlerThread的。

先看ThreadRunTransform：

class ThreadRunTransform extends Transform {

    @Override
    String getName() {
        return "ThreadTransform"
    }

    @Override
    Set<QualifiedContent.ContentType> getInputTypes() {
        return TransformManager.CONTENT_CLASS
    }

    @Override
    Set<? super QualifiedContent.Scope> getScopes() {
        return Sets.immutableEnumSet(QualifiedContent.Scope.PROJECT)
    }

    @Override
    boolean isIncremental() {
        return false
    }

    @Override
    void transform(TransformInvocation transformInvocation) throws TransformException, InterruptedException, IOException {
        super.transform(transformInvocation)
        transformInvocation.inputs.each { TransformInput input ->
            input.directoryInputs.each { DirectoryInput directoryInput ->
                transformDirectory(directoryInput, transformInvocation.outputProvider)
            }
        }
    }

    private void transformDirectory(DirectoryInput directoryInput, TransformOutputProvider outputProvider) {
        if (directoryInput.file.isDirectory()) {
            directoryInput.file.eachFileRecurse { File file ->
                def className = file.name
                def path = file.path
                if (isAppClass(className, path)) {
                    try {
                        FileInputStream fileInputStream = new FileInputStream(file.getAbsolutePath())
                        //-------------重点代码，拿到class类代码，通过ClassVisitor来扫描，并插入代码
                        ClassReader classReader = new ClassReader(fileInputStream)
                        ClassWriter classWriter = new ClassWriter(classReader, 0)
                        ClassVisitor visitor = new ThreadRunVisitor(className, classWriter)
                        classReader.accept(visitor, 0)
                        byte[] code = classWriter.toByteArray();
                        FileOutputStream fos = new FileOutputStream(file.parentFile.absolutePath + File.separator + className)
                        fos.write(code)
                        fos.close()
                        //------------重点代码结束------------------
                    } catch (Exception e) {

                    }
                }

            }
        }

        def dest = outputProvider.getContentLocation(directoryInput.name, directoryInput.contentTypes, directoryInput.scopes, Format.DIRECTORY)
        FileUtils.copyDirectory(directoryInput.file, dest)

    }

    private boolean isAppClass(String className, String path) {
        //检查该class是不是app工程下的包，不包括第三方的包
        return className.endsWith(".class") && !className.contains("R\$") && !"R.class".equals(className) && !"BuildConfig.class".equals(className);
    }
}
复制代码

public class ThreadRunVisitor extends ClassVisitor {

    private String className;
    private boolean needInject;

    public ThreadRunVisitor(St