DP 石子归并

WIKIOI 1048 石子归并

有n堆石子排成一列，每堆石子有一个重量w[i], 每次合并可以合并相邻的两堆石子，一次合并的代价为两堆石子的重量和w[i]+w[i+1]。问安排怎样的合并顺序，能够使得总合并代价达到最小。

输入描述 Input Description

第一行一个整数n（n<=100）

第二行n个整数w1,w2...wn  (wi <= 100)

输出描述 Output Description

一个整数表示最小合并代价

样例输入 Sample Input

4

4 1 1 4

样例输出 Sample Output

18

题目大意：相邻两堆可以合并，代价是两堆的重量和，求最小总代价。

题解：DP。按堆数划分阶段，从2堆开始直到合并n堆。

设f[i,j]表示第i~j堆合并的最小总代价，对于每个i~j，都有f[i,j]:=min(f[i,k]+f[k+1,j]+s[j]-s[i-1],f[i,j]) |i<=k<j|

也就是将i~j划分为两部分，这样从2~n就可以逐步合并出f[1,n]

const
  maxn=100;
var
  f:array[1..maxn,1..maxn]of longint;
  a,s:array[0..maxn]of longint;
  n,k,l,i,j:longint;

procedure init;
var
  i,j:longint;
begin
  readln(n);
  for i:=1 to n do
  begin
    readln(a[i]);
    s[i]:=s[i-1]+a[i];
  end;
end;

function min(a,b:longint):longint;
begin
  if a<b then exit(a) else exit(b);
end;

begin
  init;
  for i:=2 to n do
    for j:=1 to n-i+1 do
    begin
      k:=j+i-1;
      f[j,k]:=maxlongint;
      for l:=j to k-1 do
        f[j,k]:=min(f[j,l]+f[l+1,k]+s[k]-s[j-1],f[j,k]);
    end;
  writeln(f[1,n]);
end.