ahk1.1获取输入光标当前位置坐标（不是鼠标的位置）

nanj

已于 2023-07-17 14:46:21 修改

阅读量482

点赞数 1

文章标签：笔记

于 2023-07-17 14:45:45 首次发布

本文链接：https://blog.csdn.net/nanj/article/details/131766130

版权

这段代码主要用于获取当前激活窗口中光标的精确位置，特别是在网页输入时。它使用了oleacc库来访问系统的无障碍对象，从而得到光标(X,Y)坐标。如果oleacc库不可用，代码会退化为使用MouseGetPos函数获取鼠标位置作为光标位置。

摘要由CSDN通过智能技术生成


F1 Up::

    Caret:=GetCaretPos(1), hasCaretPos:=1

    x坐标 := Caret.x

    y坐标 := Caret.y

    ToolTip, %x坐标% %y坐标%

Return



; 获取光标坐标

GetCaretPos(Byacc:=1){

    Static init

    If (A_CaretX=""){

        Caretx:=Carety:=CaretH:=CaretW:=0

        If (Byacc){

            If (!init)

                init:=DllCall("LoadLibrary","Str","oleacc","Ptr")

            VarSetCapacity(IID,16), idObject:=OBJID_CARET:=0xFFFFFFF8

            , NumPut(idObject==0xFFFFFFF0?0x0000000000020400:0x11CF3C3D618736E0, IID, "Int64")

            , NumPut(idObject==0xFFFFFFF0?0x46000000000000C0:0x719B3800AA000C81, IID, 8, "Int64")

            If (DllCall("oleacc\AccessibleObjectFromWindow", "Ptr",Hwnd:=WinExist("A"), "UInt",idObject, "Ptr",&IID, "Ptr*",pacc)=0){

                Acc:=ComObject(9,pacc,1), ObjAddRef(pacc)

                Try Acc.accLocation(ComObj(0x4003,&x:=0), ComObj(0x4003,&y:=0), ComObj(0x4003,&w:=0), ComObj(0x4003,&h:=0), ChildId:=0)

                , CaretX:=NumGet(x,0,"int"), CaretY:=NumGet(y,0,"int"), CaretH:=NumGet(h,0,"int")

            }

        }

        If (Caretx=0&&Carety=0){

            MouseGetPos, x, y

            Return {x:x,y:y,h:30,t:"Mouse",Hwnd:Hwnd}

        } Else

            Return {x:Caretx,y:Carety,h:Max(Careth,30),t:"Acc",Hwnd:Hwnd}

    } Else

        Return {x:A_CaretX,y:A_CaretY,h:30,t:"Caret",Hwnd:Hwnd}

}

可以获取网页中输入光标的位置