CMake+QT使用教程

最新推荐文章于 2025-03-12 18:01:59 发布
最新推荐文章于 2025-03-12 18:01:59 发布
阅读量8.1k 收藏 52
点赞数 5
分类专栏： 软件开发笔记 文章标签： qt 开发语言 c++
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/pointerz_zyz/article/details/129781963
版权

一、CMake入门

下面是使用 Qt 用 C++ 编写的控制台应用程序的典型文件：CMakeLists.txt

1.构建一个控制台应用程序

# 指定应用程序所需的CMake最低版本（Qt本身至少需要CMake版本3.16）
cmake_minimum_required(VERSION 3.16)

# 设置项目名称和默认项目版本，同时告诉CMake该程序是用C++编写的
project(helloworld VERSION 1.0.0 LANGUAGES CXX)

# 设置变量CMAKE_CXX_STANDARD，指定C++版本（QT6需要支持c++ 17或更新版本的编译器）
# 设置变量CMAKE_CXX_STANDARD_REQUIRED，如果编译器太旧，让CMake打印一个错误
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

# 设置CMake查找Qt6，并导入模块Core
# 如果CMake找不到模块，设置标志REQUIRED让CMake终止
# 如果成功，CMake将设置一些变量，这些变量记录在模块变量中（见变量参考Module variables）
# 为了能找到依赖包，CMake可以设置变量CMAKE_PREFIX_PATH包含Qt6安装前缀
find_package(Qt6 REQUIRED COMPONENTS Core)

# qt_standard_project_setup命令为一般的QT应用程序设置项目范围的默认值
# 除此之外，该命令将CMAKE_AUTOMOC变量设置为ON，指示CMake自动设置规则，以便在需要时透明地调用Qt的元对象编译器(moc)。
qt_standard_project_setup()

# add_executable命令告诉CMake从指定源文件构建一个可执行文件（而不是库）
# 注意，这里通常不列出头文件。这与qmake不同，qmake需要显式列出头文件，以便元对象编译器(moc)处理它们。
# 对于比较复杂的项目需要改为调用qt_add_executable()，它是内置add_executable()命令的包装器，提供了额外的逻辑来自动处理诸如在静态Qt构建中链接Qt插件、特定于平台的库名定制等。
# 要创建库，使用qt_add_library。
add_executable(helloworld
    main.cpp
)

# 最后告诉CMake, helloworld可执行文件通过引用由上面的find_package()调用导入的Qt6::Core目标来使用Qt的Core模块。这不仅可以为链接器添加正确的参数，还可以确保将正确的include目录、编译器定义传递给c++编译器。PRIVATE关键字对于可执行目标并不是严格必要的，但是指定它是一种良好的实践。
# 如果helloworld是一个库而不是可执行文件，则应该指定PRIVATE或PUBLIC(如果库在头文件中提到了来自Qt6::Core的内容，则为PUBLIC，否则为PRIVATE)
target_link_libraries(helloworld PRIVATE Qt6::Core)

2.构建一个界面应用程序

cmake_minimum_required(VERSION 3.16)

