plsql分割字符串

此示例是将一行包含由分号分隔的多个值的字符串分割成多列数据。在结果集中，每个分隔的值占据一列，同时每行代表一个分割后的值，其级别编号（LEVEL）作为另一列...

--处理简单字符串分割
DECLARE
  V_LINE_R VARCHAR2(255) := 'A;B;C;D;E;F;G';
  -- 声明一个游标Cur_V，该游标使用正则表达式来分割V_Line_R变量中的字符串
  CURSOR CUR_V IS
    SELECT LEVEL, REGEXP_SUBSTR(V_LINE_R, '[^;]+', 1, LEVEL) AS V_LINE
      FROM DUAL
    -- 确保连接条件始终为非空
    CONNECT BY REGEXP_SUBSTR(V_LINE_R, '[^;]+', 1, LEVEL) IS NOT NULL;
  -- 声明一个与游标Cur_V对应的记录类型变量V_Row，用于在循环中逐行提取数据
  V_ROW CUR_V%ROWTYPE;
BEGIN
  FOR V_ROW IN CUR_V LOOP
    DBMS_OUTPUT.PUT_LINE('Level: ' || V_ROW.LEVEL || '  V_LINE: ' ||
                         V_ROW.V_LINE);
  END LOOP;
EXCEPTION
  WHEN OTHERS THEN
    DBMS_OUTPUT.PUT_LINE('Error occurred: ' || SQLERRM);
END;

输出结果：

--处理大量分割的数据
--这个示例使用了一个简单的循环和 REGEXP_INSTR 来分割字符串，并将结果存储在一个 PL/SQL 集合中(请根据需要进行修改)

DECLARE
  V_Line_R VARCHAR2(32767) := 'A;B;C;D;E;F;G';

-- 定义一个类型StrArray，它是一个索引表，用于存储分割后的字符串片段
  TYPE StrArray IS TABLE OF VARCHAR2(255) INDEX BY PLS_INTEGER;
  
  -- 声明一个变量V_Lines，类型是StrArray，用于存储分割得到的字符串片段
  V_Lines StrArray;
  
  -- 声明一个整数变量V_Index，用于作为集合的索引
  V_Index PLS_INTEGER := 1;
  
  -- 声明一个字符串变量V_Piece，用于存储每次循环中分割得到的字符串片段
  V_Piece VARCHAR2(255);
BEGIN
  -- 使用WHILE循环和正则表达式REGEXP_INSTR来分割字符串
  WHILE REGEXP_INSTR(V_Line_R, ';') > 0 LOOP
    -- 使用SUBSTR和REGEXP_INSTR获取分号之前的字符串片段
    V_Piece := SUBSTR(V_Line_R, 1, REGEXP_INSTR(V_Line_R, ';') - 1);
    
    -- 将获取的字符串片段修剪空白并存储到集合中
    V_Lines(V_Index) := TRIM(V_Piece);
    
    -- 递增索引以准备存储下一个片段
    V_Index := V_Index + 1;
    
    -- 更新V_Line_R为剩余未分割的部分
    V_Line_R := SUBSTR(V_Line_R, REGEXP_INSTR(V_Line_R, ';') + 1);
  END LOOP;
  
  -- 处理字符串中剩余的最后一个值
  V_Lines(V_Index) := TRIM(V_Line_R);

  -- 使用FOR LOOP遍历集合V_Lines中的所有元素
  FOR I IN V_Lines.FIRST .. V_Lines.LAST LOOP
    -- 输出每个元素的索引和值
    DBMS_OUTPUT.PUT_LINE('Level: ' || I || '  Value: ' || V_Lines(I));
  END LOOP;

EXCEPTION
  WHEN OTHERS THEN
    DBMS_OUTPUT.PUT_LINE('Error occurred: ' || SQLERRM);
END;

输出结果：