linux内核解读（一）

linux内核引导过程

1、pc上电后，8086结构的cpu将自动进入实模式，并从地址0xffff0开始执行代码，这个地址是rom-bios的地址。
2、bios执行系统检测，并在物理地址0处开始初始化中断向量。
3、将启动设备的第一个扇区（512k）的bootsect.s读入地址0x7c0（绝对地址31k）的位置，并转到0x7c0执行。
4、bootsect.s执行时先将自己复制到地址0x9000处，把启动设备中的2k代码（setup.s）复制到地址0x9200处，将系统的其他部分-系统模块（包括head.s）复制到0x1000处。
5、系统在启动过程中会识别主机的特性和vga卡的类型。（或者会要求用户从终端输入显示类型）。
6、bootsect.s执行完后，在执行setup.s的时候会将system模块从0x1000移动到0x0000，这样便于代码和数据的操作。
7、进入保护模式，并跳转至0x0000处执行。
8、这时候32位运行方式的设置已经都完成，包括：IDT、GDT以及LDT被加载，处理器和协处理器也已确认了，分页工作也完成。系统调用main.c执行。

程序分析：

bootsect.s
!
! SYS_SIZE is the number of clicks (16 bytes) to be loaded.
! 0x3000 is 0x30000 bytes = 196kB, more than enough for current
! versions of linux
!
SYSSIZE = 0x3000        ！system模块编译后的大小，0x3000*16byte=0x30000byte=192kb
!
!    bootsect.s        (C) 1991 Linus Torvalds
!
! bootsect.s is loaded at 0x7c00 by the bios-startup routines, and moves
! iself out of the way to address 0x90000, and jumps there.
!
! It then loads 'setup' directly after itself (0x90200), and the system
! at 0x10000, using BIOS interrupts.
!
! NOTE! currently system is at most 8*65536 bytes long. This should be no
! problem, even in the future. I want to keep it simple. This 512 kB
! kernel size should be enough, especially as this doesn't contain the
! buffer cache as in minix
!
! The loader has been made as simple as possible, and continuos
! read errors will result in a unbreakable loop. Reboot by hand. It
! loads pretty fast by getting whole sectors at a time whenever possible.

.globl begtext, begdata, begbss, endtext, enddata, endbss
.text
begtext:
.data
begdata:
.bss
begbss:
.text

SETUPLEN = 4                ! nr of setup-sectors ！setup程序的扇区数
BOOTSEG  = 0x07c0            ! original address of boot-sector
INITSEG  = 0x9000            ! we move boot here - out of the way
SETUPSEG = 0x9020            ! setup starts here
SYSSEG   = 0x1000            ! system loaded at 0x10000 (65536).
ENDSEG   = SYSSEG + SYSSIZE        ! where to stop loading

! ROOT_DEV:    0x000 - same type of floppy as boot.
!        0x301 - first partition on first drive etc
ROOT_DEV = 0x306    ！根文件系统设备，这里设置为第2个硬盘的第1个扇区。
！设备号=主设备*256+次设备号
！主设备号：1-内存，2-软盘，3-硬盘，4-ttyx，5-tty，6-并行口，6-非命名管道
！0x300-第一个硬盘第0个分区，0x305-第2个硬盘第0个分区


entry start
start:
    mov    ax,#BOOTSEG
    mov    ds,ax
    mov    ax,#INITSEG
    mov    es,ax
    mov    cx,#256
    sub    si,si
    sub    di,di
    rep        ！将bootsect.s移动到0x90000
    movw
    jmpi    go,INITSEG ！段间跳转到INITSEG（0x90000）
go:    mov    ax,cs    ！cs=0x90000
    mov    ds,ax
    mov    es,ax
! put stack at 0x9ff00.
    mov    ss,ax
    mov    sp,#0xFF00        ! arbitrary value >>512 sp要设置成远大于0x90200（就是段偏移要大于0x200+0x200*4）
                    ！因为setup.s大约是4个扇区（4*0x200）

! load the setup-sectors directly after the bootblock.
! Note that 'es' is already set up.

load_setup:
    mov    dx,#0x0000        ! drive 0, head 0
    mov    cx,#0x0002        ! sector 2, track 0
    mov    bx,#0x0200        ! address = 512, in INITSEG
    mov    ax,#0x0200+SETUPLEN    ! service 2, nr of sectors
    int    0x13            ! read it
    jnc    ok_load_setup        ! ok - continue
    mov    dx,#0x0000
    mov    ax,#0x0000        ! reset the diskette
    int    0x13
    j    load_setup        ！上面这段程序利用bios中断的INT 0x13将在第2个扇区的setup.s装载到地址0x90200
                    
ok_load_setup:

