RT-Thread任务切换原理和堆栈的具体实现

已于 2022-07-23 11:54:38 修改
阅读量1.1k 收藏 9
点赞数 1
分类专栏： rtthread 文章标签： c++ 数据结构 嵌入式实时数据库
于 2022-07-23 11:43:36 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/m0_72905370/article/details/125945539
版权

任务切换实现

  1. void rt_hw_context_switch_to(rt_uint32 to);
  2. void PendSV_Handler(void);
  3. void rt_hw_context_switch(rt_uint32 from, rt_uint32 to);
  4. void PendSV_Handler(void); 
    ;*************************************************************************
;                                 全局变量
;*************************************************************************
IMPORT rt_thread_switch_interrupt_flag
IMPORT rt_interrupt_from_thread
IMPORT rt_interrupt_to_thread
;*************************************************************************
;                                 常量
;*************************************************************************
;-------------------------------------------------------------------------
;有关内核外设寄存器定义可参考官方文档：STM32F10xxx Cortex-M3 programming manual
;系统控制块外设SCB地址范围：0xE000ED00-0xE000ED3F
;-------------------------------------------------------------------------
SCB_VTOR        EQU     0xE000ED08     ; 向量表偏移寄存器
NVIC_INT_CTRL   EQU     0xE000ED04     ; 中断控制状态寄存器
NVIC_SYSPRI2    EQU     0xE000ED20     ; 系统优先级寄存器(2)
NVIC_PENDSV_PRI EQU     0x00FF0000     ; PendSV 优先级值 (lowest)
NVIC_PENDSVSET  EQU     0x10000000     ; 触发PendSV exception的值
;*************************************************************************
;                              代码产生指令
;*************************************************************************
AREA |.text|, CODE, READONLY, ALIGN=2
THUMB
REQUIRE8
PRESERVE8



;/*
; *-----------------------------------------------------------------------
; * 函数原型：void rt_hw_context_switch_to(rt_uint32 to);
; * r0 --> to
; * 该函数用于开启第一次线程切换
; *-----------------------------------------------------------------------
; */
rt_hw_context_switch_to    PROC
; 导出rt_hw_context_switch_to，让其具有全局属性，可以在C文件调用
EXPORT rt_hw_context_switch_to

; 设置rt_interrupt_to_thread的值
LDR     r1, =rt_interrupt_to_thread             ;将rt_interrupt_to_thread的地址加载到r1
STR     r0, [r1]                                ;将r0的值存储到rt_interrupt_to_thread

; 设置rt_interrupt_from_thread的值为0，表示启动第一次线程切换
LDR     r1, =rt_interrupt_from_thread           ;将rt_interrupt_from_thread的地址加载到r1
MOV     r0, #0x0                                ;配置r0等于0
STR     r0, [r1]                                ;将r0的值存储到rt_interrupt_from_thread

; 设置中断标志位rt_thread_switch_interrupt_flag的值为1
LDR     r1, =rt_thread_switch_interrupt_flag    ;将rt_thread_switch_interrupt_flag的地址加载到r1
MOV     r0, #1                                  ;配置r0等于1
STR     r0, [r1]                                ;将r0的值存储到rt_thread_switch_interrupt_flag