project(helloworld VERSION 1.0.0 LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

find_package(Qt6 REQUIRED COMPONENTS Widgets)
qt_standard_project_setup()

add_executable(helloworld
    mainwindow.ui
    mainwindow.cpp
    main.cpp
)

target_link_libraries(helloworld PRIVATE Qt6::Widgets)

# 最后，我们在应用程序目标上设置属性，效果如下:
# 防止在Windows上创建控制台窗口。
# 在macOS上创建应用程序包。
set_target_properties(helloworld PROPERTIES
    WIN32_EXECUTABLE ON
    MACOSX_BUNDLE ON
)

3.构建子目录项目

  • 项目目录结构
<project root>
├── CMakeLists.txt
└── src
    └── app
        ├── CMakeLists.txt
        ├── main.cpp
        ├── mainwindow.cpp
        ├── mainwindow.h
        └── mainwindow.ui
  • 顶层CMakeLists.txt，包含整个项目的设置并调用add_subdirectory，顶层CMakeLists.txt设置的变量在子目录项目中可见
cmake_minimum_required(VERSION 3.16)

project(helloworld VERSION 1.0.0 LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

find_package(Qt6 REQUIRED COMPONENTS Widgets)
qt_standard_project_setup()

add_subdirectory(src/app)
  • 子目录项目CMakeLists.txt
add_executable(helloworld
    mainwindow.ui
    mainwindow.cpp
    main.cpp
)

target_link_libraries(helloworld PRIVATE Qt6::Widgets)

set_target_properties(helloworld PROPERTIES
    WIN32_EXECUTABLE ON
    MACOSX_BUNDLE ON
)

4.构建库和使用库

  • 项目目录结构
<project root>
├── CMakeLists.txt
└── src
    ├── app
    │   ├── ...
    │   └── main.cpp
    └── businesslogic
        ├── CMakeLists.txt
        ├── businesslogic.cpp
        └── businesslogic.h
  • 库项目文件（src/businesslogic/CMakeLists.txt）
# add_library命令创建businesslogic库，STATIC表示静态库，SHARED表示动态库
add_library(businesslogic STATIC
    businesslogic.cpp
)

target_link_libraries(businesslogic PRIVATE Qt6::Core)

# 通过调用target_include_directories，确保businesslogic目录的绝对路径被自动添加为使用我们的库的所有目标的包含路径。
# 这使我们在main.cpp中不用使用相对路径来定位businesslogic.h。相反，我们可以直接写#include <businesslogic.h>
target_include_directories(businesslogic INTERFACE ${CMAKE_CURRENT_SOURCE_DIR})

最后，我们必须将库的子目录添加到顶级项目文件中:

add_subdirectory(src/app)
add_subdirectory(src/businesslogic)
  • 使用库
target_link_libraries(helloworld PRIVATE
    businesslogic
    Qt6::Widgets)

5.添加资源

qt_add_resources(helloworld imageresources
    PREFIX "/images"
    FILES logo.png splashscreen.png
)

用法：

logoLabel->setPixmap(QPixmap(":/images/logo.png"));

6.添加翻译

qt_add_translations(helloworld
    TS_FILES helloworld_de.ts helloworld_fr.ts)

要更新.ts文件中的条目，构建update_translations目标:

$ cmake --build . --target update_translations

要手动触发.qm文件的生成，构建release_translations目标:

$ cmake --build . --target release_translations

二、CMake命令参考（CMake Command Reference）

  • Qt6::Core

    CMake命令描述
    qt_add_big_resources将大型二进制资源编译为目标代码
    qt_add_binary_resources从 Qt 资源文件列表创建 RCC 文件
    qt_add_executable创建并最终确定指定平台类型的应用程序目标
    qt_add_library创建并完成库
    qt_add_plugin创建 Qt 插件目标
    qt_add_resources将二进制资源编译为源代码
    qt_allow_non_utf8_sources防止强制将源文件视为适用于 Windows 的 UTF-8
    qt_android_add_apk_target定义运行安卓部署qt以生成APK的构建目标
    qt_android_apply_arch_suffix将目标二进制文件的名称配置为包含特定于体系结构的后缀
    qt_android_generate_deployment_settings生成 androiddeployqt 所需的部署设置文件
    qt_deploy_qt_conf在部署时编写 qt.conf 文件
    qt_deploy_runtime_dependencies部署可执行文件所需的Qt插件，Qt和非Qt库
    qt_disable_unicode_defines防止在目标上自动设置某些与 Unicode 相关的编译器定义
    qt_extract_metatypes防止在目标上自动设置某些与 Unicode 相关的编译器定义
    qt_finalize_project处理与Qt项目相关的各种常见平台特定任务
    qt_finalize_target处理与Qt目标相关的各种常见平台特定任务
    qt_generate_deploy_app_script为应用程序生成部署脚本
    qt_generate_moc对输入文件调用 moc
    qt_import_plugins指定要为静态Qt构建导入的自定义插件集
    qt_set_finalizer_mode自定义目标最终确定的各个方面
    qt_standard_project_setup将项目范围的默认设置设置为标准排列
    qt_wrap_cpp从源文件创建.moc文件

  • Qt6::DBus

    CMake命令描述
    qt_add_dbus_adaptor将项目范围的默认设置设置为标准排列
    qt_add_dbus_interface生成实现 D-Bus 接口描述文件接口的C++源
    qt_add_dbus_interfaces生成实现 D-Bus 接口描述文件接口的C++源
    qt_generate_dbus_interface从头文件生成 D-Bus 接口

  • Qt6::InterfaceFramework

    CMake命令描述
    qt_ifcodegen_extend_target使用从 qface IDL 文件生成的文件扩展目标
    qt_ifcodegen_generate从 qface IDL 文件生成文件
    qt_ifcodegen_import_variables从 qface IDL 文件生成文件，并提供变量以在 CMake 中使用
    qt_set_ifcodegen_variable将变量设置为 ifcodegen 模板中的给定 c 值

  • Qt6::LinguistTools

    CMake命令描述
    qt_add_lrelease添加目标以将Qt语言学家.ts文件转换为.qm文件
    qt_add_lupdate添加目标以生成或更新Qt语言学家.ts文件
    qt_add_translation添加目标以生成或更新Qt语言学家.ts文件
    qt_add_translations添加目标以更新Qt Linguist .ts文件并将其转换为.qm文件
    qt_create_translation设置Qt语言学家翻译工具链

  • Qt6::Qml

    CMake命令描述
    qt_add_qml_module设置Qt语言学家翻译工具链
    qt_add_qml_plugin定义与 QML 模块关联的插件
    qt_deploy_qml_imports部署可执行文件所需的 QML 模块的运行时组件
    qt_generate_deploy_qml_app_script为 QML 应用程序生成部署脚本
    qt_generate_foreign_qml_types在 QML 模块中注册来自一个目标的类型
    qt_import_qml_plugins确保为静态构建导入目标所需的 QML 插件
    qt_query_qml_module检索有关 QML 模块的信息
    qt_target_compile_qml_to_cpp
    qt_target_qml_sources检索有关 QML 模块的信息

  • Qt6::RemoteObjects

    CMake命令描述
    qt_add_repc_merged从 Qt 远程对象 .rep 文件为源和副本类型创建C++头文件
    qt_add_repc_replicas从 Qt 远程对象 .rep 文件为副本类型创建C++头文件
    qt_add_repc_sources从 Qt 远程对象 .rep 文件为源类型创建C++头文件
    qt_reps_from_headers从 QObject 头文件创建 .rep 文件

  • Qt6::Scxml

    CMake命令描述
    qt_add_statecharts

  • Qt6::ShaderTools

    CMake命令描述
    Qt Shader Tools Build System Integration编译着色器并将其添加到Qt资源

  • Qt6::Widgets

    CMake命令描述
    qt_wrap_ui编译着色器并将其添加到Qt资源

  • Qt6::WebEngineCore

    CMake命令描述
    qt_add_webengine_dictionary将 hunspell 字典格式转换为 bdict 二进制格式

三、CMake变量参考（CMake Variable Reference）

1.模块变量（Module variables）

变量描述
Qt6Widgets_COMPILE_DEFINITIONS针对库构建时使用的编译定义列表。
Qt6Widgets_DEFINITIONS针对库进行构建时使用的定义列表。
Qt6Widgets_EXECUTABLE_COMPILE_FLAGS针对库构建可执行文件时使用的标志字符串。
Qt6Widgets_FOUND描述是否成功找到模块的布尔值。
Qt6Widgets_INCLUDE_DIRS针对库构建时使用的包含目录列表。
Qt6Widgets_LIBRARIES模块导入的目标的名称:Qt5::Widgets
Qt6Widgets_PRIVATE_INCLUDE_DIRS在构建库和使用私有Qt API时使用的私有包含目录列表。
Qt6Widgets_VERSION_STRING包含模块版本的字符串。

2.安装变量（Installation variables）

变量描述
QT_DEFAULT_MAJOR_VERSION在混合Qt 5和Qt 6项目的情况下，在调用相应的find_package()之前，需要将其设置为5或6。如果未设置，第一次find_package调用将定义默认版本。
QT_LIBINFIX当Qt配置了-libinfix时，保存库名称中使用的中缀的字符串。
QT_NO_CREATE_VERSIONLESS_FUNCTIONS隐藏以qt_开头的命令，只保留以qt6_开头的版本化命令。
QT_NO_CREATE_VERSIONLESS_TARGETS隐藏导入的以Qt::开头的目标。相反，您需要使用以Qt6::开头的目标。
QT_VISIBILITY_AVAILABLE在Unix上，一个布尔值，用于描述Qt库和插件是否使用-fvisibility=hidden进行编译。这意味着只导出选定的符号。

3.项目变量（Project variables）

  • Qt6::Core
变量描述
ANDROID_NDK_HOST_SYSTEM_NAME特定于android的主机系统架构
ANDROID_SDK_ROOTAndroid SDK的位置
QT_ANDROID_ABIS为其构建项目包的abi列表
QT_ANDROID_APPLICATION_ARGUMENTS要传递给Android应用程序的参数列表
QT_ANDROID_BUILD_ALL_ABIS允许使用自动检测的Qt for Android SDK列表构建多abi包
QT_ANDROID_MULTI_ABI_FORWARD_VARS允许在多个abi构建中共享CMake变量
QT_ANDROID_SIGN_AAB使用指定的密钥库、别名和存储密码对.aab包进行签名
QT_ANDROID_SIGN_APK使用指定的密钥库、别名和存储密码对包进行签名
QT_DEPLOY_BIN_DIR前缀-相对子目录，用于在某些目标平台上部署运行时二进制文件
QT_DEPLOY_LIB_DIR前缀相对子目录，用于在某些目标平台上部署库
QT_DEPLOY_PLUGINS_DIR前缀-相对子目录，用于在一些目标平台上部署Qt插件
QT_DEPLOY_PREFIX部署的基本位置
QT_DEPLOY_QML_DIR前缀-相对子目录，用于在一些目标平台上部署QML插件
QT_DEPLOY_SUPPORT要包括用于设置部署支持的文件的名称
QT_ENABLE_VERBOSE_DEPLOYMENT启用部署工具的详细模式
QT_HOST_PATH交叉编译时主机Qt安装的位置
QT_IOS_LAUNCH_SCREEN所有目标使用的iOS启动屏幕故事板的路径
QT_NO_COLLECT_BUILD_TREE_APK_DEPS防止在Android部署期间收集项目构建的共享库目标
QT_NO_SET_XCODE_BUNDLE_IDENTIFIER在iOS上禁用在目标终结期间提供备用应用程序包ID
QT_NO_SET_XCODE_DEVELOPMENT_TEAM_ID在iOS上禁用在目标完成过程中提供备用团队ID
QT_NO_STANDARD_PROJECT_SETUP防止后续对qt_standard_project_setup()的调用进行任何更改
QT_PATH_ANDROID_ABI_为相应的ABI指定Qt for Android路径的变量集
  • Qt6::Qml
变量描述
QT_QML_OUTPUT_DIRECTORY默认情况下将在其下面创建QML模块的基本输出目录
  • Qt6::InterfaceFramework
变量描述
IFCODEGEN_VERBOSE为所有ifcodegen函数启用详细日志记录
QT_IFCODEGEN_TEMPLATE_SEARCH_PATHifcodegen模板的搜索路径

四、CMake属性参考（CMake Property Reference）

  • Qt6::Core

    目标属性

属性描述
QT_ANDROID_ABIS为单个目标的包构建的abi列表
QT_ANDROID_DEPLOYMENT_DEPENDENCIES覆盖添加到目标部署中的Qt依赖项
QT_ANDROID_DEPLOYMENT_SETTINGS_FILE指定目标生成的部署设置文件的位置
QT_ANDROID_EXTRA_LIBS要与目标一起部署的额外库
QT_ANDROID_EXTRA_PLUGINS额外的Qt插件与目标一起部署
QT_ANDROID_MIN_SDK_VERSIONAndroid SDK最低版本
QT_ANDROID_NO_DEPLOY_QT_LIBSQt共享库是否打包在Android的APK中
QT_ANDROID_PACKAGE_SOURCE_DIR自定义Android包模板的路径
QT_ANDROID_SDK_BUILD_TOOLS_REVISIONAndroid构建工具的修订使用
QT_ANDROID_SYSTEM_LIBS_PREFIX指定Qt库在目标设备上的位置
QT_ANDROID_TARGET_SDK_VERSIONAndroid目标SDK版本
QT_ANDROID_VERSION_CODEAndroid内部应用版本
QT_ANDROID_VERSION_NAME可读的安卓应用版本
QT_IOS_LAUNCH_SCREENiOS启动屏幕故事板的路径
QT_QML_IMPORT_PATH指定要搜索QML导入的目录列表
QT_QML_ROOT_PATH覆盖应用程序qml目录的位置
QT_RESOURCE_PREFIX指定默认的Qt资源前缀
QT_WASM_INITIAL_MEMORY内部WebAssembly初始内存
QT_WASM_PTHREAD_POOL_SIZE内部WebAssembly线程池大小
qt_no_entrypoint指定禁止链接到Qt的入口点库

源文件属性

属性描述
QT_RESOURCE_ALIAS为资源中的文件指定Qt资源别名
  • Qt6::DBus

源文件属性

属性描述
CLASSNAME覆盖默认的接口类名
INCLUDE添加一个包含路径
NO_NAMESPACE禁止生成名称空间名称
  • Qt6::Qml

源文件属性

属性描述
QT_QMLTC_FILE_BASENAME指定非默认的.h和.cpp文件名
QT_QML_INTERNAL_TYPE将QML文件标记为提供内部类型
QT_QML_SINGLETON_TYPE将QML文件标记为提供单例类型
QT_QML_SKIP_CACHEGEN不允许将文件编译为字节代码
QT_QML_SKIP_QMLDIR_ENTRY排除一个文件作为类型添加到QML模块的typeinfo文件
QT_QML_SKIP_QMLLINT防止一个文件被自动qmllint处理
QT_QML_SKIP_TYPE_COMPILER不允许使用qmltc将文件编译为c++
QT_QML_SOURCE_TYPENAME重写文件提供的类型名称
QT_QML_SOURCE_VERSIONS指定类型的自定义版本集
使用CMake构建QT项目
FucMobile的博客
09-24 1140
在本文中，我们介绍了如何使用CMake构建一个QT项目。通过编写适当的CMakeLists.txt文件，并使用CMake来生成构建系统，我们能够轻松地管理和构建复杂的QT项目。在项目的根目录下，创建一个名为"src"的文件夹用于存放源代码文件，创建一个名为"build"的文件夹用于存放构建生成的文件。在项目的根目录下，创建一个名为CMakeLists.txt的文件，用于配置CMake构建项目的规则。在上述CMakeLists.txt文件中，我们首先指定了CMake的最低版本要求，并指定了项目的名称。
WIN10+Opencv+Cmake +VS+QT环境搭建教程
qq_44582403的博客
07-20 887
Win10+Opencv+Cmake +VS&QT环境搭建教程 Double C 准备软件 版本：建议最新版（我的是Opencv4.3.0 Cmake3.18 VS2017 QT5.14） VS：https://visualstudio.microsoft.com/zh-hans/vs/ Cmake：https://cmake.org/download/ QT：https://download.qt.io 下载源码：qt-opensource-windows-___.exe Opencv：ht
(Qt) cmake编译Qt项目
cuber-lotus的博客
12-31 6159
通常我们在编写qt的时候都是在Qt creator中。而如何在VS Code中编写qt就是本文需要解决的问题。
QT 如何使用CMAKE（QT官方文档）
m0_61540162的博客
12-05 2805
CMake是一个允许构建（build）、测试（test）和打包应用程序的工具。就像Qt一样，它可以在所有主要的开发平台上使用。它也被各种IDE支持，当然也包括Qt Creator。 在本节中，我们将展示在CMake项目中使用Qt的最基本方法。
使用 CMake 构建 Qt 动态库模块
威桑的博客
03-05 917
Qt CMake 制作动态库
QT用于CMake项目
12-09
QT用于CMake项目
QT项目使用CMake
极地星辰
03-03 2588
1.00++17。
CMake教程--QT项目使用CMake
宁静致远的博客
11-11 4479
其中，BasicUsageEnvironment, groupsock, liveMedia, UsageEnvironment都是live555项目的子模块，mediaServer是集成所有子模块打包成为可执行文件的部分。调用环境变量: $ENV{NAME}这种做法会导致项目里即便改了一处代码，也会编译所有代码，导致编译时间较长，不能很好利用增量编译，再说C/C++本身编译就很慢。变量的引用方式是使用${}，在IF中，不需要使用这种方式，直接使用变量名亦可。在工程build目录下执行。
CMake Qt 配置
weixin_42252757的博客
09-15 2101
该文件供使用Cmake 搭建Qt项目框架
qt的cmake配置
最新发布
LYOBOYI123的博客
03-12 201
要求：boost的msvc版本的动态库静态链接版本，编译器版本qt的msvc编译器。
基于Cmake+QT+VS的C++项目构建开发编译简明教程
weixin_30632089的博客
03-17 4795
目录 一、工具下载与安装 1. Qt 2. Visual Studio 2015 3. Cmake 二、C++及Qt项目构建 1. 基于VS构建Qt项目 2. 基于Qt Creater构建，在VS中使用 用Qt Creater构建项目 用VS开发Qt Creater生成的项目 3. 基于Cmake构建 用CMake-Gui构建 ...
Windows+VSCode+cmake+Qt5环境，记录一下踩过的坑
weixin_42221830的博客
12-16 1万+
Qt的编辑界面看腻了 ，最近喜欢上VSCode，在VSCode上写Qt程序，配了几个晚上，查了N多资料，终于成功。煎熬死了 1.环境： Windows 2.我安装的工具： VScode ，Qt5.9.5，cmake3.11.2 GCC5.3.0 GCC可在Qt安装的时候记得把相应的GCC也安装了，在Qt安装步骤可选。也可以自行安装 安装成功后在Qt安装文件夹下的C:\Qt\Qt5.9.5\Tools可以见到。 3.VScode配置 安装扩展工具 CMake Tools ...
使用CMake+Visual Studio构建Qt程序（二）
TinyHou的博客
05-25 1797
在上一篇文章中，我们成功生成并执行了自己的HelloWorld，接下来将进一步完善其构建方法，使其更加方便更加自动化。同时也会介绍安装打包以及增加程序功能的方法。 设置CMakeLists中的变量来更改VS项目的默认设置 上篇文章结尾我们得到了一个有控制台窗口的HelloWorld程序。我们可以通过修改Visual Studio中的设置来隐藏控制台窗口。 也可以在CMakeLists.txt中添加如下内容达到相同效果： set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_.
Qt CMake配置
Bloggy of Gallopt
10-21 1719
修改程序图标 1. 图标为.ico格式: icon.ico 2. 创建.rc文件：resource.rc .rc文件内容： IDI_ICON1 ICON DISCARDABLE "icon.ico" #图标的文件路径 3. 在CMakeLists.txt内添加： set(PROJECT_SOURCES main.cpp mainwindow.cpp mainwindow.h mainwindow.ui resource.rc
QT的cmake项目工程配置
热门推荐
独行猫a 的沉淀、积累、总结。天天学习，好好向上...c/c++,嵌入式 linux,Android,HarmonyOS)
03-24 1万+
QT的项目工程默认使用的是qmake,这本来也没什么问题。但是，由于要用到vcpkg这个工具来管理第三方库，好像这个 vcpkg工具只能在cmake的项目中才能使用。 于是，这里记录下QT的cmake工程配置。 需要注意的是需要额外配置个项： -DCMAKE_PREFIX_PATH=D:\Qt\Qt5.10.0\5.10.0\msvc2015\lib\cmake -DCMAKE_TOOLCHAIN_FILE=F:\vcpkg\scripts\buildsystems\vcpkg.cmake -Wn
Qt扫盲-CMake 使用概述
洪源兄
03-05 7130
CMake是一个简化跨不同平台开发项目的构建过程的工具。对C++来说其实就是生成一个文件，文件里面描述了，怎么组织这个工程，用编译器怎么编译这个项目之类的，这个CMake 本身不是一个编译器，其实就是生成一个让编译器能读懂编译流程的文件工具。让CMake自动生成构建系统，例如Makefiles和Visual Studio项目文件。CMake是一个第三方工具，有自己的文档。这里就是介绍一下在Qt 5中使用CMake 3.5 系列，反正是 CMake 3系列。
Qt6.5 CMake项目配置
izwmain的博客
10-30 3571
Qt项目CMake配置，Qt6.5
cmake配置Qt工程
wjh_monkey的博客
08-04 852
initDrivers@MainWindow@@QEAAXXZ)，函数 "public: __cdecl MainWindow::MainWindow(char const *,class QWidget *)" (?无法解析的外部符号 "public: virtual int __cdecl MainWindow::qt_metacall(enum QMetaObject::Call,int,void * *)" (?
cmake构建Qt项目
weixin_73186358的博客
06-16 1394
项目结构。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值