ABAP长文本读取效率优化

长文本的数据在表中是以二进制的形式存储的，无法直接查表获取数据，常规做法是直接调用标准函数READ_TEXT进行读取，但是数据量大了之后效率会很低，因为每次调用都会重新执行一次SQL，优化方法：将长文本的数据查询到内表后将二进制数据转换为可读数据，测试代码如下

DATA:CON_MAX_SELECT_ROWS TYPE I VALUE '100000'.
DATA:LV_UZEIT TYPE SY-UZEIT.
DATA:LV_TIMES TYPE I.

DATA:LT_LINES_TEMP TYPE TABLE OF TLINE.
DATA:LT_LINES TYPE TABLE OF TLINE.
DATA:LS_LINES TYPE TLINE.

PERFORM FRM_READ_INTERNAL_TABLE.
PERFORM FRM_READ_FM.

FORM FRM_READ_INTERNAL_TABLE.

  TYPES:BEGIN OF TY_STXK_RAW,
       CLUSTR TYPE STXL-CLUSTR,
       CLUSTD TYPE STXL-CLUSTD,
      END OF TY_STXK_RAW.

  TYPES:TY_TAB_STXK_RAW TYPE STANDARD TABLE OF TY_STXK_RAW.

  DATA:LT_STXL_RAW TYPE TY_TAB_STXK_RAW.
  DATA:LT_STXL TYPE TY_TAB_STXK_RAW.
  DATA:LS_STXL TYPE TY_STXK_RAW.

  FREE:LT_LINES.

  GET TIME.
  LV_UZEIT = SY-UZEIT.

  SELECT CLUSTR CLUSTD INTO CORRESPONDING FIELDS OF TABLE LT_STXL FROM STXL UP TO CON_MAX_SELECT_ROWS ROWS WHERE TDOBJECT = 'EKPO' AND TDID = 'F01'.

  LOOP AT LT_STXL INTO LS_STXL.

    REFRESH:LT_STXL_RAW.
    APPEND LS_STXL TO LT_STXL_RAW.
    IMPORT TLINE = LT_LINES_TEMP  FROM INTERNAL TABLE LT_STXL_RAW.
    APPEND LINES OF LT_LINES_TEMP TO LT_LINES.

  ENDLOOP.

  GET TIME.
  LV_TIMES = SY-UZEIT - LV_UZEIT.

  WRITE:/'IMPORT INTERNAL TABLE 耗时：', LV_TIMES , '秒'.

ENDFORM.

FORM FRM_READ_FM.

  DATA:LT_STXL TYPE TABLE OF STXL.
  DATA:LS_STXL TYPE STXL.

  FREE:LT_LINES.

  GET TIME.
  LV_UZEIT = SY-UZEIT.

  SELECT * INTO CORRESPONDING FIELDS OF TABLE LT_STXL FROM STXL UP TO CON_MAX_SELECT_ROWS ROWS WHERE TDOBJECT = 'EKPO' AND TDID = 'F01'.
  LOOP AT LT_STXL INTO LS_STXL.

    CALL FUNCTION 'READ_TEXT'
      EXPORTING
        CLIENT                  = SY-MANDT
        ID                      = LS_STXL-TDID
        LANGUAGE                = LS_STXL-TDSPRAS
        NAME                    = LS_STXL-TDNAME
        OBJECT                  = LS_STXL-TDOBJECT
      TABLES
        LINES                   = LT_LINES_TEMP
      EXCEPTIONS
        ID                      = 1
        LANGUAGE                = 2
        NAME                    = 3
        NOT_FOUND               = 4
        OBJECT                  = 5
        REFERENCE_CHECK         = 6
        WRONG_ACCESS_TO_ARCHIVE = 7
        OTHERS                  = 8.
    IF SY-SUBRC = 0.
      APPEND LINES OF LT_LINES_TEMP TO LT_LINES.
    ENDIF.

  ENDLOOP.

  GET TIME.
  LV_TIMES = SY-UZEIT - LV_UZEIT.

  WRITE:/'READ FM 耗时：', LV_TIMES , '秒'.

ENDFORM.