grouping sets如何使用
数据准备:
建表语句:
use default;
create table gb(
a string,
b string,
c int
)row format delimited fields terminated by '\t' stored as textfile;
案例数据:
1 1 1
2 1 2
2 2 2
2 2 3
2 1 2
1 2 2
使用案例:
第一种组合:
select a,b,sum(c) from gb group by a,b grouping sets(a);
1 NULL 3
2 NULL 9
第二种组合:
select a,b,sum(c) from gb group by a,b grouping sets(b);
NULL 1 5
NULL 2 7
第三种组合:
select a,b,sum(c) from gb group by a,b grouping sets(a,b);
NULL 1 5
NULL 2 7
1 NULL 3
2 NULL 9
第四种组合:
select a,b,sum(c) from gb group by a,b grouping sets((a,b));
1 1 1
1 2 2
2 1 4
2 2 5
第五种组合:
select a,b,sum(c) from gb group by a,b grouping sets((a,b),a);
1 NULL 3
1 1 1
1 2 2
2 NULL 9
2 1 4
2 2 5
特殊组合:
select a,b,sum(c) from gb group by a,b;
1 1 1
1 2 2
2 1 4
2 2 5
通过案例演示,发现grouping sets是可以细化到每一种组合,不同的组合可以通过其他的组合进行union实现,其中直接使用group by 和使用grouping sets((a,b))效果是一致的,可以理解为group by是grouping sets的其中一个组合。
grouping sets实际应用
grouping sets可以替换 group by + union的操作,并且可以细化到每一个组合,通过这种聚合查询方式来实现多种分组聚合结果的合并,可以大大提高开发效率,要统计每月的收入(year,month)和年收入(year)以及历年收入()就可以使用这个。