! Get disk drive parameters, specifically nr of sectors/track

    mov    dl,#0x00
    mov    ax,#0x0800        ! AH=8 is get drive parameters
    int    0x13
    mov    ch,#0x00
    seg cs
    mov    sectors,cx
    mov    ax,#INITSEG
    mov    es,ax            ！利用INT 0x13取驱动器的参数，特别是每道的扇区数量。

! Print some inane message

    mov    ah,#0x03        ! read cursor pos
    xor    bh,bh
    int    0x10
    
    mov    cx,#24
    mov    bx,#0x0007        ! page 0, attribute 7 (normal)
    mov    bp,#msg1
    mov    ax,#0x1301        ! write string, move cursor
    int    0x10            ！利用INT 0x10打印msg1里面的信息-loading system .......

! ok, we've written the message, now
! we want to load the system (at 0x10000)    ！装载系统模块到0x10000

    mov    ax,#SYSSEG
    mov    es,ax        ! segment of 0x010000
    call    read_it        ！读磁盘上的system模块，es是参数
    call    kill_motor

! After that we check which root-device to use. If the device is
! defined (!= 0), nothing is done and the given device is used.
! Otherwise, either /dev/PS0 (2,28) or /dev/at0 (2,8), depending
! on the number of sectors that the BIOS reports currently.
！此后检查哪个设备做为根文件系统
    seg cs
    mov    ax,root_dev
    cmp    ax,#0
    jne    root_defined    ！表示已经设置好了
    seg cs            ！没设好，通过bios的中断返回的每磁道扇区数来判断
    mov    bx,sectors
    mov    ax,#0x0208        ! /dev/ps0 - 1.2Mb
    cmp    bx,#15
    je    root_defined
    mov    ax,#0x021c        ! /dev/PS0 - 1.44Mb
    cmp    bx,#18
    je    root_defined
undef_root:
    jmp undef_root        ！无法设置系统就停在这里
root_defined:
    seg cs
    mov    root_dev,ax

! after that (everyting loaded), we jump to
! the setup-routine loaded directly after
! the bootblock:

    jmpi    0,SETUPSEG  ！指令跳转到setup.s（0x90200），bootsect.s结束了。

! This routine loads the system at address 0x10000, making sure
! no 64kB boundaries are crossed. We try to load it as fast as
! possible, loading whole tracks whenever we can.
!
! in:    es - starting address segment (normally 0x1000)
!
sread:    .word 1+SETUPLEN    ! sectors read of current track
head:    .word 0            ! current head
track:    .word 0            ! current track

！============================================read-it=================================
read_it:
    mov ax,es
    test ax,#0x0fff
die:    jne die            ! es must be at 64kB boundary ！判断es是不是64kb的边缘，不是就
    xor bx,bx        ! bx is starting address within segment
rp_read:
    mov ax,es
    cmp ax,#ENDSEG        ! have we loaded all yet?
    jb ok1_read
    ret
ok1_read:
    seg cs
    mov ax,sectors
    sub ax,sread
    mov cx,ax
    shl cx,#9
    add cx,bx
    jnc ok2_read
    je ok2_read
    xor ax,ax
    sub ax,bx
    shr ax,#9
ok2_read:
    call read_track
    mov cx,ax
    add ax,sread
    seg cs
    cmp ax,sectors
    jne ok3_read
    mov ax,#1
    sub ax,head
    jne ok4_read
    inc track
ok4_read:
    mov head,ax
    xor ax,ax
ok3_read:
    mov sread,ax
    shl cx,#9
    add bx,cx
    jnc rp_read
    mov ax,es
    add ax,#0x1000
    mov es,ax
    xor bx,bx
    jmp rp_read

read_track:        ！读当前磁道指定扇区和扇区数。
    push ax
    push bx
    push cx
    push dx
    mov dx,track
    mov cx,sread
    inc cx
    mov ch,dl
    mov dx,head
    mov dh,dl
    mov dl,#0
    and dx,#0x0100
    mov ah,#2
    int 0x13
    jc bad_rt
    pop dx
    pop cx
    pop bx
    pop ax
    ret
bad_rt:    mov ax,#0        ！驱动器复位操作，跳到read_track从新读取
    mov dx,#0
    int 0x13
    pop dx
    pop cx
    pop bx
    pop ax
    jmp read_track

/*
 * This procedure turns off the floppy drive motor, so
 * that we enter the kernel in a known state, and
 * don't have to worry about it later.
 */
kill_motor:        ！关闭驱动器，这样就可以知道驱动器的状态了。//这个地方不是很懂
    push dx
    mov dx,#0x3f2
    mov al,#0
    outb
    pop dx
    ret

sectors:
    .word 0

msg1:
    .byte 13,10
    .ascii "Loading system ..."
    .byte 13,10,13,10

.org 508
root_dev:
    .word ROOT_DEV
boot_flag:
    .word 0xAA55

.text
endtext:
.data
enddata:
.bss
endbss:

（未完）