ORACLE动态SQL语句

问题的提出

我们经常需要运行可变化的SQL语句,这种通常称为动态SQL,在ORACLE中执行动态的SQL语句,需要了解ORACLE的动态SQL语句的相关规定。
SQL动态语句是由程序或者存储过程生成的SQL语句,这种语句的特点是,不能简单的去运行。因为它不是标准的,其中含有变化的成分,因此ORACLE提供了一个执行动态SQL语句的模式:
EXECUTE IMMEDIATE
这句话的含义是立即执行,而不先去进行语法检查,在执行过程中可能会发生逻辑错误,则通过错误中断进行处理。

一种动态SQL的方法

/***
  DBMS_OUTPUT.PUT_LINE(uSQL);

  p_Money_TJ

  CALL p_Money_TJ();
  测试在SQL*PLUS下进行
  VAR r refcursor;
  Exec p_Money_TJ(:r);
  print r;
***/
CREATE OR REPLACE PROCEDURE p_Money_TJ(p_cur out sys_refcursor)
AS

-- 变量定义

Cursor CC IS
SELECT FTYPE FROM APP_MONEY GROUP BY FTYPE;
uSQL VARCHAR2(32600);
BEGIN
  uSQL :=         'BEGIN OPEN :p_cur for ';
  uSQL := uSQL || 'SELECT FMID 会员账号,F_GETXM(FMID) 会员姓名';
  FOR C IN CC LOOP
    uSQL := uSQL || ',SUM(CASE WHEN FTYPE = '''||C.FTYPE||''' THEN FMONEY END) '||C.FTYPE;
  END LOOP;
  uSQL := uSQL || ' FROM APP_MONEY GROUP BY FMID';
  uSQL := uSQL || '; END;';

  EXECUTE IMMEDIATE uSQL USING p_cur;
END;

使用动态游标

1、声明动态游标

TYPE cc_type IS REF CURSOR;

2、声明游标变量

my_cursor cc_type;

3、使用游标

n_deptno:=20;
uSQL := 'SELECT empno,ename FROM emp WHERE deptno = '||n_deptno;
OPEN my_cursor FOR uSQL;
LOOP 
  FETCH my_cursor INTO n_empno,v_ename;
  EXIT WHEN my_cursor%NOTFOUND;
  --用n_empno,v_ename做其它处理
  --....
END LOOP;
CLOSE my_cursor;

4、小结
动态游标可以胜任大多数动态SQL的需求了,使用简洁方便。

使用 EXECUTE IMMEDIATE

最早大家都使用DBMS_SQL包,但是太太麻烦了,最终都放弃了。但是自从有了EXECUTE IMMEDIATE之后,但要注意以下几点:
EXECUTE IMMEDIATE代替了以前 Oracle8i 中 DBMS SQL package包, 它解析并马上执行动态的SQL语句或非运行时创建的PL/SQL块。动态创建和执行SQL语句性能超前,EXECUTE IMMEDIATE的目标在于减小企业费用并获得较高的性能,较之以前它相当容易编码。尽管DBMS_SQL仍然可用,但是推荐使用EXECUTE IMMEDIATE,因为它获的收益在包之上。
使用技巧
1. EXECUTE IMMEDIATE将不会提交一个DML事务执行,应该显式提交如果通过EXECUTE IMMEDIATE处理DML命令,那么在完成以前需要显式提交或者作为EXECUTE IMMEDIATE自己的一部分. 如果通过EXECUTE IMMEDIATE处理DDL命令,它提交所有以前改变的数据
2. 不支持返回多行的查询,这种交互将用临时表来存储记录(参照例子如下)或者用REF cursors.
3. 当执行SQL语句时,不要用分号,当执行PL/SQL块时,在其尾部用分号.
4. 在Oracle手册中,未详细覆盖这些功能。下面的例子展示了所有用到Execute immediate的可能方面.希望能给你带来方便.
5. 对于Forms开发者,当在PL/SQL 8.0.6.3.版本中,Forms 6i不能使用此功能.

EXECUTE IMMEDIATE用法例子

1. 在PL/SQL运行DDL语句

begin
  execute immediate 'set role all';
end;

2. 给动态语句传值(USING 子句)

declare
  l_depnam varchar2(20) := 'testing';
  l_loc    varchar2(10) := 'Dubai';
begin
  execute immediate 'insert into dept values  (:1, :2, :3)'
  using 50, l_depnam, l_loc;
  commit;
end;

3. 从动态语句检索值(INTO子句)

declare
  l_cnt    varchar2(20);
begin
  execute immediate 'select count(1) from emp'
  into l_cnt;
  dbms_output.put_line(l_cnt);
end;

4. 动态调用例程

例程中用到的绑定变量参数必须指定参数类型.黓认为IN类型,其它类型必须显式指定

declare
  l_routin   varchar2(100) := 'gen2161.get_rowcnt';
  l_tblnam   varchar2(20) := 'emp';
  l_cnt      number;
  l_status   varchar2(200);
begin
  execute immediate 'begin ' || l_routin || '(:2, :3, :4); end;'
  using in l_tblnam, out l_cnt, in out l_status;

  if l_status != 'OK' then
     dbms_output.put_line('error');
  end if;
end;

5. 将返回值传递到PL/SQL记录类型

同样也可用%rowtype变量

declare
  type empdtlrec is record (empno  number(4),ename  varchar2(20),deptno  number(2));
  empdtl empdtlrec;
begin
  execute immediate 'select empno, ename, deptno '||'from emp where empno = 7934'
  into empdtl;
end;

6. 传递并检索值

INTO子句用在USING子句前

declare
  l_dept    pls_integer := 20;
  l_nam     varchar2(20);
  l_loc     varchar2(20);
begin
  execute immediate 'select dname, loc from dept where deptno = :1'
  into l_nam, l_loc
  using l_dept ;
end;

7. 多行查询选项

对此选项用insert语句填充临时表,用临时表进行进一步的处理,也可以用REF cursors纠正此缺憾.

declare
  l_sal   pls_integer := 2000;
begin
  execute immediate 'insert into temp(empno, ename) ' ||
                   '          select empno, ename from emp ' ||
                   '          where  sal > :1'
  using l_sal;
  commit;
end;

对于处理动态语句,EXECUTE IMMEDIATE比以前可能用到的更容易并且更高效.当意图执行动态语句时,适当地处理异常更加重要.应该关注于捕获所有可能的异常.
Oracle 动态SQL
Oracle 动态SQL有两种写法:用 DBMS_SQL 或 execute immediate,建议使用后者。试验步骤如下:

1. DDL 和 DML

/*** DDL ***/  
begin  
    EXECUTE IMMEDIATE 'drop table temp_1';  
    EXECUTE IMMEDIATE 'create table temp_1(name varchar2(8))';  
end;  

/*** DML ***/  
declare  
    v_1 varchar2(8);  
    v_2 varchar2(10);  
    str varchar2(50);  
begin  
    v_1:='测试人员';  
    v_2:='北京';  
    str := 'INSERT INTO test (name ,address) VALUES (:1, :2)';  
    EXECUTE IMMEDIATE str USING v_1, v_2;  
    commit;  
end;  

2. 返回单条结果

declare  
    str varchar2(500);  
    c_1 varchar2(10);  
    r_1 test%rowtype;  
begin  
    c_1:='测试人员';  
    str:='select * from test where name=:c WHERE ROWNUM=1';  
    execute immediate str into r_1 using c_1;  
    DBMS_OUTPUT.PUT_LINE(R_1.NAME||R_1.ADDRESS);  
end ;  

3. 返回结果集

CREATE OR REPLACE package pkg_test as  
    /* 定义ref cursor类型  
    不加return类型,为弱类型,允许动态sql查询,  
    否则为强类型,无法使用动态sql查询;  
    */  
    type myrctype is ref cursor;  

    --函数申明  
    function get(intID number) return myrctype;  
end pkg_test;  
/  

CREATE OR REPLACE package body pkg_test as  
--函数体  
    function get(intID number) return myrctype is  
        rc myrctype; --定义ref cursor变量  
        sqlstr varchar2(500);  
    begin  
        if intID=0 then  
            --静态测试,直接用select语句直接返回结果  
            open rc for select id,name,sex,address,postcode,birthday from  
student;  
        else  
            --动态sql赋值,用:w_id来申明该变量从外部获得  
            sqlstr := 'select id,name,sex,address,postcode,birthday from student  
where id=:w_id';  
            --动态测试,用sqlstr字符串返回结果,用using关键词传递参数  
            open rc for sqlstr using intid;  
        end if;  

        return rc;  
    end get;  

end pkg_test;  
  • 15
    点赞
  • 96
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 1
    评论
动态sql语句基本语法 1 :普通SQL语句可以用Exec执行 例: Select * from tableName Exec('select * from tableName') Exec sp_executesql N'select * from tableName' -- 请注意字符串前一定要加N 2:字段名,表名,数据库名之类作为变量时,必须用动态SQL 错误: declare @fname varchar(20) set @fname = 'FiledName' Select @fname from tableName -- 错误,不会提示错误,但结果为固定值FiledName,并非所要。 正确: Exec('select ' + @fname + ' from tableName') -- 请注意加号前后的单引号的边上加空格 当然将字符串改成变量的形式也可 declare @fname varchar(20) set @fname = 'FiledName' --设置字段名 declare @s varchar(1000) set @s = 'select ' + @fname + ' from tableName' Exec(@s) -- 成功 exec sp_executesql @s -- 此句会报错 --注:@s参数必须为ntext或nchar或nvarchar类型,必须将declare @s varchar(1000) 改为declare @s Nvarchar(1000) 如下: declare @s Nvarchar(1000) -- 注意此处改为nvarchar(1000) set @fname = 'FiledName' --设置字段名 set @s = 'select ' + @fname + ' from tableName' Exec(@s) -- 成功 exec sp_executesql @s -- 此句正确 3. 输入或输出参数 (1)输入参数: declare @QueryString nvarchar(1000) --动态查询语句变量(注:必须为ntext或nchar哐nvarchar类型,不能是varchar类型) declare @paramstring nvarchar(200) --设置动态语句中的参数的字符串(注:必须为ntext或nchar哐nvarchar类型,不能是varchar类型) declare @input_id int--定义需传入动态语句的参数的值 set @QueryString='select * from tablename where id=@id' --id为字段名,@id为要传入的参数 set @paramstring='@id int' --设置动态语句中参数的定义的字符串 set @input_id =1 --设置需传入动态语句的参数的值为1 exec sp_executesql @querystring,@paramstring,@id=@input_id   若有多个参数: declare @QueryString nvarchar(1000) --动态查询语句变量(注:必须为ntext或nchar哐nvarchar类型,不能是varchar类型) declare @paramstring nvarchar(200) --设置动态语句中的参数的字符串(注:必须为ntext或nchar哐nvarchar类型,不能是varchar类型) declare @input_id int--定义需传入动态语句的参数的值,参数1 declare @input_name varchar(20)--定义需传入动态语句的参数的值,参数2 set @QueryString='select * from tablename where id=@id and name=@name' --id与name为字段名,@id与@name为要传入的参数 set @paramstring='@id int,@name varchar(20)' --设置动态语句中参数的定义的字符串,多个参数用","隔开 set @input_id =1 --设置需传入动态语句的参数的值为1 set @input_name='张三' --设置需传入动态语句的参数的值为"张三" exec sp_executesql @querystring,@paramstring,@id=@input_id,@name=@input_name --请注意参数的顺序 (2)输出参数

“相关推荐”对你有帮助么?

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 1
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

彖爻之辞

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付:¥1
获取中
扫码支付

您的余额不足,请更换扫码支付或充值

打赏作者

实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值