使用cmd生成u盘自启动防疫文件夹,和删除相似功能的文件夹

@echo off
title 建立/删除自启动病毒免疫文件夹autorun.inf
:top
cls
echo .
echo 建立/删除自启动病毒免疫文件夹autorun.inf for /XP
echo .
echo 此批处理会在指定的分区根目录下建立autorun.inf/cfan.文件夹，默
echo 认的情况下是删不掉的，但可以用这个批处理删掉。在XP下测试通过。
echo .
echo [m] 按 m 键回车:为指定分区建立autorun.inf文件夹免疫autorun类病毒
echo [d] 按 d 键回车:删除指定分区下的autorun.inf文件夹
echo [c] 按 c 键回车:拉入指定文件夹进行防删除处理(原理同上)
echo [r] 按 r 键回车:拉入指定文件夹进行删除
echo [←] 直接回车退出
echo .
SET Choice=
SET /P Choice= 请选择要进行的操作：
IF /I '%Choice:~0,1%'=='m' goto md
IF /I '%Choice:~0,1%'=='d' goto del
IF /I '%Choice:~0,1%'=='r' goto rd
IF /I '%Choice:~0,1%'=='c' goto nd
exit
:md
cls
color c0
echo 请稍候!正在查找存在的盘符...
wmic logicaldisk get Name,Description,VolumeName
echo [*] 请输入你要免疫的盘符(只能输入上面列出的),不能带:号
echo [←] 直接回车退出
echo .
SET Choice=
SET /P Choice= 请选择要进行的操作(输入盘符或直接回车退出)：
IF '%Choice%'=='' exit
set Choice=%Choice%:
@echo on
md %Choice%/autorun.inf
md %Choice%/autorun.inf/qidizi../
attrib +s +h +r %Choice%/autorun.inf
@echo off
echo 已经在%Choice%分区的根目录下建立autorun.inf/qidizi.文件夹免疫autorun病毒。
echo 如果存在同名文件夹qidizi此功能会失效.
pause
goto top
exit
:del
cls
color c0
echo 请稍候!正在查找存在的盘符...
wmic logicaldisk get Name,Description,VolumeName
echo [*] 请输入你要删除免疫文件夹的盘符(只能输入上面列出的),不能带:号
echo [←] 直接回车退出
echo .
SET Choice=
SET /P Choice= 请选择要进行的操作(输入盘符或直接回车退出)：
IF '%Choice%'=='' exit
set Choice=%Choice%:
@echo on
rd /s /q %Choice%/autorun.inf/qidizi../
rd /s /q %Choice%/autorun.inf
@echo off
echo 已经删除各分区的根目录下建立autorun.inf/cfan.文件夹。
echo 感谢使用，按任意键退出
pause
goto top
:rd
cls
color c0
SET Choice=
SET /P Choice= 请把要删除的文件夹拉入后回车(直接回车退出)：
IF '%Choice%'=='' exit
@echo on
rd /s /q %Choice%./
@echo off
echo 已经删除%Choice%
echo 感谢使用，按任意键退出
pause
goto top
:nd
cls
color c0
SET Choice=
SET /P Choice= 请把要防删除的文件夹拉入后回车(直接回车退出)：
IF '%Choice%'=='' exit
@echo on
md %Choice%/no4del../
attrib +s +h +r %Choice%
@echo off
echo 已经删除%Choice%
echo 感谢使用，按任意键退出
pause
goto top

 

---------------

 

执行后的菜单选择

----------

 

.
建立/删除自启动病毒免疫文件夹autorun.inf for /XP
.
此批处理会在指定的分区根目录下建立autorun.inf/cfan.文件夹，默
认的情况下是删不掉的，但可以用这个批处理删掉。在XP下测试通过。
.
[m] 按 m 键回车:为指定分区建立autorun.inf文件夹免疫autorun类病毒
[d] 按 d 键回车:删除指定分区下的autorun.inf文件夹
[c] 按 c 键回车:拉入指定文件夹进行防删除处理(原理同上)
[r] 按 r 键回车:拉入指定文件夹进行删除
[←] 直接回车退出
.
 请选择要进行的操作：