1. 适用范围:addFrameScript用于给MovieClip对象添加帧代码。
只有MovieClip及其子类才能使用这个功能,Sprite等不行。
一般是为了给多帧的动画动态添加帧代码,有时候不希望在原动画里直接写帧代码,或者同一段动画在执行时需要有不同的控制逻辑。
2. 基本用法:
asdoc里只有简短的说明:
flash.display.MovieClip.addFrameScript(...parameters):void
可以看出需要传入动态参数,这个参数列表必须是偶数个。
用法如下:
mc.addFrameScript(frameIndex, function);
其中frameIndex就是你要加入帧脚本的帧。
这里值得注意的是,这里的frameIndex是从0开始的,而不是像gotoAndStop()函数是从1开始的,这里需要将实际的帧减1才是正确的。
写一段代码
public class DemoClass
{
var mc:MovieClip; //mc是多帧动画
public function DemoClass()
{
// todo 在这里创建mc实例
....
//这条语句给第一帧加入了帧代码,0代表第一帧。
mc.addFrameScript(0, traceFrame());
//给最后一帧添加帧代码
mc.addFrameScript(mc.totalFrames - 1, traceFrame());
}
private function traceFrame():void
{
trace('currentFrame: ' + mc.currentFrame + ' / ' + 'totalFrames: ' + mc.totalFrames);
}
}
输出结果是:
currentFrame: 1 / totalFrames: 34
currentFrame: 1 / totalFrames: 34
修改其中两句为:
mc.addFrameScript(0, traceFrame);//这条语句给第一帧加入了帧代码,0代表第一帧。
mc.addFrameScript(mc.totalFrames - 1, traceFrame);//给最后一帧添加帧代码
代码已经在正确的帧执行:
currentFrame: 1 / totalFrames: 34
currentFrame: 34 / totalFrames: 34
currentFrame: 1 / totalFrames: 34
currentFrame: 34 / totalFrames: 34
currentFrame: 1 / totalFrames: 34
......
mc.addFrameScript(0, function1, 1, function2, .... mc.totalFrames - 1, functionX);
注意:
1). 对同一帧重复添加帧代码,新的帧代码会自动替换旧的。
2). 通过jellyfish.addFrameScript(frameIndex, null)的方法可以清除frameIndex帧的代码。
3). 如果参数不匹配会报错:
jellyfish.addFrameScript(0, function1, 1);
Error #2001: 指定的参数太少;当前为 3,应该为 4。
4). 如果frameIndex不是数字,默认给第一帧添加帧代码。如果与某一帧对应的代码不是合法的函数类型,而是执行语句,则会在第一帧执行之前执行一遍。
5). 如果给不合法帧添加代码,则都会自动过滤
mc.addFrameScript(
-100, innerFunc,
0, innerFunc,
mc.totalFrames - 1, innerFunc,
100, innerFunc
);
复制代码
这一段给-100,100帧添加帧代码的语句会被无视。中间两条能正常执行。
3. 给帧代码传参。
因为addFrameScript的参数传递的是函数类型,不是函数引用,因此不能传参。
通过内联函数的形式可以给外部传递参数过去。
public class DemoClass
{
public function DemoClass()
{
var mc:MovieClip; //mc是多帧动画
....
mc.addFrameScript(0, function():void
{
execute.call(null, mc);
});
}
private function execute(_mc:MovieClip):void
{
//对_mc的操作
}
}
或者用这种形式就不需要把参数传递过去了:
public class DemoClass
{
public function DemoClass()
{
var mc:MovieClip; //mc是多帧动画
....
function execute():void
{
//对mc的操作
}
mc.addFrameScript(0, execute);
}
}
4. 不推荐使用addFrameScript,addFrameScript是flash的隐藏方法,与EnterFrame在底层实现机制是一样的。EnterFrame事件完全能够实现它所能做的事情,可能写起来代码会稍微多几行。就像setTimeOut能够完全被Timer替代一样。
所以最好还是不要用addFrameScript了。