游游标的概念:
游标是SQL的一个内存工作区,由系统或用户以变量的形式定义。游标的作用就是用于临时存储从数据库中提取的数据块。在某些情况下,需要把数据从存放在磁盘的表中调到计算机内存中进行处理,最后将处理结果显示出来或最终写回数据库。这样数据处理的速度才会提高,否则频繁的磁盘数据交换会降低效率。游标有两种类型:显式游标和隐式游标。在前述程序中用到的SELECT...INTO...查询语句,一次只能从数据库中提取一行数据,对于这种形式的查询和DML操作,系统都会使用一个隐式游标。但是如果要提取多行数据,就要由程序员定义一个显式游标,并通过与游标有关的语句进行处理。显式游标对应一个返回结果为多行多列的SELECT语句。游标一旦打开,数据就从数据库中传送到游标变量中,然后应用程序再从游标变量中分解出需要的数据,并进行处理。
隐式游标:
如前所述,DML操作和单行SELECT语句会使用隐式游标,它们是:
* 插入操作:INSERT。
* 更新操作:UPDATE。
* 删除操作:DELETE。
* 单行查询操作:SELECT ... INTO ...。
当系统使用一个隐式游标时,可以通过隐式游标的属性来了解操作的状态和结果,进而控制程序的流程。隐式游标可以使用名字SQL来访问,但要注意,通过SQL游标名总是只能访问前一个DML操作或单行SELECT操作的游标属性。所以通常在刚刚执行完操作之后,立即使用SQL游标名来访问属性。游标的属性有四种,如下所示。
- 游标的属性 返回值类型 意 义
- %ROWCOUNT 整型 获得FETCH语句返回的数据行数
- %FOUND 布尔型 最近的FETCH语句返回一行数据则为真,否则为假
- %NOTFOUND 布尔型 与%FOUND属性返回值相反
- %ISOPEN 布尔型 游标已经打开时值为真,否则为假
begin
update user_info set pwd='liyanbin' where id='u002';
if SQL%FOUND then --SQL%FOUND判断sql语句是否执行成功
dbms_output.put_line('修改成功,请查看。');
commit;
else
dbms_output.put_line('修改失败,请查看你的游标。');
end if;
end;
显式游标
游标的定义和操作
游标的使用分成以下4个步骤。
1.声明游标
在DECLEAR部分按以下格式声明游标:
CURSOR 游标名[(参数1 数据类型[,参数2 数据类型...])]
IS SELECT语句;
参数是可选部分,所定义的参数可以出现在SELECT语句的WHERE子句中。如果定义了参数,则必须在打开游标时传递相应的实际参数。
SELECT语句是对表或视图的查询语句,甚至也可以是联合查询。可以带WHERE条件、ORDER BY或GROUP BY等子句,但不能使用INTO子句。在SELECT语句中可以使用在定义游标之前定义的变量。
2.打开游标
在可执行部分,按以下格式打开游标:
OPEN 游标名[(实际参数1[,实际参数2...])];
打开游标时,SELECT语句的查询结果就被传送到了游标工作区。
3.提取数据
在可执行部分,按以下格式将游标工作区中的数据取到变量中。提取操作必须在打开游标之后进行。
FETCH 游标名 INTO 变量名1[,变量名2...];
或
FETCH 游标名 INTO 记录变量;
游标打开后有一个指针指向数据区,FETCH语句一次返回指针所指的一行数据,要返回多行需重复执行,可以使用循环语句来实现。控制循环可以通过判断游标的属性来进行。
下面对这两种格式进行说明:
第一种格式中的变量名是用来从游标中接收数据的变量,需要事先定义。变量的个数和类型应与SELECT语句中的字段变量的个数和类型一致。
第二种格式一次将一行数据取到记录变量中,需要使用%ROWTYPE事先定义记录变量,这种形式使用起来比较方便,不必分别定义和使用多个变量。
定义记录变量的方法如下:
变量名 表名|游标名%ROWTYPE;
其中的表必须存在,游标名也必须先定义。
4.关闭游标
CLOSE 游标名;
显式游标打开后,必须显式地关闭。游标一旦关闭,游标占用的资源就被释放,游标变成无效,必须重新打开才能使用。
显式游标之HelloWorld----数据变量(提取表中id为u002的字段值)
declare
name varchar(15);
pwd varchar(15);
CURSOR cursor is
select name,pwd from user_info where id='u002';
begin
open cursor;
fetch cursor into name,pwd;
dbms_output.put_line(name||','||pwd);
close cursor;
end;
显式游标之HelloWorld----记录变量
declare
CURSOR cursor is
select name,pwd from user_info where id='u002';
record cursor%rowtype;--定义在游标之后
begin
open cursor;
fetch cursor into record;
dbms_output.put_line(record.name||','||record.pwd);
close cursor;
end;
显式游标之HelloWorld----循环输出(在郭靖、乔峰他们之中找出功夫最好的前三人)
create table EMP
(
NAME VARCHAR2(10),
SALARY VARCHAR2(10),
TITLE VARCHAR2(10)
);
declare
name varchar(15);
salary varchar(15);
CURSOR emp_cursor is
select name,salary from emp order by salary desc;
begin
open emp_cursor;
for i IN 1..3 loop
fetch emp_cursor into name,salary;
dbms_output.put_line(name||','||salary);
end loop;
close emp_cursor;
end;
执行结果:风清扬,10000 乔峰,8000 郭靖,6000
显式游标之HelloWorld----特殊for循环----省略游标定义(使用特殊for循环显示所有雇员的头衔和工资)
declare
CURSOR emp_cursor is
select title,salary from emp order by salary desc;
begin
for emp_record in emp_cursor loop
dbms_output.put_line(emp_record.title||','||emp_record.salary);
end loop;
end;
这个pl/sql看起来比较特殊,没有申明变量emp_record却可以直接使用,游标没有打开也没有关闭更没有数据的提出,那是如何实现输出的呢,等看完下面这个例子,就会总结。
begin
for emp in(select title,salary from emp order by salary desc)loop
dbms_output.put_line(emp.title||','||emp.salary);
end loop;
end;
显式游标属性前面我们使用fetch来获取游标的数据,但是在显示游标中有可以使用属性来灵活的控制结构化组织,下面是常用属性
- 游标的属性 返回值类型 意 义
- %ROWCOUNT 整型 获得FETCH语句返回的数据行数
- %FOUND 布尔型 最近的FETCH语句返回一行数据则为真,否则为假
- %NOTFOUND 布尔型 与%FOUND属性返回值相反
- %ISOPEN 布尔型 游标已经打开时值为真,否则为假
declare
name varchar2(10);
salary number;
title varchar2(10);
CURSOR emp_cursor is
select name,salary,title from emp order by salary desc;
begin
open emp_cursor;
if emp_cursor%isopen then
loop
fetch emp_cursor into name,salary,title;
exit when emp_cursor%notfound;
dbms_output.put_line(to_char(emp_cursor%rowcount)||name||'-'||salary||'-'||title);
end loop;
else
dbms_output.put_line('游标没打开!');
end if;
close emp_cursor;
end;
参数游标参数游标之HelloWorld
declare
name varchar2(10);
salary number;
CURSOR emp_cursor(t_age number,t_educational varchar2) is
select name,salary from emp
where age = t_age and educational = t_educational;
begin
open emp_cursor(101,'postdoctor');
loop
fetch emp_cursor into name,salary;
exit when emp_cursor%notfound;
dbms_output.put_line(name||'----'||salary);
end loop;
end;
输出:风清扬----10000
动态SELECT语句和动态游标的用法Oracle支持动态SELECT语句和动态游标,动态的方法大大扩展了程序设计的能力。 对于查询结果为一行的SELECT语句,可以用动态生成查询语句字符串的方法,在程序执行阶段临时地生成并执行,
语法是: execute immediate 查询语句字符串 into 变量1[,变量2...];
declare
queryStr varchar2(100);
t_name varchar2(10);
begin
queryStr := 'select name from emp where salary>8000';
execute immediate queryStr into t_name;
dbms_output.put_line(t_name);
end;
在变量声明部分定义的游标是静态的,不能在程序运行过程中修改。虽然可以通过参数传递来取得不同的数据,但还是有很大的局限性。通过采用动态游标,可以在程序运行阶段随时生成一个查询语句作为游标。要使用动态游标需要先定义一个游标类型,然后声明一个游标变量,游标对应的查询语句可以在程序的执行过程中动态地说明。
定义游标类型的语句: TYPE 游标类型名 REF CURSOR;
声明游标变量的语句如下: 游标变量名 游标类型名;
在可执行部分可以如下形式打开一个动态游标: OPEN 游标变量名 FOR 查询语句字符串;
declare
type cur_type is ref cursor;
cur cur_type;
rec scott.emp%rowtype;
str varchar2(50);
letter char:= 'A';
begin
loop
str:= 'select name from emp where name like ''%'||letter||'%''';
open cur for str;
dbms_output.put_line('包含字母'||letter||'的名字:');
loop
fetch cur into rec.name;
exit when cur%notfound;
dbms_output.put_line(rec.name);
end loop;
exit when letter='Z';
letter:=chr(ascii(letter)+1);
end loop;
end;
总结: