如何创建跟踪 (Transact-SQL)

 

本主题介绍了如何使用存储过程创建跟踪。

创建跟踪

1. 执行带所需参数的 sp_trace_create 以创建新的跟踪。新的跟踪将处于停止状态（status 为 0）。

2. 执行带所需参数的 sp_trace_setevent 以选择要跟踪的事件和列。

3. 也可以执行 sp_trace_setfilter 以设置任意筛选或筛选组合。

   sp_trace_setevent 和 sp_trace_setfilter 只能在已停止的现有跟踪上执行。

   重要提示
   与常规存储过程不同的是，必须严格键入所有 SQL Server Profiler 存储过程的参数 (sp_trace_xx)，而且这些参数不支持数据类型自动转换。如果这些参数不是使用正确的输入参数数据类型（如参数说明中指定的那样）调用的，则存储过程会返回错误。

示例

---

下面的代码演示如何使用 Transact-SQL 创建跟踪。代码分为三部分：创建跟踪、填充跟踪文件以及停止跟踪。通过添加要跟踪的事件来自定义跟踪。有关事件和列的列表，请参阅 sp_trace_setevent (Transact-SQL)。

下面的代码创建跟踪，向跟踪添加事件，随后启动跟踪：

other

复制

DECLARE @RC int, @TraceID int, @on BIT
EXEC @rc = sp_trace_create @TraceID output, 0, N'C:\SampleTrace'

-- Select the return code to see if the trace creation was successful.
SELECT RC = @RC, TraceID = @TraceID

-- Set the events and data columns you need to capture.
SELECT @on = 1

-- 10 is RPC:Completed event. 1 is TextData column. 
EXEC sp_trace_setevent @TraceID, 10, 1, @on 
-- 13 is SQL:BatchStarting, 11 is LoginName
EXEC sp_trace_setevent @TraceID, 13, 11, @on 
-- 13 is SQL:BatchStarting, 14 is StartTime
EXEC sp_trace_setevent @TraceID, 13, 14, @on 
-- 12 is SQL:BatchCompleted, 15 is EndTime
EXEC sp_trace_setevent @TraceID, 12, 15, @on 
-- 13 is SQL:BatchStarting, 1 is TextData
EXEC sp_trace_setevent @TraceID, 13, 1, @on 

-- Set any filter. Not provided in this example
--EXEC sp_trace_setfilter 1, 10, 0, 6, N'%Profiler%'

-- Start Trace (status 1 = start)
EXEC @RC = sp_trace_setstatus @TraceID, 1
GO

现在已创建并启动跟踪，接下来执行下面的代码以便用活动填充跟踪。

other

复制

SELECT * FROM master.sys.databases
GO
SELECT * FROM ::fn_trace_getinfo(default)
GO

可以随时停止和重新启动跟踪。在本示例中，执行下面的代码以停止跟踪、关闭跟踪并删除跟踪定义。

other

复制

DECLARE @TraceID int
-- Populate a variable with the trace_id of the current trace
SELECT  @TraceID = TraceID FROM ::fn_trace_getinfo(default) WHERE VALUE = N'C:\SampleTrace.trc'

-- First stop the trace. 
EXEC sp_trace_setstatus @TraceID, 0

-- Close and then delete its definition from SQL Server. 
EXEC sp_trace_setstatus @TraceID, 2

若要检查跟踪文件，请使用 SQL Server Profiler 打开 SampleTrace.trc 文件。