; 设置 PendSV 异常的优先级
LDR     r0, =NVIC_SYSPRI2
LDR     r1, =NVIC_PENDSV_PRI
LDR.W   r2, [r0,#0x00]       ; 读
ORR     r1,r1,r2             ; 改
STR     r1, [r0]             ; 写

; 触发 PendSV 异常 (产生上下文切换)
LDR     r0, =NVIC_INT_CTRL
LDR     r1, =NVIC_PENDSVSET
STR     r1, [r0]

; 开中断
CPSIE   F
CPSIE   I

; 永远不会到达这里
ENDP


;/*
; *-----------------------------------------------------------------------
; * void rt_hw_context_switch(rt_uint32 from, rt_uint32 to);
; * r0 --> from
; * r1 --> to
; *-----------------------------------------------------------------------
; */
;rt_hw_context_switch_interrupt
;EXPORT rt_hw_context_switch_interrupt
rt_hw_context_switch    PROC
EXPORT rt_hw_context_switch
; 设置中断标志位rt_thread_switch_interrupt_flag为1
LDR     r2, =rt_thread_switch_interrupt_flag          ; 加载rt_thread_switch_interrupt_flag的地址到r2
LDR     r3, [r2]                                      ; 加载rt_thread_switch_interrupt_flag的值到r3
CMP     r3, #1                                        ; r3与1比较，相等则执行BEQ指令，否则不执行
BEQ     _reswitch
MOV     r3, #1                                        ; 设置r3的值为1
STR     r3, [r2]                                      ; 将r3的值存储到rt_thread_switch_interrupt_flag，即置1

; 设置rt_interrupt_from_thread的值
LDR     r2, =rt_interrupt_from_thread                 ; 加载rt_interrupt_from_thread的地址到r2
STR     r0, [r2]                                      ; 存储r0的值到rt_interrupt_from_thread，即上一个线程栈指针sp的指针
_reswitch
; 设置rt_interrupt_to_thread的值
LDR     r2, =rt_interrupt_to_thread                   ; 加载rt_interrupt_from_thread的地址到r2
STR     r1, [r2]                                      ; 存储r1的值到rt_interrupt_to_thread，即下一个线程栈指针sp的指针
; 触发PendSV异常，实现上下文切换
LDR     r0, =NVIC_INT_CTRL
LDR     r1, =NVIC_PENDSVSET
STR     r1, [r0]

; 子程序返回
BX      LR

; 子程序结束
ENDP


;/*
; *-----------------------------------------------------------------------
; * void PendSV_Handler(void);
; * r0 --> switch from thread stack
; * r1 --> switch to thread stack
; * psr, pc, lr, r12, r3, r2, r1, r0 are pushed into [from] stack
; *-----------------------------------------------------------------------
; */
PendSV_Handler   PROC
EXPORT PendSV_Handler
; 失能中断，为了保护上下文切换不被中断
MRS     r2, PRIMASK
CPSID   I

; 获取中断标志位，看看是否为0
LDR     r0, =rt_thread_switch_interrupt_flag     ; 加载rt_thread_switch_interrupt_flag的地址到r0
LDR     r1, [r0]                                 ; 加载rt_thread_switch_interrupt_flag的值到r1
CBZ     r1, pendsv_exit                          ; 判断r1是否为0，为0则跳转到pendsv_exit

; r1不为0则清0
MOV     r1, #0x00
STR     r1, [r0]                                 ; 将r1的值存储到rt_thread_switch_interrupt_flag，即清0

; 判断rt_interrupt_from_thread的值是否为0
LDR     r0, =rt_interrupt_from_thread            ; 加载rt_interrupt_from_thread的地址到r0
LDR     r1, [r0]                                 ; 加载rt_interrupt_from_thread的值到r1
CBZ     r1, switch_to_thread                     ; 判断r1是否为0，为0则跳转到switch_to_thread
                                                 ; 第一次线程切换时rt_interrupt_from_thread肯定为0，则跳转到switch_to_thread
; ========================== 上文保存 ==============================
; 当进入PendSVC Handler时，上一个线程运行的环境即：
; xPSR，PC（线程入口地址），R14，R12，R3，R2，R1，R0（线程的形参）
; 这些CPU寄存器的值会自动保存到线程的栈中，剩下的r4~r11需要手动保存
MRS     r1, psp                                  ; 获取线程栈指针到r1
STMFD   r1!, {r4 - r11}                          ;将CPU寄存器r4~r11的值存储到r1指向的地址(每操作一次地址将递减一次)
LDR     r0, [r0]                                 ; 加载r0指向值到r0，即r0=rt_interrupt_from_thread
STR     r1, [r0]                                 ; 将r1的值存储到r0，即更新线程栈sp

; ========================== 下文切换 ==============================
switch_to_thread
LDR     r1, =rt_interrupt_to_thread               ; 加载rt_interrupt_to_thread的地址到r1
																									; rt_interrupt_to_thread是一个全局变量，里面存的是线程栈指针SP的指针
LDR     r1, [r1]                                  ; 加载rt_interrupt_to_thread的值到r1，即sp指针的指针
LDR     r1, [r1]                                  ; 加载rt_interrupt_to_thread的值到r1，即sp
LDMFD   r1!, {r4 - r11}                           ;将线程栈指针r1(操作之前先递减)指向的内容加载到CPU寄存器r4~r11
MSR     psp, r1                                   ;将线程栈指针更新到PSP
pendsv_exit
; 恢复中断
MSR     PRIMASK, r2
ORR     lr, lr, #0x04                             ; 确保异常返回使用的堆栈指针是PSP，即LR寄存器的位2要为1
BX      lr                                        ; 异常返回，这个时候任务堆栈中的剩下内容将会自动加载到xPSR，PC（任务入口地址），R14，R12，R3，R2，R1，R0（任务的形参）
                                                  ; 同时PSP的值也将更新，即指向任务堆栈的栈顶。在ARMC3中，堆是由高地址向低地址生长的。
																									; xPSR, PC, LR, R12, R0-R3会自动的恢复
; PendSV_Handler 子程序结束
ENDP


ALIGN   4

END

PendSV设置

设置PendSV优先级

NVIC_SYSPRI14   EQU 0xE000ED22
NVIC_PENDSV_PRI EQU 0xFF
LDR R0, =NVIC_SYSPRI14 
LDR R1, =NVIC_PENDSV_PRI
STRB R1, [R0]

触发PendSV异常

NVIC_INT_CTRL  EQU 0xE000ED04
NVIC_PENDSVSET EQU 0x10000000
LDR R0, =NVIC_INT_CTRL
LDR R1, =NVIC_PENDSVSET
STR R1, [R0]

任务切换具体过程

初始化/创建任务时rt_thread_init/rt_thread_create，假设申请的堆栈：0x2000588-0x20000988，

对0x20000948-0x20000988进行初始化，保存函数入口等信息后，则thread.sp = 0x20000948。

0x20000988 - 0x20000968 : psr, pc, lr, r12, r3, r2, r1, r0

0x20000968 - 0x20000948 : r4~r11

第一次调用 rt_hw_context_switch(rt_uint32 from, rt_uint32 to)

void PendSV_Handler(void);

to : thread.sp = 0x20000948 ,将thread.sp~thread.sp+0x20的内容手动出栈，赋值r4~r11。thread.sp= 0x20000968, 赋值psp = thread.sp, 当PendSV退出异常中断时，thread.sp~thread.sp+0x20的内容自动出栈，赋值(xPSR, PC, LR, R12, R0-R3)，故psp = 0x20000988，并跳转pc = thread.entry（pc为刚出栈的内容）

线程程序运行，局部变量，函数调用等,需要数据入栈

第二次调用 rt_hw_context_switch(rt_uint32 from, rt_uint32 to)

void PendSV_Handler(void);

from : psp = 0x20000940 ，(xPSR，pc，r14，r12，r3，r2，r1，r0)自动入栈后，psp = 0x20000920 , 再将r4~r11手动入栈后，psp = 0x20000900, 更新thread.sp = psp = 0x20000900.

……..调用其他进程，并等待挂起

第三次调用 rt_hw_context_switch(rt_uint32 from, rt_uint32 to)

void PendSV_Handler(void);

to : thread.sp = 0x20000900 ,将thread.sp~thread.sp+0x20的内容手动出栈，赋值r4~r11。thread.sp= 0x20000920, 赋值psp = thread.sp, 当PendSV退出异常中断时，thread.sp~thread.sp+0x20的内容自动出栈，赋值(xPSR, PC, LR, R12, R0-R3)，故psp = 0x20000940，并跳转pc（pc为刚出栈的内容）

……..调用其他进程，并等待挂起

注意事项

  • 申请的堆栈大小至少为0x40+0x20
  • 0x40为(xPSR，pc，r14，r12，r3，r2，r1，r0 r3-r11)的大小
  • 0x20为函数嵌套调用等大小
m0_72905370
关注
  • 1
    点赞
  • 踩
  • 9
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
专栏目录
RTThread创建线程.rar
04-29
基于博客中Rt-Thread学习笔记-----线程创建（三）的测试工程。里面包含RTThread的单线程动态、静态创建，以及多线程动态静态的配合（基于Stm32F103Zet6、Keil5、rtthread3.1.3）
RT-thread系统移植到stm32.zip
09-02
RT-thread是一款开源、轻量级、可扩展性强的实时操作系统（RTOS），被广泛应用于各种嵌入式设备，尤其是微控制器（MCU）如STM32系列。STM32是由意法半导体（STMicroelectronics）推出的基于ARM Cortex-M内核的微控制...
RT-thread学习笔记之线程切换
发呆健将的博客
08-31 1358
年初的时候学习的RT-thread，时间久了有些东西都又忘了，这里记录一下自己的学习笔记方便回顾，请参考RT-thread的官方编程指南，里面讲解的其实很详细。 RT-thread在Cortex-M内核中是通过人为触发PendSV异常中断进行线程切换的，若在中断中触发PendSV异常，那么PendSV响应将在所有中断结束后进行，其实很多芯片内核都有PendSV异常中断用于操作系统线程切换； ...
RT_Thread内核源码分析(一)——CM3内核和上下文切换
最新发布
langhunxiaoyue的博客
05-28 954
基于STM32F103ZE单片机+keil5编译器分析RT_Thread启动及运行过程，主要涉及CM3的内核知识、操作系统启动、上下文切换。
RT-Thread 内核线程切换原理
Tang的博客
01-02 2292
1、背景 本文章主要说明 rtthread 内核线程是如何切换的，初学者刚从裸机开发接触 RTOS 时难免会有些不适应，明白这部分原理之后就会对 RTOS 有更深的理解。在学习内核线程切换原理之前需要有以下基础知识铺垫。本文以 arm 公司的 Cortex-M3 内核为例。 2、基础知识 CM3 拥有通用寄存器 R0-R15 以及一些特殊功能寄存器(中断屏蔽寄存器等等） R0-R12 都是通用寄存器，用来临时存储程序运行时产生的数据 R13 这个寄存器存储堆栈指针，在 CM3 内核
RT-Thread线程创建和切换分析
qq_43460068的博客
10-06 2309
提出问题：什么叫线程？思考这个问题之前，先想想怎么切换线程？怎么保存线程？想要回答以上的问题，需要了解一些微机原理和ARM架构及汇编的知识。
RT-Thread任务切换函数，汇编源码gcc环境详解
niu_88的博客
08-13 1208
  主要针对RT-Thread系统中任务切换函数汇编部分进行一下记录，方便回头查看，gcc/MDK/IAR内容差不多，只是语法格式不同而已，本人一般使用gcc环境，所以对 context_gcc.S详解。 先贴源码 /* * Copyright (c) 2006-2018, RT-Thread Development Team * * SPDX-License-Identifier: Apache-2.0 * * Change Logs: * Date Author
RT-Thread代码启动过程与线程切换的实现
sinat_31039061的博客
01-30 2535
我们找到系统复位的地方，可以往下单步跟踪。 ①从系统初始化开始执行，将函数地址赋给R0寄存器，跳转到R0地址执行并返回此处（BLX是带链接的跳转，即带返回的跳转）。 ②将main函数地址给R0，将函数地址赋给R0，跳转到R0地址执行，不返回（BX是跳转，不返回）。 ③跳转到了$Sub$$main。 【注：在 __CC_ARM 编译器环境下，使用了$Sub$$ 与 $Super$$ 的“补丁”功能...
STM32H750移植rt-thread操作系统完整工程.zip
05-17
5. **RTOS初始化**：调用rtthread_init()函数进行rt-thread的初始化，包括创建第一个线程、设置调度策略等。 6. **应用程序开发**：基于rt-thread的API开发用户应用，可以创建任务、信号量、消息队列等，实现特定的...
NXP i.MX RT1052 RT-Thread实战：线程的定义与线程切换的实现【基于Cortex-M7】
12-01
在本文中，我们将深入探讨NXP i.MX RT1052处理器上的RT-Thread实时操作系统（RTOS）的实战应用，特别是线程管理和线程切换的实现。NXP i.MX RT1052是一款高性能的跨界微控制器，基于ARM Cortex-M7内核，为嵌入式应用...
NXP i.MX RT1052 RT-Thread实战：线程的定义与线程切换的实现【基于Cortex-M3】
12-01
在嵌入式系统开发中，实时操作系统（RTOS）如RT-Thread扮演着至关重要的角色，尤其是在处理多任务并发和时间敏感的应用中。本教程将深入探讨如何在NXP i.MX RT1052微处理器上使用RT-Thread进行线程管理和线程切换的...
NXP i.MX RT1052 RT-Thread实战：线程的定义与线程切换的实现【基于Cortex-M4】
12-01
在RT-Thread中，线程是任务调度的基础，每个线程都有自己的堆栈空间和上下文，包括寄存器状态、程序计数器等。创建线程时，我们需要指定线程的优先级、堆栈大小、入口函数和参数，以及可能的初始化状态。 NXP i.MX ...
rt-thread------任务调度
qq_39854159的博客
09-09 1173
本文主要阐述rt-thread任务切换原理，优先级和时间片的概念
STM32 RT-Thread 系统分析（3）-线程管理之线程切换（系统移植基础篇一）
鸳鸯冰笔的博客
10-08 1536
线程管理之线程切换前言基本信息前言说明CPU 架构移植rt_hw_interrupt_disable 关闭全局中断知识点中断屏蔽寄存器组汇编指令B、BL、BX、BLX 和 BXJ连接寄存器 R14（ LR）rt_hw_interrupt_enable 打开全局中断知识点MSR 指令*rt_hw_stack_init 线程栈的初始化知识点RT_ASSERT(EX) 前言 基本信息 名称 描述说明 RT-Thread Studio 软件版本 版本: 1.1.3 RT-Thread 系统版本
rt-thread源码分析篇四：堆栈分配机制
OnlyLove_的博客
08-21 999
一、前言 参考文档：《Libraries and Floating Point Support Guide》 二、堆栈分配机制 《Libraries and Floating Point Support Guide》文档中对堆栈描述如下： 堆栈模型有2种： 1、单内存区域模型（堆栈共用一片空间） 2、双内存区域模型（堆和栈都有独立空间） 双内存区域模型开启方法： 1、汇编语言使用语句：IMPORT __use_two_region_memory 2、c语言使用语句：#pragma import(__use
RT-thread 堆栈理解
Tang的博客
01-08 2773
1. 背景 ​ 相信不少的小伙伴一直有这个问题，堆栈堆栈，到底在哪里？本文以RT-thread 为例，讲解 RTT 中堆栈的位置。 2. 栈在哪，堆在哪？ ​ 在回答堆栈在哪之前，首先要明白堆栈是内存，内存是什么？是实际的存储设备，比如 eeprom、flash、sram、sdram。我们的代码以及数据不可能没地方放，否则 cpu 怎么去执行指令。 ​ cpu 需要从内存中读取数据到 cpu内部(寄存器)，他怎么知道把数据放入内部那个寄存器呢？汇编代码中说明了数据存入那些寄存器中。 ​ 栈不需要程序员手动去
Rt-Thread 移植2--线程定义与切换（KF32）
qq_43650963的博客
09-22 169
主要是变量定义。
rtthread线程定义与切换实现
lzw508170827的博客
12-17 4068
title: rtthread线程定义与切换实现 date: 2020-10-22 12:39:15 tags: rtthread 创建线程 包括：线程栈大小、线程栈、线程函数、线程控制块 定义线程栈 在多线程系统中，每个线程都是独立的，互不干扰的，所以要为每个线程都分配独立的栈空间，这个栈空间通常是一个预先定义好的全局数组，也可以是动态分配的一段内存空间，但它们都存在于 RAM 中。 定义线程栈 线程栈即rt_uint8_t类型数组 ALIGN(RT_ALIGN_SIZE) /* 定义线程栈 */ r.
RT-Thread-03-栈空间分配
u012084226的博客
06-24 366
先将线程栈空间大小设置一个固定值（比如2048），在线程运行时通过查看线程栈的使用情况，再根据使用的情况合理修改设置栈空间的大小，一般栈空间最大使用量设置为70%在drv_gpio.h中有对引脚IO的驱动配置。
rt-thread入门教程PPT
03-13
rt-thread入门教程PPT

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值