易语言 服务端给客户端发弹窗信息源码

易语言 服务端给客户端发弹窗信息源码

需要用到服务器 云服务器_云主机_弹性云主机租用尽在 玖毅云

源码下载：易语言服务器给客户端发送弹窗源码.rar-其它文档类资源-CSDN下载

服务端源码

.版本 2
.支持库 Exmlrpc
.支持库 iext
.支持库 spec

.子程序 _按钮1_被单击

Port ＝ 到数值 (编辑框1.内容)
Server.启动 (Port, &Handler, 假)

.子程序 Handler
.参数 Value, 整数型
.局部变量 Type, 整数型
.局部变量 CHandle, 整数型
.局部变量 ClientIP, 文本型
.局部变量 Index, 整数型
.局部变量 Byte, 字节集
.局部变量 Information, 字节集
.局部变量 jc, 整数型
.局部变量 n1, 整数型
.局部变量 txt1, 文本型
.局部变量 txt2, 文本型

Type ＝ Server.取消息类型 (Value)
.如果真 (Type ＝ 0)
    Server.取客户句柄 (Value, CHandle)
    Server.取客户IP (CHandle, ClientIP)
    Index ＝ 超级列表框1.插入表项 (, ClientIP, , , , )
    超级列表框1.置标题 (Index, 1, 到文本 (CHandle))
    返回 ()
.如果真结束
.如果真 (Type ＝ 1)
    Server.取客户句柄 (Value, CHandle)
    jc ＝ 超级列表框1.取表项数 ()
    .计次循环首 (jc, n1)
        txt1 ＝ 超级列表框1.取标题 (n1 － 1, 1)
        .如果真 (txt1 ＝ 到文本 (CHandle))
            超级列表框1.删除表项 (n1 － 1)
            跳出循环 ()
        .如果真结束

    .计次循环尾 ()
.如果真结束
.如果真 (Type ＝ 2)
    调试输出 (1)
    Server.取请求字节集 (Value, txt2, Byte)
    .如果真 (到文本 (Byte) ＝ “真”)
        Information ＝ 图片框1.图片
        Server.发送字节集 (txt2, Information)
    .如果真结束

.如果真结束


.子程序 _按钮2_被单击
.局部变量 CHandle, 整数型
.局部变量 jc, 整数型
.局部变量 n1, 整数型

.如果真 (选择框1.选中 ＝ 真)
    jc ＝ 超级列表框1.取表项数 ()
    .计次循环首 (jc, n1)
        CHandle ＝ 到数值 (超级列表框1.取标题 (n1 － 1, 1))
        Process (CHandle, 编辑框2.内容, 图片框1.图片)
    .计次循环尾 ()
    返回 ()
.如果真结束
CHandle ＝ 到数值 (超级列表框1.取标题 (超级列表框1.现行选中项, 1))
.如果真 (CHandle ＝ 0)
    返回 ()
.如果真结束
Process (CHandle, 编辑框2.内容, 图片框1.图片)

.子程序 Process, 逻辑型
.参数 Client, 整数型
.参数 Text, 文本型, 可空
.参数 Picture, 字节集, 可空
.局部变量 Information, 字节集

.如果 (Picture ＝ {  })
    Information ＝ 到字节集 (Text)
    返回 (Server.发送字节集 (Client, Information))
.否则
    Information ＝ 到字节集 (“/#” ＋ Text)
    返回 (Server.发送字节集 (Client, Information))
.如果结束





.子程序 _按钮3_被单击
.局部变量 CHandle, 整数型

Process (CHandle, 编辑框2.内容, 图片框1.图片)

客户端源码

.版本 2
.支持库 Exmlrpc
.支持库 iext3
.支持库 spec
.支持库 EThread

.程序集 窗口程序集1
.程序集变量 Client, 请求客户端
.程序集变量 txt1, 文本型
.程序集变量 Missionarea, 整数型
.程序集变量 Ready, 整数型

.子程序 __启动窗口_创建完毕
.局部变量 Area, RECT

.如果真 (Client.连接 (12345, “127.0.0.1”, 假, &Handler) ＝ 假)
    信息框 (“链接服务器异常”, 0, “粉蝴蝶软件”)
    结束 ()
.如果真结束
Area (48, 0, Area, 0)
Missionarea ＝ Area.D

.子程序 Handler
.参数 Value, 整数型
.局部变量 Byte1, 字节集
.局部变量 Byte2, 字节集, , "0"
.局部变量 Location, 整数型
.局部变量 Logic, 逻辑型, 静态
.局部变量 Type, 整数型


Type ＝ Client.取消息类型 (Value)
.如果真 (Type ＝ 0)
    信息框 (“与服务器断开链接”, 0, “粉蝴蝶软件”)
    结束 ()
.如果真结束
.如果真 (Type ＝ 1)
    Client.取返回字节集 (Value, Byte1)
    .如果 (Logic ＝ 真)
        Pop (txt1, Byte1)
    .否则
        Location ＝ 寻找文本 (到文本 (Byte1), “/#”, , 假)
        .如果 (Location ＝ -1)
            高级选择夹1.现行子夹 ＝ 0
            txt1 ＝ 到文本 (Byte1)
            Pop (txt1, )
            返回 ()
        .否则
            Logic ＝ 假
            .如果真 (Client.异步发送字节集 (到字节集 (“真”)))
                txt1 ＝ 子文本替换 (到文本 (Byte1), “/#”, “”, , , 真)
                Logic ＝ 真
            .如果真结束
            高级选择夹1.现行子夹 ＝ 1
            调试输出 (1)

        .如果结束

    .如果结束
    返回 ()
.如果真结束


.子程序 Pop
.参数 Text, 文本型
.参数 Picture, 字节集, 可空

_启动窗口.左边 ＝ 取屏幕宽度 () － _启动窗口.宽度
_启动窗口.顶边 ＝ Missionarea
连续赋值 (Text, 标签1.标题, 标签2.标题)
图片框1.图片 ＝ Picture
_启动窗口.可视 ＝ 真
启动线程 (&递减窗口, , Ready)

.子程序 递减窗口

.判断循环首 (_启动窗口.顶边 ≥ Missionarea － _启动窗口.高度)
    延时 (1)
    _启动窗口.顶边 ＝ _启动窗口.顶边 － 1
.判断循环尾 ()
_启动窗口.顶边 ＝ Missionarea － _启动窗口.高度
关闭线程句柄 (Ready)

.子程序 __启动窗口_可否被关闭, 逻辑型

_启动窗口.可视 ＝ 假
返回 (假)