【NOIP2018复习】区间（RMQ/分治）

1277.区间

时间限制:1000MS内存限制:256000KB

题目描述

每一个机房中总有一个红太阳。有一天，AmberFrame 来到机房，发现桌上有不知道哪个蒟蒻放上的问 题： 有一个 n 个数的序列，一开始所有的数都是 0，每次可以将一个区间 [l, r](l ≤ r) 内的数 +1，求到达最 终状态的最少操作次数。 AmberFrame 非常强，自然不会把时间花在这种水题上。因此他就把任务交给了你，如果不会做的话，他 可能就会觉得你就是那个放问题的蒟蒻了而把你批判一番了。 

数据规模

输入

第一行包含一个正整数 n，表示序列的长度。
第二行包含 n 个非负整数 a1, a2, ..., an，表示最终的状态。

输出

输出的第一行是一个正整数 m，表示最少的操作次数。 接下来 m 行每行两个正整数 li , ri，表示一次操作。你需要保证 1 ≤ li ≤ ri ≤ n。 保证最少次数 m ≤ 10^5，按字典序输出。

输入样例复制

6
2 3 3 3 3 3

输出样例复制

3
1 6
1 6
2 6

说明

Hint 下发样例中第 i 个样例与第 i 组数据范围相符。 对于样例 1，第一个数被加了两次，其他每个数都被加了三次，显然满足条件。

题解：思考可得，对于一个区间，将整个区间减去区间最小值是一种最优解。每次找到区间最小值，标记减去该最小值并记录区间，以该位置为界分为左右两边，分治。

RMQ求区间最小值的位置

const
  maxn=100100;
  inf='range.in';
  ouf='range.out';
var
  a:array[1..maxn]of longint;
  n,m,po,ansm,i:longint;
  ans:array[0..maxn,1..3]of longint;
  lg:array[1..maxn]of longint;
  mi:array[0..31]of longint;
  f:array[1..maxn,0..31]of longint;

procedure st;
var
  i,j:longint;
begin
  for i:=1 to n do
    f[i,0]:=i;
  for j:=1 to lg[n] do
    for i:=1 to n do
    begin
      if i+mi[j]-1>n then continue;
      if a[f[i,j-1]]<a[f[i+mi[j-1],j-1]] then f[i,j]:=f[i,j-1] else f[i,j]:=f[i+mi[j-1],j-1];
    end;
end;

procedure init;
var
  i:longint;
begin
  readln(n);
  po:=1;
  for i:=1 to n do
  begin
    read(a[i]);
    if a[po]>a[i] then po:=i;
  end;
  mi[0]:=1;
  for i:=1 to 30 do
    mi[i]:=mi[i-1]*2;
  for i:=1 to n do
    lg[i]:=trunc(ln(i)/ln(2));
  st;
end;


function rmq(l,r:longint):longint;
var
  k:longint;
begin
  k:=lg[r-l+1];
  if a[f[l,k]]<a[f[r-mi[k]+1,k]] then rmq:=f[l,k] else rmq:=f[r-mi[k]+1,k];
end;

procedure dfs(l,r,y:longint);
var
  i,po,head,flag,kk:longint;
begin
  if l=r then
  begin
    inc(m,a[l]-y);
    inc(ansm);
    ans[ansm,1]:=l;ans[ansm,2]:=l;ans[ansm,3]:=a[l]-y;
    a[l]:=0;
    exit;
  end;
  po:=rmq(l,r);
  inc(ansm);inc(m,a[po]-y);
  ans[ansm,1]:=l;ans[ansm,2]:=r;ans[ansm,3]:=a[po]-y;
  if l<=po-1 then dfs(l,po-1,a[po]);
  if po+1<=r then dfs(po+1,r,a[po]);

end;

procedure qsort(l,r:longint);
var
  i,j,key1,key2:longint;
begin
  if l>r then exit;
  i:=l;j:=r;
  key1:=ans[(i+j)shr 1,1];
  key2:=ans[(i+j)shr 1,2];
  repeat
    while (ans[i,1]<key1)or(ans[i,1]=key1)and(ans[i,2]<key2) do inc(i);
    while (ans[j,1]>key1)or(ans[j,1]=key1)and(ans[j,2]>key2) do dec(j);
    if i<=j then
    begin
      ans[0]:=ans[i];ans[i]:=ans[j];ans[j]:=ans[0];
      inc(i);dec(j);
    end;
  until i>j;
  qsort(l,j);
  qsort(i,r);
end;


procedure print;
var
  i,j:longint;
begin
  writeln(m);
  qsort(1,ansm);
  for i:=1 to ansm do
    for j:=1 to ans[i,3] do
      writeln(ans[i,1],' ',ans[i,2]);
end;

begin
  assign(input,inf);reset(input);
  assign(output,ouf);rewrite(output);
  init;
  dfs(1,n,0);
  print;
  close(input);close(output);
end.