bzoj 1706 奶牛接力

【USACO练习题目】奶牛接力

Time Limit:10000MS  Memory Limit:65536K
Total Submit:12 Accepted:8 
Case Time Limit:1000MS

Description

FJ 的N(2 <= N <= 1,000,000)头奶牛选择了接力跑作为她们的日常锻炼项目。至于进行接力跑的地点，自然是在牧场中现有的T(2 <= T <= 100)条跑道上。 
农场上的跑道有一些交汇点，每条跑道都连结了两个不同的交汇点I1i和I2i(1 <= I1i <=1,000; 1 <= I2i <= 1,000)。每个交汇点都是至少两条跑道的端点。奶牛们知道每条跑道的长度lengthi(1 <= lengthi <= 1,000)，以及每条跑道连结的交汇点的编号。并且，没有哪两个交汇点由两条不同的跑道直接相连。你可以认为这些交汇点和跑道构成了一张图。 
为了完成一场接力跑，所有N 头奶牛在跑步开始之前都要站在某个交汇点上（有些交汇点上可能站着不只1头奶牛）。当然，她们的站位要保证她们能够将接力棒顺次传递，并且最后持棒的奶牛要停在预设的终点。 
你的任务是，写一个程序，计算在接力跑的起点(S)和终点(E)确定的情况下，奶牛们跑步路径可能的最小总长度。显然，这条路径必须恰好经过N条跑道。

Input

第1行: 4个用空格隔开的整数：N，T，S，以及E 
第2..T+1行: 第i+1为3个以空格隔开的整数：lengthi，I1i，以及I2i，描述了第i条跑道。

Output

1行:输出1个正整数，表示起点为S、终点为E，并且恰好经过N 条跑道的路径的最小长度

Sample Input

2 6 6 4
11 4 6
4 4 8
8 4 9
6 6 8
2 6 9
3 8 9

Sample Output

<span style="font-size:14px;">题目大意：给出M条边，起点和终点，求从起点到终点正好经过N条边（可以重复）的最短路径。</span>

<span style="font-size:14px;">题解：分析题目，易得出最多只有100个点，将点离散化。设一个矩阵A，A[i,j]表示从i到j的最短路径和。走N条边的最短路径和即为A^n，不过要注意矩阵的运算换成floyed。即c[i,j]=a[i,k]*b[k,j]换成c[i,j]=min(c[i,j],a[i,k]*b[k,j]); c[s,e]即为答案</span>

const 

  maxn=100;
type
  arr=array[1..maxn,1..maxn]of longint;

var
  n,m,s,e,ans,sum,i,j:longint;
  c,d:arr;
  num:array[1..1000]of longint;

procedure init;
var
  i,x,y,l:longint;
begin
  readln(n,m,s,e);
  for i:=1 to m do
  begin
    readln(l,x,y);
    if num[x]=0 then
    begin
      inc(sum);
      num[x]:=sum;
    end;
    if num[y]=0 then
    begin
      inc(sum);
      num[y]:=sum;
    end;
    d[num[x],num[y]]:=l;
    d[num[y],num[x]]:=l;
  end;
end;

function min(a,b:longint):longint;
begin
  if a<b then exit(a) else exit(b);
end;

procedure floyed(a,b:arr);
var
  i,j,k:longint;
begin
  for i:=1 to sum do
    for j:=1 to sum do
      c[i,j]:=maxlongint div 3;
  for i:=1 to sum do
    for j:=1 to sum do
      for k:=1 to sum do
        if (a[i,k]<maxlongint)and(b[k,j]<maxlongint) then
          c[i,j]:=min(c[i,j],a[i,k]+b[k,j]);
end;


procedure ksm(n:longint);
begin
  if n=1 then exit;
  ksm(n div 2);
  floyed(c,c);
  if odd(n) then floyed(c,d);
end;




begin
  init;
  for i:=1 to sum do
    for j:=1 to sum do
      if d[i,j]=0 then d[i,j]:=maxlongint;
  c:=d;
  ksm(n);
  writeln(c[num[s],num[e]]);
end.